More than 3 years have passed since last update.

株式会社函館ラボラトリ

【Bラボデジタルサイネージ8】設置されている場所の名前を表示する「LocationModule」

Last updated at 2022-07-05Posted at 2021-10-28

本記事は、株式会社函館ラボラトリが運営する「Bラボ」における、大人向け「看板アプリ（デジタルサイネージ）を作るコース」用教材テキストです。

作るもの

デジタルサイネージが設置されている場所の住所や店舗名を表示できるようにします。
ただし、GPSなどを使うわけではなく、あくまで手打ちの値を表示します。

本テキストでは、設置場所を「北海道函館市美原2丁目 / MIRAI BASE」と表示したいと思います。

必要な変数の用意

「北海道函館市美原2丁目 / MIRAI BASE」という値を、定数として定義します。

DigitalSignage.pde

/* 略 */

final String AD_PATH = "ad/";

final String LOCATION = "北海道函館市美原2丁目 / MIRAI BASE"; /* 追加 */

void settings() {
  size(1920, 1080);
  //fullScreen();
}

/* 略 */

文字色などの色指定に使う変数も定義しておきます。

DigitalSignage.pde

/* 略 */

final String LOCATION = "北海道函館市美原2丁目 / MIRAI BASE";

color WHITE_COLOR; /* 追加 */
color NEARLY_WHITE_COLOR; /* 追加 */
color NEARLY_GREEN_COLOR; /* 追加 */
color BLACK_COLOR; /* 追加 */
color LIGHT_COLOR; /* 追加 */
color GRAY_COLOR; /* 追加 */
color GREEN_COLOR; /* 追加 */

/* 中略 */

void setup() {
  frameRate(1);
  noCursor();
  colorMode(HSB, 360, 100, 100, 100);

  WHITE_COLOR = color(0, 0, 100); /* 追加 */
  NEARLY_WHITE_COLOR = color(100, 2, 98); /* 追加 */
  NEARLY_GREEN_COLOR = color(100, 5, 98); /* 追加 */
  BLACK_COLOR = color(0, 0, 0); /* 追加 */
  LIGHT_COLOR = color(0, 0, 80); /* 追加 */
  GRAY_COLOR = color(0, 0, 50); /* 追加 */
  GREEN_COLOR = color(150, 100, 60); /* 追加 */
  
  background = pImageCut(loadImage("background.jpg"), CENTER, CENTER, width, height);
  
  initialize();
}

/* 略 */

フォント「Noto Sans CJK JP Bold」も読み込みます。
読み込んで使う処理を記述します。

DigitalSignage.pde

/* 略 */

void setup() {
  frameRate(1);
  noCursor();
  colorMode(HSB, 360, 100, 100, 100);

  WHITE_COLOR = color(0, 0, 100);
  NEARLY_WHITE_COLOR = color(100, 2, 98);
  NEARLY_GREEN_COLOR = color(100, 5, 98);
  BLACK_COLOR = color(0, 0, 0);
  LIGHT_COLOR = color(0, 0, 80);
  GRAY_COLOR = color(0, 0, 50);
  GREEN_COLOR = color(150, 100, 60);

  textFont(createFont("Noto Sans CJK jp Bold", 32)); /* 追加 */
  
  background = pImageCut(loadImage("background.jpg"), CENTER, CENTER, width, height);
  
  initialize();
}

/* 略 */

テキスト表示用の関数

Processingにおいてテキストを表示するには、関数textが使われます。

例

text("テキスト", 0, 0);

テキスト描画時に、「中央揃え」などのオプションを指定したい場合、textAlignが使われます。
文字の大きさにはtextSizeが使われます。

例

textAlign(CENTER, CENTER);
textSize(32);
text("テキスト", 0, 0);

こういった複数の処理をいちいち数行書くのは面倒なので、1つの関数を呼び出すだけで完結できるようにしてみましょう。
たとえば、下記のように1行だけで呼び出せるようになると便利です。

例

drawText(RIGHT, BASELINE, color(0, 0, 100), 36, LOCATION, width-100, 30);

それでは、テキスト描画用の関数を実装してみましょう。
新しい関数drawTextを作ります。

DigitalSignage.pde

/* 略 */

void updateNowPageID(boolean isIncrement) {
  if (isIncrement) {
    nowPageID = (nowPageID + 1) % PAGE_ALL_COUNT;
  } else {
    nowPageID = (nowPageID + PAGE_ALL_COUNT - 1) % PAGE_ALL_COUNT;
  }
}

/* ここから追加 */
void drawText(int alignX, int alignY, color c, int size, String text, int x, int y) {
}
/* ここまで追加 */

引数が多いので、各引数の役割を説明します。

alignXとalignYの2つは、関数textAlignで使う変数です。
cは、関数fillで文字色指定に使う変数です。
sizeは、関数textSizeで文字サイズ指定に使う変数です。
textとxとyは、関数textで使う変数です。

これらの引数を使うように実装すると、下記のようになります。

DigitalSignage.pde

/* 略 */

void drawText(int alignX, int alignY, color c, int size, String text, int x, int y) {
  /* ここから追加 */
  pushStyle();
  textAlign(alignX, alignY);
  textSize(size);
  fill(c);
  if (alignY == BASELINE) {
    text(text, x, y+size);
  } else {
    text(text, x, y);
  }
  popStyle();
  /* ここまで追加 */
}

pushStyle()とpopStyle()は、「色」「文字サイズ」などの設定が、この関数を実行されている間だけ適用させるために用います。

alignYに値BASELINEが指定されたときの実装意図については、下記の記事を参考にしてください。
【Processing】テキスト表示位置がOSによって微妙に異なるときの対処方法（執筆中）

LOCATIONを表示

新しくM_Location.pdeというファイルを作り、関数を作ります。
LOCATIONを、画面右上に黒い字で表示する処理にします。
下記の3行を書き込みます。

M_Location.pde

void drawLocationModule() {
  drawText(RIGHT, BASELINE, BLACK_COLOR, 36, LOCATION, width-100, 30);
}

関数drawModules()内で、drawLocationModule()を呼び出すように書き換えます。

DigitalSignage.pde

/* 略 */

void drawModules() {
  if (nowPageID == 0) {
    drawFullImageModule(background);
    drawGridModule();
    drawPlaceholderModule();
  } else if (nowPageID == 1) {
    drawFullImageModule(adImage[0]);
  }
  drawLocationModule(); /* 追加 */
}

/* 略 */

一度実行すると、下図のような表示になります。

この状態でも十分ですが、広告画像の背景が黒い場合には、文字が読めなくなってしまいます。
そこで、ひと工夫を加えてみましょう。
blendModeを使います。

M_Location.pde

void drawLocationModule() {
  blendMode(EXCLUSION); /* 追加 */
  drawText(RIGHT, BASELINE, WHITE_COLOR, 36, LOCATION, width-100, 30); /* 変更 */
  blendMode(BLEND); /* 追加 */
}

blendMode(EXCLUSION);は、異なる色を重ねたときに、色を反転してくれる混色モードです。
このモードを使うことで、黒い背景に書かれた文字は白く、白い背景に書かれた文字は黒く表示されるようになります。

最後に

これで、設置されている場所の名前を表示する「LocationModule」が実装できました。
次は、**現在の時間を表示する「DateModule」**を実装してみましょう。

You get articles that match your needs
You can efficiently read back useful information
You can use dark theme

What you can do with signing up