解決したいこと Freenoveのラジコンキットをつかい、IRリモコンでラジコンを操作したいです。 https://amzn.asia/d/ghOXhW0 発生している問題・エラーサンプル...

ではなく、をつかったコードを作りたいが、何を変えればよいか不明 ??? プログラムコードはコードブロックを使って記載してください。また、< はHTMLのタグの始まりのため、正しく表示...

[Q&A] Arduino「IRremote.hpp」ライブラリを使用してラジコンを動かしたい

@nak435 posted at 2024-04-18

ではなく、をつかったコードを作りたいが、何を変えればよいか不明

???

プログラムコードはコードブロックを使って記載してください。
また、< はHTMLのタグの始まりのため、正しく表示されません。

書き方

```c:IR_Remote_Car.ino
#include <IRremote.h>
#include "Freenove_4WD_Car_for_Arduino.h"

（以下省略）

```

Comments

@yoshi_arduino
Questioner
すみません。ライブラリは
IRremote.hではなく
IRremote.hppを使用して、コードを書き換えたい、という意味です。

また、コードブロックの使い方教えて頂きありがとうございます。改めてまた質問内容修正します。
@nak435

IRremote.hではなく
IRremote.hppを使用して、コードを書き換えたい、という意味です。

それは何故でしょうか？
~~IRremote.hppはIRremote.hをインクルードしており、結局は同じだと思います。~~
↑これは間違いでした。失礼しました。

下記コードで書き替えたが、コンパイルエラー

コンパイルエラーを含む結果全体をコードブロックに貼ってください。
@yoshi_arduino
Questioner
ご返信が遅くなりました。
コンパイルエラーとFREENOVE_4WD_CAR_FOR_ARDUINOライブラリを追記しています。

@nak435 posted at 2024-04-18

そこで下記コードでシリアルモニタを開くと正常に反応

IrReceiver.begin(11,true);
こちらのプログラムは、ピン番号11を使っています。そうであれば、以下のようにピン番号を変更すだけで動くかも。

PIN_IRREMOTE_RECVは9だと思います。

IR_Remote_Car.ino

- IRrecv irrecv(PIN_IRREMOTE_RECV);
+ IRrecv irrecv(11);

Comments

@yoshi_arduino
Questioner

上記画像のように、ピンアサインは9となっております。

なお、「そこで下記コードでシリアルモニタを開くと正常に反応」
については別に、
拡張ボードやモーターを取り外して、arduinoUnoとジャンパーワイヤー、センサーだけを使用し、9番→11番につけかえてためしたということです。
＊「自分で試したこと」に上記内容追記

@nak435

9番ピンが正しいならば、以下のスケッチを実行して、リモコンのコードを確認してみてください。シリアルのスピードは適宜変更（9600→115200）してください。

https://github.com/Freenove/Freenove_4WD_Car_Kit/blob/master/Sketches/04.1_IR_Receiver/04.1_IR_Receiver.ino

/**********************************************************************
  Filename    : IR_Receiver.ino
  Product     : Freenove 4WD Car for UNO
  Description : A demo of uasage of IR-Recveiver.
  Auther      : www.freenove.com
  Modification: 2019/08/06
**********************************************************************/
#include <IRremote.h>             // incudle IRremote library
#define PIN_IRREMOTE_RECV  9      // Infrared receiving pin

IRrecv irrecv(PIN_IRREMOTE_RECV); // Create a class object used to receive

decode_results results;           // Create a decoding results class object

void setup()
{
  Serial.begin(9600);         // Initialize the serial port and set the baud rate to 9600
  irrecv.enableIRIn();        // Start the receiver
}

void loop() {
  if (irrecv.decode(&results)) {        // Waiting for decoding
    Serial.println(results.value, HEX); // Print out the decoded results
    irrecv.resume();                    // Receive the next value
  }
  delay(100);
}

これで正しく受信できるならば、<IRremote.h>の問題ではないということです。

@yoshi_arduino
Questioner
早急にご対応いただきありがとうございます。
ご提示いただいたコードで試してみましたが、下記の通り、どのリモコンのボタンを押してもFFFFFFとなってしまいます。

シリアルの速度を変更しても同様です。
@nak435

どのリモコンのボタンを押してもFFFFFFとなってしまいます。

9番ピンにIR受信センサーが接続されているとは考えられない結果ですが、
IR受信モジュールは、下記写真の基板でしょうか？

arduinoUnoとジャンパーワイヤー、センサーだけを使用し、9番→11番につけかえてためしたということです。

この時のIRセンサーも、上記のIR受信モジュールを使用したのでしょうか？
@yoshi_arduino
Questioner
返信遅くなりすみません。
はい、他に別の３ピン形式の
IRレシーバーと類似のIRリモコンにつけかえても同様の結果でした。

@nak435

手持ちのIR受信モジュールで試してみましたが、確かに"FFFF"と出ますね。

実行すると、以下のメッセージがシリアルに出力され、これを読むと、バージョン2.0のAPIはサポートされずAPIを置き換えるようにと書いてますね。

**************************************************************************************************
Thank you for using the IRremote library!
It seems, that you are using a old version 2.0 code / example.
This version is no longer supported!
Please use one of the new code examples from the library,
 available at "File > Examples > Examples from Custom Libraries / IRremote".
Or downgrade your library to version 2.6.0.

Start with the SimpleReceiver or SimpleSender example.

The examples are documented here:
 https://github.com/Arduino-IRremote/Arduino-IRremote#examples-for-this-library
A guide how to convert your 2.0 program is here:
 https://github.com/Arduino-IRremote/Arduino-IRremote#converting-your-2x-program-to-the-4x-version

Thanks
**************************************************************************************************


FFFFFFFF
FFFFFFFF

APIの書き換え方が、https://github.com/Arduino-IRremote/Arduino-IRremote#converting-your-2x-program-to-the-4x-versionにあります。

そこにある、New 4.x program はちゃんと動きました。

#include <IRremote.hpp>
#define IR_RECEIVE_PIN 9

void setup()
{
  Serial.begin(115200);
  IrReceiver.begin(IR_RECEIVE_PIN, ENABLE_LED_FEEDBACK); // Start the receiver
}

void loop() {
  if (IrReceiver.decode()) {
      Serial.println(IrReceiver.decodedIRData.decodedRawData, HEX); // Print "old" raw data
      IrReceiver.printIRResultShort(&Serial); // Print complete received data in one line
      IrReceiver.printIRSendUsage(&Serial);   // Print the statement required to send this data
      delay(100);
      IrReceiver.resume(); // Enable receiving of the next value
  }
}

54AB6D82
Protocol=NEC Address=0x6D82 Command=0xAB Raw-Data=0x54AB6D82 32 bits LSB first
Send with: IrSender.sendNEC(0x6D82, 0xAB, <numberOfRepeats>);
43BC6D82
Protocol=NEC Address=0x6D82 Command=0xBC Raw-Data=0x43BC6D82 32 bits LSB first
Send with: IrSender.sendNEC(0x6D82, 0xBC, <numberOfRepeats>);

@yoshi_arduino
Questioner
ご回答毎度ありがとうございます。
①ご指摘いただいたのは、arduinoIDEのバージョンが新しいため、本プログラムと互換性
がないということでしょうか。
②対策としてはご提示いただいた
以下の２つを参照、ということでしょうか。
※実機確認はあらためてします。

IMG_8734.png

申し訳ありません。初心者なものでAPI
を理解しかねております。下記リンクを参照しましたが、意味合いがピンときてません。
https://garretlab.web.fc2.com/arduino.cc/docs/learn/starting-guide/getting-started-arduino/

お手数ですがご回答のほどよろしくお願いします。

@nak435

①ご指摘いただいたのは、arduinoIDEのバージョンが新しいため、本プログラムと互換性がないということでしょうか。

いいえ、ArduinoIDEのバージョンのことではなく、IRRemoteライブラリのバージョンのことです。

対策は、IRRemoteライブラリの新APIに書き換えることです。これは、@yoshi_arduino さんが、最初の質問時に言われていた、『 IRremote.h ではなく、IRremote.hpp を使用して、コードを書き換えたい』そのものでした。
自分の理解がすぐにそこに及ばず、遠回りしましたが、
以下のコードが『IRremote.hpp を使用するように書き換えたコード』です。
実機を持っていないので動作確認はできませんが、コンパイルできるところまでは確認済みです。-が削除行、+が追加行を表します。

  /**********************************************************************
  * Filename    : IR_Remote_Car.ino
  * Product     : Freenove 4WD Car for UNO
  * Description : An IR-Remote Car.
  * Auther      : www.freenove.com
  * Modification: 2019/08/06
  **********************************************************************/
- #include <IRremote.h>
+ #include <IRremote.hpp>
  #include "Freenove_4WD_Car_for_Arduino.h"
  
  //define key, the code can not be changed.
  #define IR_REMOTE_KEYCODE_UP      0xFF02FD
  #define IR_REMOTE_KEYCODE_DOWN    0xFF9867
  #define IR_REMOTE_KEYCODE_LEFT    0xFFE01F
  #define IR_REMOTE_KEYCODE_RIGHT   0xFF906F
  #define IR_REMOTE_KEYCODE_CENTER  0xFFA857
  
  #define IR_UPDATE_TIMEOUT     120
  #define IR_CAR_SPEED          180
  
- IRrecv irrecv(PIN_IRREMOTE_RECV);
- decode_results results;
  u32 currentKeyCode, lastKeyCode;
  bool isStopFromIR = false;
  u32 lastIRUpdateTime = 0;
  
  void setup() {
+ //Serial.begin(115200); //⭐️
-   irrecv.enableIRIn(); // Start the receiver
+   IrReceiver.begin(PIN_IRREMOTE_RECV, ENABLE_LED_FEEDBACK); // Start the receiver
  }
  
  void loop() {
-   if (irrecv.decode(&results)) {
+   if (IrReceiver.decode()) {
      isStopFromIR = false;
-     currentKeyCode = results.value;
+     currentKeyCode = IrReceiver.decodedIRData.decodedRawData;
+   //Serial.println(currentKeyCode, HEX); //⭐️
      if (currentKeyCode != 0xFFFFFFFF) {
        lastKeyCode = currentKeyCode;
      }
      switch (lastKeyCode) {
        case IR_REMOTE_KEYCODE_UP:
          motorRun(IR_CAR_SPEED, IR_CAR_SPEED); //move forward
          break;
        case IR_REMOTE_KEYCODE_DOWN:
          motorRun(-IR_CAR_SPEED, -IR_CAR_SPEED); //move back
          break;
        case IR_REMOTE_KEYCODE_LEFT:
          motorRun(-IR_CAR_SPEED, IR_CAR_SPEED);  //turn left
          break;
        case IR_REMOTE_KEYCODE_RIGHT:
          motorRun(IR_CAR_SPEED, -IR_CAR_SPEED);  //turn right
          break;
        case IR_REMOTE_KEYCODE_CENTER:
          setBuzzer(true);              //turn on buzzer
          break;
        default:
          break;
      }
-     irrecv.resume(); // Receive the next value
+     IrReceiver.resume(); // Receive the next value
      lastIRUpdateTime = millis(); //write down current time
    }
    else {
      if (millis() - lastIRUpdateTime > IR_UPDATE_TIMEOUT) {
        if (!isStopFromIR) {
          isStopFromIR = true;
          motorRun(0, 0);
          setBuzzer(false);
        }
        lastIRUpdateTime = millis();
      }
    }
  }

受信データを確認する場合は、⭐️印のコメントを外してください。

@yoshi_arduino
Questioner
誠にありがとうございます。
上記ご指摘いただいた内容で実機確認します。
また確認次第ご連絡します。

Arduino「IRremote.hpp」ライブラリを使用してラジコンを動かしたい

解決したいこと

発生している問題・エラー

該当するソースコード

自分で試したこと

2Answer

Comments

Comments

Your answer might help someone💌

Popular Questions