Go to Qiita Advent Calendar 2024 Top
LoginSignup
14
18

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

More than 5 years have passed since last update.

サムザップAdvent Calendar 2017

Day 2
@yosizo@github(katsunori yoshisue)

Jenkinsパイプラインスクリプトで簡単！Unity＋iOSビルド環境構築

Last updated at Posted at 2017-12-05

本記事はサムザップ Advent Calendar 2017の2日目の記事です。
昨日は@norimatsu_yusukeさんの「ReSharperのテンプレート機能について」でした

#はじめに
従来のJenkinsでは複数のジョブを作成し、それらを組み合わせてビルド環境を構築していましたが、Jenkins2ではGroovyスクリプトで実行できるようになり、以前に比べてビルド環境のセットアップが簡単になりました。

そこで、この記事ではJenkins2のPipelineスクリプトを使った、Unity+iOSビルド環境の構築について説明します。

※Pipelineの基本的な使い方については、こちらの記事が参考になると思います

#環境

  • Mac（OSX Sierraで動作確認）
  • Jenkins2.x（v2.7.3で動作確認）
  • Xcode（普段お使いのもの）
  • Unity（普段お使いのもの）
  • Git（普段お使いのもの）

#事前準備
まずはJenkinsを動かすPC上で下記の項目（コマンドライン、Unity、XcodeでのGitアクセスからビルド、ipa作成、キーチェーンでの認証情報設定）が正常に動作することを確認してください。
基本的に、これらがすべて動作確認できてからJenkinsのコマンドに落とし込んでいきます。
・・・というか、ここができていないと上手くいかない時に無駄に悩むことになりますので、事前にしっかり準備しましょう
##◆あらかじめ準備しておくべき項目

  • Jenkins2のインストールとワークスペースディレクトリの確認
  • gitコマンドでプロジェクトのリポジトリから正常にチェックアウトできること
  • Unityエディター上でiOS向けにビルドできること
  • ipaビルド用plistファイルの準備
  • こちらの記事（iOSアプリのビルドスクリプトを作成）を参考にビルド用のplistファイルを作成しておく
  • AppStore関連の証明書設定
  • Xcodeでビルドしたプロジェクトからアーカイブできること
  • Xcodeでアーカイブファイルからipaファイルを作成できること
  • 環境に合わせてパラメーターを設定したJenkinsスクリプトの用意
  • （サンプルのJenkinsFileをGitHubに置きました）ので、こちらを参考に自分の環境に合わせてスクリプトを修正してください。

ここまで準備できたら（まぁこれだけでも結構大変ですが…）ようやくJenkinsでの環境設定に移ります。

#ビルドパイプラインの作成
・Jenkinsに管理者権限でログインします
・Jenkinsのメニューから「新規ジョブ作成」でパイプラインを作成
sc1.jpg

sc2.jpg

・パイプラインの設定画面で下記項目を設定する

・同時ビルドの制限
General＞Do not allow concurrent builds にチェック
（Unityのビルドコマンドは同じプロジェクトに対して複数実行することはできませんので、同時にビルドが走らないようあらかじめ制限をかけておきます）
sc3.jpg

・pipeline scriptのテキストボックスにJenkinsFileスクリプトをコピーする

・スクリプトの実行制限を外す
パイプライン＞UseGroovySandboxのチェックを外す
sc4.jpg

#Jenkinsスクリプトの設定
ここでは、Jenkinsスクリプトのサンプルをベースに内容を解説していきます。

※スクリプト中のプロジェクト名やGitリポジトリ、Xcodeビルド用の各種設定項目は、それぞれの環境によって変わってきますので、必要に応じて書き換えてください。

##1・Inputステップでブランチを選択
まずはビルド対象となるブランチを選択します。
パラメーター付きビルドでやってもいいのですが、ブランチの状態を最新に保つためには管理画面でScriptを動かす等の設定が必要なので今回はInputステップでメニューを表示することにします。

def buildBranchName

stage('InputParam')
{
    // リモートからブランチの一覧を取得しプルダウンリスト用に整形する
    def branchList = sh(script: "git ls-remote --heads ${repositoryURL} | sed -e 's#.*refs/heads/##'", returnStdout: true)

    // 入力待ち状態で5分経過したらタイムアウトする
    timeout(time:5,unit:"MINUTES")
    {
        def defaultBranch = "develop"

        // デプロイセッティングの入力待ち
        def inputParam = input(
            message: 'ビルドパラメーターをセットしてください',
            ok: 'ビルド開始',
            parameters: [
                [$class:"ChoiceParameterDefinition",
                    name: 'branchName',
                    choices: branchList,
                    defaultValue: defaultBranch,
                    description: 'ビルド対象のブランチを選択してください'
                ],
            ])

        // 取得したブランチ名を変数に保存
        buildBranchName = inputParam.branchName
    }
}

ChoiceParameterDefinition クラスでプルダウンメニューを表示していますが、改行で区切られた文字列を渡す必要があるので、こちらの記事のやり方で一覧を取得しています

またここでは、入力待ちの状態で他の人がビルドできなくなることを防ぐため、timeoutブロックを利用して一定時間が経過したら自動的にビルドが失敗するように設定しています。

timeout(time:5,unit:"MINUTES")
{
（何かの処理）
}

##2・Gitからブランチをチェックアウトする
次にGitステップを使ってブランチからチェックアウトします。
※お使いの環境に合わせて証明書などの設定は済ませておいてください。

// ビルド対象リポジトリ
def repositoryURL = 'https://[your_build_target_project_repository].git'

// ローカルリポジトリディレクトリ名
def repositoryName = "[your_repository_name]"

stage('Git') {
    dir (repositoryName) {
        // ブランチをチェックアウト
        git( branch: buildBranchName, url: repositoryURL)
    }
}

##3・Unityバッチビルドを行う
基本的にこのステージではバッチビルド用のコマンド文字列を生成し、シェルステップで実行しているだけです。

Unityのバッチビルドモードを利用してビルドを行うためには、事前にUnityプロジェクト側でバッチビルド用のクラスを追加する必要があります。
参考：
コマンドラインからUnityのビルドを走らせる。 -基礎編-
UnityのBatchBuildについて
[Unityのプロジェクトをコマンドラインからビルドする]
(https://tyfkda.github.io/blog/2015/07/04/unity-build-from-shell.html)

このビルドコマンドについては、プロジェクトによって大きく変わる部分だと思いますので、まずはJenkinsを動かすPCのコマンドラインでバッチビルドができることを確認し、そのコマンドを元にJenkins側のスクリプトを書き換えるのが効率が良いと思います。

// Unityプロジェクト名
def projectName = "[your_project_name]"

// GitステップでチェックアウトされるUnityプロジェクトのパス
def projectPath = "${WORKSPACE}/${repositoryName}/${projectName}"

stage('Unity Build')
{
    // UnityコマンドPath
    def unityPath = "/Applications/Unity/Unity.app/Contents/MacOS/Unity"
    // Unityビルドスクリプトクラス名
    // ※ここはUnity側に設置したバッチビルド用クラスとメソッド名を指定してください
    def executeMethod = "BuildBatchClass.BuildMethod"
    // ビルドターゲット
    def buildTarget = "ios"

    // UnityのバッチビルドでXcodeプロジェクトをビルドするためのコマンド文字列を作成
    def buildCommand = "${unityPath} -quit -batchmode"
    buildCommand += " -executeMethod ${executeMethod}"
    buildCommand += " -projectPath ${projectPath}"
    buildCommand += " -buildTarget ${buildTarget}"

    // ビルドコマンドを実行
    sh(script: buildCommand)
}

##4・XCodeでビルドする
UnityBuildと同様、基本的にこのステージではビルド用のコマンド文字列を生成し、シェルステップで実行しているだけです。

参考：
iOSアプリのビルドスクリプトを作成
Xcodeでのビルドを自動化するxcodebuildコマンドとIPAファイルを作成してiTunes Connect(Testflight)に投げる方法
macOSアプリのCI事情5 – xcodebuildでxcarchiveを作る

stage('xcode build')
{
    // XcodeプロジェクトPath
    def xcodeprojDir = "${projectPath}/iOS/"
    def xcodeproj = "${xcodeprojDir}Unity-iPhone.xcodeproj"

    // 設定項目（必要に応じて適宜設定してください）
    def bundleID = "xxxxxxxxx"
    def displayName = "xxxxxxxxxxxxx"
    def versionNumber = "xxxxxxxxxxxxx"
    def BuildNumber = "xxxxxxxxx"

     // Plistbuddyで設定項目を書き換える
    sh("/usr/libexec/Plistbuddy -c \"Set CFBundleIdentifier ${bundleID}\" ${xcodeprojDir}Info.plist")
    sh("/usr/libexec/Plistbuddy -c \"Set CFBundleDisplayName ${displayName}\" ${xcodeprojDir}Info.plist")
    sh("/usr/libexec/Plistbuddy -c \"Set CFBundleShortVersionString ${versionNumber}\" ${xcodeprojDir}Info.plist")
    sh("/usr/libexec/Plistbuddy -c \"Set CFBundleVersion ${BuildNumber}\" ${xcodeprojDir}Info.plist")

    // ビルド環境をクリーン
    sh(script: "xcodebuild clean -project ${xcodeproj}")

    // XcodeBuildコマンドでアーカイブ作成
    def developmentTeamName = "xxxxxxxxxxxxxx"
    def provisioningProfilerSpecifier = "xxxxxxxxxxxxxxx"

    sh(script: "xcodebuild archive -project ${xcodeproj} -archivePath ${archivePath} -configuration Develop -scheme Unity-iPhone -sdk iphoneos10.3 CODE_SIGN_IDENTITY=\"iPhone Distribution\" PROVISIONING_PROFILE_SPECIFIER=${provisioningProfilerSpecifier} DEVELOPMENT_TEAM=${developmentTeamName}")
}

ここではPlistBuddyというOSXのツールを使ってXcodeのinfo.plistファイルの内容を書き換えています。
アプリの表示名やバージョンなどinfo.plistの項目をビルドごとに変更したい場合はここで行うのが簡単でしょう。
参考：PlistBuddyの使い方

sh("/usr/libexec/Plistbuddy -c \"Set CFBundleIdentifier ${bundleID}\" ${xcodeprojDir}Info.plist")

また、ビルドコマンドを動作させるためにDEVELOPMENT_TEAMなどの値が必要になりますので、下記のコマンドで取得してください。

xcodebuild -showBuildSettings -project {プロジェクト名}.xcodeproj

参考：
[Xcode] CIなどを使用するときに必要な値を確認する方法

##5・ipaファイルのビルド

stage('ipa export')
{
    // ipaビルド設定ファイルPath
    def exportOptionFile = "${WORKSPACE}/build/buildparams/exportOptions.plist"

    // XcodeアーカイブPath
    def archivePath = "${projectPath}/iOS/build/${projectName}.xcarchive"

    // ipa出力先
    def exportDir = "${WORKSPACE}/export/${BUILD_NUMBER}/"
    def exportFileName = "${projectName}_${BUILD_NUMBER}.ipa"

    // exportディレクトリがなければ作成
    dir ('export') {
        // XcodeBuildコマンドでipa作成
        sh(script: "xcodebuild -exportArchive -archivePath ${archivePath} -exportPath ${exportDir} -exportOptionsPlist ${exportOptionFile}")

        if( fileExists("${BUILD_NUMBER}/Unity-iPhone.ipa") )
        {
            // そのままだと毎回、Unity-iPhone.ipaというファイルが生成されるので、アーカイブ用にリネーム
            sh(script:"mv ${BUILD_NUMBER}/Unity-iPhone.ipa ${BUILD_NUMBER}/${exportFileName}")

            // アーカイブ
            archiveArtifacts(artifacts: "${BUILD_NUMBER}/${exportFileName}", onlyIfSuccessful: true)
        }
    }
}

##6・おまけ／Chatworkへの投稿
ビルドが完了したことをChatworkに投稿したい場合は以下の記事を参考にステップを追加してください
[Jenkins2のPipelineScriptでChatworkに投稿する
]
(https://qiita.com/yosizo@github/items/a9b98094f014657f7384)
※ビルド番号やスクリプトの結果などをメッセージに追加しておくと読みやすくなると思います。

#まとめ
いかがでしたでしょうか。
一度環境さえ作ってしまえばコピ＆ペーストで簡単にビルド環境を複製できますし、ビルドのパラメーターもGroovyスクリプトで設定できますので（Jenkins職人がいなくても）状況に合わせたビルド環境を複製できます。

また、今回の記事ではJenkinsFileを管理画面から設定しましたが、GitリポジトリからJenkinsFileを取得する事も可能ですのでぜひチャレンジしてみてください。

開発中によくある「これ、実機で動作確認したいんだけど・・・」で作業を中断される悩みから解放され、快適なCIライフを送りましょう。

#さいごに
「パイプラインスクリプトで簡単と言ったな。」

「あれは嘘だ。」

明日はSumzapアドベントカレンダー3日目、@yos316さんの【Unity】SimpleAnimationについてです。

14
18
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
Sign upLogin
14
18

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?