0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

Terraform Enterpriseを触ってみた -ローカルCLIからRemote Plan編-

0
Last updated at Posted at 2026-11-16

はじめに

前編では、Azure上にTerraform Enterprise(以下、TFE)の検証環境を用意しました。

今回はその続きで、手元のPCからTerraform CLIを使い、TFE上でAzureのPlanを実行してみます。先に結果を書くと、Planまでは成功しました。ただ、ApplyはService PrincipalのRBACで403となり、Storage Accountの作成までは進んでいません。

Service Principal(以下、SP)の準備からTFEへの登録、Terraformファイル、実行時に詰まったところまでを順番にまとめます。

今回の実行経路

Windows端末のTerraform CLI
  │ 構成を送信し、TFEへ実行を要求
  ▼
Terraform EnterpriseのRemote Run
  │ Terraform + AzureRM Provider
  │ WorkspaceのARM_*環境変数で認証
  ▼
Azure Resource Manager
  └─ 既存Resource Group内のStorage AccountをPlan

コマンドを打つのは手元の端末ですが、Planを処理するTerraformとProviderはTFE側の実行環境で動きます。TFEへの接続先を決めるのは cloud ブロック、Azureのリソースを操作するのはAzureRM Providerです。

検証環境

項目 検証時のバージョン・設定
TFE v202507-1 / 単一VM / Docker Compose
手元のTerraform CLI v1.17.1 / Windows amd64
TFE Remote RunのTerraform v1.12.1 / Linux amd64
AzureRM Provider v4.81.0(構成上の制約は ~> 4.0)
作成を計画するリソース Storage Account / StorageV2 / Standard / LRS / Hot

TFEが起動済みであることに加え、端末からTFEへ、Remote RunからTFEと必要な配布サイト・Azure APIへ通信できることが前提です。

なお、ここでは認証が2段階あります。混ざりやすいので、先に整理しておきます。

経路 使う情報
手元のCLI → TFE terraform login で取得するTFE API Token
TFEのRemote Run → Azure Service PrincipalのClient ID・Client Secret等

Service Principalを作成する

まずは、TFEからAzureへ接続するためのIDを用意します。

  1. Azure Portalで「Microsoft Entra ID」→「アプリの登録」→「新規登録」を開きます。
  2. 検証用の名前(例:sp-tfe-storage-poc)を付け、シングルテナントで登録します。
  3. 「概要」からClient IDとTenant IDを控えます。
  4. 「証明書とシークレット」→「クライアント シークレット」で、新しいシークレットを作成します。有効期限は組織の方針に合わせます。
  5. 対象サブスクリプションのIDも確認します。

Portalでアプリを登録すると、そのテナント内で使うService Principalも作成されます。Azureリソースのアクセス権は、後述のRBACでこのSPに割り当てます。

取得する項目 TFEに登録する変数
Application (client) ID ARM_CLIENT_ID
Client Secretの値 ARM_CLIENT_SECRET
Directory (tenant) ID ARM_TENANT_ID
Subscription ID ARM_SUBSCRIPTION_ID

Client Secretは「シークレットID」ではなく「値」を使います。値を確認できるのは作成時だけなので、安全な場所へ保管しておきます。Terraformコードやログには残しません。

スクリーンショット 2026-11-01 163830.png

Azure RBACについて

SPでAzureのリソースを操作するには、アプリ登録に加えてRBACでの権限割り当てが必要です。

検証手順では、既存Resource Groupを参照するための Reader と、Storage Account管理用の Storage Account Contributor を、対象Resource Groupの範囲に限定して割り当てる想定でした。

権限を準備する際は、対象Resource Groupの「アクセス制御(IAM)」で、割当先のSPとスコープを確認し、必要であれば管理者へ依頼します。

この記事では、実行した結果どの操作で拒否されたかを後半で確認します。

TFE WorkspaceへSP情報を登録する

TFEの対象Workspaceを開きます。

  1. 「Settings」→「General」で、Execution Modeが Remote であることを確認します。
  2. 「Variables」→「Add variable」で、次の4つを Environment variable として追加します。
  3. ARM_CLIENT_SECRET には Sensitive を設定します。
Key Value Sensitive
ARM_CLIENT_ID Client ID 組織の方針に従う
ARM_CLIENT_SECRET Client Secretの値 必須
ARM_TENANT_ID Tenant ID 組織の方針に従う
ARM_SUBSCRIPTION_ID Subscription ID 組織の方針に従う

ここはTerraform variableではなくEnvironment variableとして登録するところがポイントです。AzureRM Providerが実行環境の ARM_* を参照して認証します。Sensitiveにしていても、コードから明示的に出力するような扱いは避けます。

スクリーンショット 2026-11-01 165601.png

また、検証コードではResource Providerの自動登録を無効にしています。対象サブスクリプションで Microsoft.Storage がRegisteredであることを、事前に確認しておきます。

Windows端末からTFEへ接続する

自己署名証明書の信頼設定

前編のTFEでは自己署名証明書を使っています。SSH等の認可済み経路で公開証明書 cert.pem を端末のDownloadsへ tfe-cert.pem として取得し、別経路でフィンガープリントを照合してから登録します。秘密鍵 key.pem は取得しません。

PowerShellで実行します。

# ※ 前編で設定したTFEのFQDNと、取得した公開証明書のパスを設定
$TfeHost = 'tfe.example.com'
$CertPath = Join-Path $HOME 'Downloads/tfe-cert.pem'
Import-Certificate -FilePath $CertPath -CertStoreLocation 'Cert:\CurrentUser\Root'
(Invoke-WebRequest -Uri "https://$TfeHost/_health_check" -UseBasicParsing).StatusCode

今回の検証ではヘルスチェックが 200 で応答しました。TLSエラーになる場合は、信頼設定、証明書の期限、接続名とSANの一致を確認します。

TFEへログイン

terraform login $TfeHost

ブラウザでTokenを作成し、CLIの入力欄へ貼り付けます。TFEへのログインに成功すれば、接続側の準備は完了です。

既定では %APPDATA%\terraform.d\credentials.tfrc.json にTokenが平文保存されます。Gitや共有用バックアップには含めないでください。検証用証明書を端末で信頼させることも含め、今回は管理された検証環境での操作です。

Terraformファイルを準備する

今回は以下のファイルを同じ作業フォルダーに置きます。識別名は説明用に置き換えています。実際の環境に合わせて変更してください。

tf-storage-poc/
├── versions.tf
├── providers.tf
├── main.tf
├── variables.tf
├── outputs.tf
└── terraform.tfvars

TFEの接続先とAzureRM Provider

versions.tf では、接続するTFEとWorkspace、使用するProviderを指定します。

terraform {
  required_version = ">= 1.6.0"

  cloud {
    # ※ 自身の環境に合わせたTFEのFQDNとOrganization名を設定
    hostname     = "tfe.example.com"
    organization = "tfe-poc"

    workspaces {
      # ※ TFEに作成したWorkspace名を設定
      name = "storage-poc"
    }
  }

  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "~> 4.0"
    }
  }
}

providers.tf は以下です。SPの資格情報はWorkspaceから渡すため、ここへ直接書く必要はありません。

provider "azurerm" {
  features {}

  # Resource ProviderはAzure側で事前登録し、自動登録は行わない
  resource_provider_registrations = "none"
}

none はAzure側の権限を追加する設定ではなく、Providerによる自動登録を行わない設定です。

リソース・変数・出力

設定は少し長くなるので、ファイルごとに折りたたんでいます。

main.tf
resource "azurerm_storage_account" "poc" {
  name                = var.storage_account_name
  resource_group_name = var.resource_group_name
  location            = var.location

  account_kind             = "StorageV2"
  account_tier             = "Standard"
  account_replication_type = "LRS"
  access_tier              = "Hot"

  https_traffic_only_enabled      = true
  min_tls_version                 = "TLS1_2"
  allow_nested_items_to_be_public = false

  tags = var.tags
}
variables.tf
variable "resource_group_name" {
  description = "Storage Accountの作成先となる既存Resource Group"
  type        = string
}

variable "location" {
  description = "Storage Accountを作成するリージョン"
  type        = string
  default     = "japaneast"
}

variable "storage_account_name" {
  description = "Azure全体で一意なStorage Account名"
  type        = string

  validation {
    condition     = can(regex("^[a-z0-9]{3,24}$", var.storage_account_name))
    error_message = "英小文字・数字の3〜24文字で指定してください。"
  }
}

variable "tags" {
  description = "検証用タグ"
  type        = map(string)
  default = {
    env    = "poc"
    system = "tfe-storage-poc"
  }
}
outputs.tf
output "storage_account_id" {
  description = "Storage AccountのリソースID"
  value       = azurerm_storage_account.poc.id
}

output "primary_blob_endpoint" {
  description = "Blobエンドポイント"
  value       = azurerm_storage_account.poc.primary_blob_endpoint
}

terraform.tfvars に環境ごとの値を設定します。作成先はTFE本体とは別の既存Resource Groupです。以下の名前は例なので、実行先とStorage Account名を変更してください。

# ※ 自身の環境に合わせた既存Resource Group名・リージョンを設定
resource_group_name = "rg-storage-poc"
location            = "japaneast"

# ※ Azure全体で一意になるStorage Account名を設定
storage_account_name = "sttfepoc20991231example"

このWorkflowでは terraform.tfvars も構成と一緒にTFEへ送信されます。ファイルにはSPの認証情報を入れません。

Remote Planを実行する

PowerShellで、用意したファイルがある作業フォルダーへ移動して実行します。

# TFEとの連携とProviderを初期化する
terraform init

# 書式・構成を確認する
terraform fmt -check
terraform validate

# TFE側でPlanを実行する
terraform plan

init ではTFEとの連携とProviderの初期化、fmt と validate ではコードの書式・構成を確認します。今回の検証ではいずれも成功しました。init の成功メッセージには「HCP Terraform」と出る場合がありますが、接続先は cloud.hostname で指定したTFEです。

スクリーンショット 2026-11-13 185513.png

検証時に選択されたAzureRM Providerは v4.81.0 です。~> 4.0 は4系を許可する指定なので、同じバージョンを再現できるよう選択結果を記録する .terraform.lock.hcl は保持します。

そのままPlanまで進めたいところですが、初回は以下の2点で止まりました。

Plan成功までに詰まったところ

構成アップロードのtimeout

最初は、次のエラーが表示されました。

Error: Failed to upload configuration files: operation timed out

この表示だけ見ると、端末からのアップロードに失敗したように見えます。ただ、TFE側ログではConfiguration Versionの作成と構成アーカイブの送信が成功していました。その先を追うと、ArchivistからTFE自身へ戻る内部callbackの直後で処理が進まなくなっていました。

TFEのFQDNをPublic IPへ解決する構成だったため、TFE本体コンテナにもPrivate IPへの名前解決を追加しました。設定対象は以下の2つです。

設定 対象
Composeの services.tfe.extra_hosts TFE本体。Archivistのcallbackを含む
TFE_RUN_PIPELINE_DOCKER_EXTRA_HOSTS TerraformのRemote Runコンテナ

前編に掲載したComposeは、この2つの設定を反映したものです。反映後はRemote Runを開始できるようになりました。

Resource Groupのread権限で403

次に、既存Resource GroupのリージョンをData Sourceで取得する処理が、以下の操作で403になりました。

Microsoft.Resources/subscriptions/resourceGroups/read

今回はResource Group名とリージョンが分かっているので、その取得処理を外し、変数で直接渡す構成へ変更しました。上に載せたコードは変更後のものです。

Remote Planの結果

変更後に再実行すると、TFEでPlanを実行していることを示すメッセージ、RunのURL、Linux上のTerraformのバージョンが表示されました。ログは手元のCLIへストリーミングされます。

スクリーンショット 2026-11-13 192810.png

最後に、以下の結果を確認できました。

Plan: 1 to add, 0 to change, 0 to destroy.

Changes to Outputs:
  + primary_blob_endpoint = (known after apply)
  + storage_account_id    = (known after apply)

ここまでで、手元のCLIからTFEのRemote Runを起動し、Storage Accountを1つ作成する計画を確認できました。ただし、まだAzureリソースは作成されていません。OutputsもApply後に決まる値です。

ApplyはRBACの403で停止

続いて terraform apply も試しました。今回は保存済みPlanを使っていないため、Apply時には改めてPlanが実行され、確認後に適用へ進みます。

しかし、Storage Accountの存在確認で以下のエラーになりました。識別子を除いたエラー部分です。

Error: checking for existing Storage Account
unexpected status 403 (403 Forbidden) with error: AuthorizationFailed

Microsoft.Storage/storageAccounts/read

Resource GroupのData Sourceを外してPlanが通っても、Storage Accountの作成・管理時には事前の存在確認として read 権限が別途必要でした。

この検証では、ここからSPのロールを追加・変更する対応は行わず、Remote Plan成功までを到達点としています。

項目 結果
TFEのRemote Plan 成功
Storage Account作成 未完了(Applyが403で失敗)
作成後のState・Outputs確認 未実施
terraform destroy 未実施

さいごに

SPの情報をTFE Workspaceへ登録し、手元のTerraform CLIからRemote Planを実行できました。CLI側は普段の terraform plan ですが、実行場所はTFE側という流れを確認できています。

一方で、今回は最初にResource Groupのread、次にStorage Accountのreadと、段階ごとに異なる操作で403になっています。

必要な権限はロール名だけで判断せず、対象SPと割当スコープ、Providerが実際に呼ぶ操作を照らし合わせる必要がありそうです。権限変更後のApplyはまだ検証していないため、続きとして残します。

参考資料

0
0
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?