1
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

【Salesforce】Google Calendar APIを触ってみる!ApexからGoogleカレンダーに予定を登録するハンズオン

1
Posted at

はじめに

前回は、Googleカレンダーの予定をSalesforceから取得しました。

今回はその逆です。

Salesforceの行動レコードをGoogleカレンダーに登録してみます。

前回のハンズオンで作成したOAuth認証や指定ログイン情報を再利用するので、比較的簡単に実装できます。

前回の記事はこちらです。

【Salesforce】Google Calendar APIを触ってみる!ApexからGoogleカレンダーの予定を取得するハンズオン

今回のゴール

Salesforceの行動(Event)に登録した予定を、Googleカレンダーに登録します。

image.png

今回はApexの匿名実行で予定を1件登録します。

1. 事前準備

必要なものは以下のとおりです。

準備するもの 用途
Trailhead Playground Salesforce開発環境
Googleアカウント 予定の登録先
指定ログイン情報 OAuth認証とAPI接続

Google CloudやSalesforceの認証設定は、前回の記事で作成したものを使用します。

まだ設定していない場合は、先に前回の記事を実施してください。

2. Google Calendar APIの権限を変更する

前回は、Googleカレンダーの予定を取得する読み取り専用の権限を使用しました。

今回は予定を登録するために、OAuthスコープを変更します。

操作 OAuthスコープ
予定の取得 calendar.events.readonly
予定の登録・更新・削除 calendar.events

Google Cloud Consoleの「Google Auth Platform」→「データアクセス」を開きます。

「スコープを追加または削除」から、次のスコープを追加してください。

https://www.googleapis.com/auth/calendar.events

image.png

Salesforceの設定画面を開きます。

「指定ログイン情報」→「外部ログイン情報」から、前回作成した GoogleCalendarOAuth を開きます。

プリンシパルの GoogleUser に設定した範囲(スコープ)を修正します。

項目 設定値
パラメーター名 GoogleUser
IDタイプ ユーザーごとのプリンシパル
連番 1
範囲 https://www.googleapis.com/auth/calendar.events

image.png

保存したら、GoogleアカウントのOAuth認証を再実行してください。

これで、Googleカレンダーに予定を登録する準備ができました。

3. Salesforceに行動を作成する

Salesforceにテスト用の行動を登録します。

Trailhead Playgroundを開き、カレンダーなどから新しい行動を作成してください。

例:

項目 値
件名 Googleカレンダー連携テスト
開始日時 明日の10:00
終了日時 明日の11:00
割り当て先 自分のSalesforceユーザー

4. Apexクラスを作成する

Salesforceの「設定」→「Apexクラス」→「新規」を開きます。

次のコードを貼り付けて保存してください。

public with sharing class GoogleCalendarInsertService {

    public static void insertEvent() {

        // 自分が作成した最新の行動を取得
        Event ev = [
            SELECT Id, Subject, StartDateTime, EndDateTime
            FROM Event
            WHERE OwnerId = :UserInfo.getUserId()
            AND IsAllDayEvent = false
            AND StartDateTime != null
            AND EndDateTime != null
            ORDER BY CreatedDate DESC
            LIMIT 1
        ];

        // Googleカレンダーに登録するデータ
        Map<String, Object> eventData =
            new Map<String, Object>();

        eventData.put('summary', ev.Subject);

        eventData.put('start', new Map<String, String>{
            'dateTime' => ev.StartDateTime.formatGmt(
                'yyyy-MM-dd\'T\'HH:mm:ss\'Z\''
            )
        });

        eventData.put('end', new Map<String, String>{
            'dateTime' => ev.EndDateTime.formatGmt(
                'yyyy-MM-dd\'T\'HH:mm:ss\'Z\''
            )
        });

        // HTTPリクエスト
        HttpRequest req = new HttpRequest();

        req.setEndpoint(
            'callout:GoogleCalendarAPI' +
            '/calendar/v3/calendars/primary/events'
        );

        req.setMethod('POST');
        req.setHeader('Content-Type', 'application/json');
        req.setBody(JSON.serialize(eventData));
        req.setTimeout(20000);

        // Google Calendar APIを呼び出す
        HttpResponse res = new Http().send(req);

        System.debug('ステータスコード:' + res.getStatusCode());
        System.debug('レスポンス:' + res.getBody());

        if (res.getStatusCode() != 200 &&
            res.getStatusCode() != 201) {

            throw new CalloutException(
                'Google Calendar API Error: ' +
                res.getStatusCode() + ' / ' + res.getBody()
            );
        }
    }
}

コードを簡単に解説

押さえておきたいポイントは3つです。

① Salesforceの行動を取得する

Event ev = [
    SELECT Id, Subject, StartDateTime, EndDateTime
    FROM Event
    WHERE OwnerId = :UserInfo.getUserId()
    AND IsAllDayEvent = false
    AND StartDateTime != null
    AND EndDateTime != null
    ORDER BY CreatedDate DESC
    LIMIT 1
];

SOQLでSalesforceの行動を取得します。

今回取得する項目は、件名・開始日時・終了日時です。

② Googleに送信するJSONを作成する

eventData.put('summary', ev.Subject);

Salesforceの Subject をGoogleカレンダーの件名に設定します。

開始日時と終了日時も同様に設定しています。

③ POSTメソッドで予定を登録する

req.setMethod('POST');

前回の記事では、予定を取得するために GET メソッドを使用しました。

今回は予定を新しく登録するため、POST メソッドを使用します。

Google Calendar APIのエンドポイントはこちらです。

POST /calendar/v3/calendars/primary/events

primary は、認証したGoogleアカウントのメインカレンダーを意味します。

5. Apexの匿名実行で動作確認する

いよいよ実行です!

開発者コンソールで「Debug」→「Open Execute Anonymous Window」を開きます。

次のコードを入力してください。

GoogleCalendarInsertService.insertEvent();

「Open Log」にチェックを入れて実行します。

正常に登録できると、デバッグログに以下のような内容が表示されます。

image.png

Google Calendar APIの予定作成が成功すると、200 OK が返されます。

レスポンスには、Google側で作成された予定のIDや件名などが含まれます。

続いて、Googleカレンダーを開いてください。

Salesforceに作成した行動が、Googleカレンダーにも表示されていれば成功です!

image.png

まとめ

Salesforceの行動をGoogleカレンダーに登録しました。

前回との違いをまとめます。

項目 前回 今回
連携方向 Google → Salesforce Salesforce → Google
HTTPメソッド GET POST
OAuth権限 読み取り 書き込み可能
Apexの処理 JSONを取得 JSONを送信

認証やAPI接続先の設定を再利用できるので、思ったより簡単だったのではないでしょうか。

Salesforceから外部サービスにデータを送信する基本的な仕組みは、他のAPI連携でも応用できます。

最後まで読んでいただきありがとうございました!

1
0
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
1
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?