IchigoJam で3分タイマー

IchigoJamでタイマー

IchigoJam についてはIchigoJam の紹介と OS X で使う方法のまとめで紹介していますが、そのキャラクター表示のディスプレィで数字を大きく表示するタイマーを作ってみました。

実はパクリ

数字を大きく表示する部分は、Facebook内のグループ「IchigoJam-FAN」の Hidetaka Hayakawa さん作成の「時計」から、時間のカウントダウン部分は 志賀 慶一 さんの「3分タイマー」からパクりました。
なので、このプログラムをソースを公開することにしました。

スクリーンショット

プログラムのソース

10 行の T=3 が3分を指定していますので、この数値を変えるとタイマーの時間を変えられます。
圧電サウンダが付いていたら、420行のREMを消すとブザーも鳴らせます。

3minTimer.bas

5 REM 3min Timer By Y.NOMURA
10 T=3:C=60
20 [0]=31599:[1]=4681:[2]=29671:[3]=29647:[4]=23497
30 [5]=31183:[6]=31215:[7]=29257:[8]=31727:[9]=31695:[10]=0
40 CLS:CLT:LED 0:M=3:S=0:H=M:B=S
50 GOSUB250:LC13,9:? CHR$(1):LC13,11:? CHR$(1):GOSUB200
60 W=T*60*C-TICK()
70 IF W<=0 GOTO 400
80 S=W/C:M=S/60:S=S%60
90 IF H>M THEN H=M:GOSUB250
100 IF B<>S THEN B=S:GOSUB200
110 GOTO 60

200 IF S<10 N=0:X=15:GOSUB 300
220 IF S>=10 N=S/10:X=15:GOSUB 300
230 N=S%10:X=19:GOSUB 300:RETURN

250 X=8:N=M%10:GOSUB 300:RETURN

300 D=[N]>>12&7:LC X,8:?CHR$(D&4>0);CHR$(D&2>0);CHR$(D&1);
310 D=[N]>>9&7:LC X,9:?CHR$(D&4>0);CHR$(D&2>0);CHR$(D&1);
320 D=[N]>>6&7:LC X,10:?CHR$(D&4>0);CHR$(D&2>0);CHR$(D&1);
330 D=[N]>>3&7:LC X,11:?CHR$(D&4>0);CHR$(D&2>0);CHR$(D&1);
340 D=[N]>>0&7:LC X,12:?CHR$(D&4>0);CHR$(D&2>0);CHR$(D&1);:RETURN

400 LC10,15:?"TIME UP!"
410 I=0
420 LED(I&1):REM BEEP(2)
430 IF I<10 THEN I=I+1:WAIT(30):GOTO 420
440 LED 0
450 END