日常の開発作業を効率化するために、ゲーミングマウスを電気街に見に行きました。
しかしながら意外と高かったので、購入を断念しました。
中古を探せたら良かったのですが、今回は見つけられませんでした。
そこで今回は、ダイソーで 300 円で売っていた
戻る・進む機能のあるマウスを購入して、以下のように割り当てる bat ファイルを紹介したいと思います。
- 戻るボタン → Ctrl + C → Ctrl + Shift + V（コピー＆プレーン貼り付け）
- 進むボタン → Esc ボタンを 1 秒間押す（マウス位置通知ツールとの連携用）
操作手順
- 戻る・進むボタンのあるマウスを購入する
- AutoHotkey v2 をダウンロード してインストールする
- この bat ファイル を Windows のスタートアップフォルダに入れる
- この記事 の内容を反映して、スタートアップフォルダに設定する
以上の流れで、戻る・進む機能付きマウスを
- Ctrl + C → Ctrl + Shift + V（コピー＆プレーン貼り付け）
-
Esc ボタンを 1 秒間押す（マウス位置通知ツール連携）
に対応させることができます。
bat ファイルを直接公開するとウイルス判定される場合があるため、以下に内容を掲載しておきます。
もしダウンロードがブロックされた場合はこちらをご利用ください。
マウスの進む戻るのオーバーライド.bat
@echo off
setlocal EnableExtensions
rem === AutoHotkey v2 実行ファイルを探索 ===
set "AHKEXE="
for %%A in (
"%ProgramFiles%\AutoHotkey\v2\AutoHotkey64.exe"
"%ProgramFiles%\AutoHotkey\AutoHotkey64.exe"
"%ProgramFiles%\AutoHotkey\AutoHotkey.exe"
"%ProgramFiles(x86)%\AutoHotkey\AutoHotkey.exe"
) do (
if not defined AHKEXE if exist "%%~A" set "AHKEXE=%%~A"
)
if not defined AHKEXE (
echo [ERROR] AutoHotkey v2 が見つかりません。手動インストール先のパスを上の一覧に追記してください。
echo 例: "C:\Program Files\AutoHotkey\v2\AutoHotkey64.exe"
pause
exit /b 1
)
rem === AHK スクリプトを書き出し（純バッチ・複数行）===
set "AHKFILE=%TEMP%\BackCancelPaste.ahk"
(
echo #SingleInstance Force
echo.
echo XButton1:: {
echo Send "^c"
echo Sleep 80
echo Send "^+v"
echo }
echo.
echo XButton2:: {
echo Send "{Esc down}"
echo Sleep 1000
echo Send "{Esc up}"
echo }
) > "%AHKFILE%"
if not exist "%AHKFILE%" (
echo [ERROR] AHK スクリプトの生成に失敗しました。
pause
exit /b 1
)
rem === 常駐起動 ===
start "" "%AHKEXE%" "%AHKFILE%"
echo 常駐開始：戻る=Ctrl+C→Ctrl+Shift+V、進む=Esc
exit /b 0
もしかすると、人によっては「戻る」と「進む」の挙動を逆にした方が使いやすいと感じる場合もあるかもしれません。
その場合は、bat ファイルの内容を修正してご利用ください。
Copilot を開く場合は
Send "{LWin down}c{LWin up}"
です。
設定欄でこのショートカットを押した時に開くアプリを変更できます。
Ctrl + C → Ctrl + Shift + V を思ったより使わなかったため、私はこの記述で ChatGPT を起動するように設定しています。
まとめ
今回は「マウスの戻る・進む機能をオーバーライドする方法」を紹介しました。
マウスを見失ったときに、進むボタンでマウス位置通知ツールを動作させる、という活用も可能です。
開発作業の効率化やちょっとした快適化にぜひ検討いただければ幸いです。
閲覧ありがとうございました。
追記
この記事は ChatGPT で添削しています。
生成 AI による添削が苦手な方は申し訳ありません。