"vlc で wma ファイルを mp3 ファイルに変換するバッチファイル" の
wma を wav に変えただけのスクリプト。
曲名等の情報はひきつがれないので注意。
wav ファイルがあるフォルダに置いてダブルクリック。 管理者権限は要らない。
VLC は
http://download.videolan.org/pub/videolan/vlc/3.0.9.2/win64/vlc-3.0.9.2-win64.zip
を使えばインストール不要。 ポータブル版。 だけどバッチファイルの vlc.exe の場所を
合わせること。
(実行環境： Windows10, Window7 等)
wav_mp3.bat
@echo off
color 1f
cd /d %~dp0
set VLC="C:\Program Files (x86)\VideoLAN\VLC\vlc.exe"
if not exist %VLC% set VLC="C:\Program Files\VideoLAN\VLC\vlc.exe"
if not exist %VLC% set VLC="%~d0\vlc\vlc.exe"
if not exist %VLC% (
echo.
echo.VLC.EXE がありません。
echo.
pause
goto :eof
)
@rem エラー起きるときがあるのでダミー設定しとく。
set OUTFL=aa
echo.
echo.フォルダ内の wav ファイルを mp3 ファイルに変換します。
echo.
pause
@rem VLC が起動していると変換できないので強制的に終了させる
> nul 2>&1 taskkill /f /im vlc.exe
setlocal enabledelayedexpansion
for %%a in (*.wav) do (
set INFL="%%a"
set OUTFL=!INFL:~0,-5!.mp3"
%VLC% --no-repeat --play-and-exit -I dummy -vvv !INFL! --sout #transcode{vcodec=none,acodec=mp3,ab=192,channels=2,samplerate=44100}:file{dst=!OUTFL!} vlc://quit
if exist !OUTFL! (
echo.!OUTFL!
) else (
echo.失敗： !INFL!
)
)
color 0f
pause
goto :eof