vlc で wma ファイルを mp3 ファイルに一括変換するバッチファイル

音楽再生ソフトの VLC を使って wma ファイルを mp3 ファイルに一括変換するバッチファイル。
xxx.wma を ⇒ xxx.mp3 に変換する。
こんなん ぐぐればあるだろ、と思ったけど すぐに見つからなかったので作った。
せっかくなので置いとく。
曲名等の情報はひきつがれないので注意。

wma ファイルがあるフォルダに置いてダブルクリック。 管理者権限は要らない。
(Windows10, Window7 等)

wma_mp3.bat

@echo off
color 1f
cd /d %~dp0
set VLC="C:\Program Files (x86)\VideoLAN\VLC\vlc.exe"
if not exist %VLC% set VLC="C:\Program Files\VideoLAN\VLC\vlc.exe"
if not exist %VLC% set VLC="C:\vlc\vlc.exe"
if not exist %VLC% (
  echo.
  echo.VLC.EXE がありません。
  echo.
  pause
  goto :eof
)

@rem エラー起きるときがあるのでダミー設定しとく。
set OUTFL=aa

echo.
echo.フォルダ内の wma ファイルを mp3 ファイルに変換します。
echo.
pause

@rem VLC が起動していると変換できないので強制的に終了させる
> nul 2>&1 taskkill /f /im vlc.exe

setlocal enabledelayedexpansion
for %%a in (*.wma) do (
  set INFL="%%a"
  set OUTFL=!INFL:~0,-5!.mp3"

  %VLC% --no-repeat --play-and-exit -I dummy -vvv !INFL! --sout #transcode{vcodec=none,acodec=mp3,ab=192,channels=2,samplerate=44100}:file{dst=!OUTFL!} vlc://quit
  if exist !OUTFL! (
    echo.!OUTFL!
  ) else (
    echo.失敗： !INFL!
  )
)

color 0f
pause
goto :eof

（無料 アプリ フリーウェア フリーソフト）