0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

自前実装abbrを改善してみた

0
Posted at

はじめに

以前にZLE の仕組みを「語・展開・略」に分解して学びながら、
https://zenn.dev/sanmal/articles/ae436db04b5be0
という記事で、zsh 組み込みの _expand_alias ウィジェットを使った自前 abbr を約 40 行で実装しました。

あれから実際に .zshrc に組み込んで日常的に使ってみたところ、いくつかの不便さや設計上の問題に気づきました。
本記事は、それらを解消するために実装を改善した経緯の記録です。

改善後のコードは dotfiles リポジトリ で公開しています。

変更の全体像

項目 前回(記事版) 今回(改善版)
展開方式 zle _expand_alias(alias テーブル経由) LBUFFER 直接書き換え
データ保持 キーのみ + alias テーブル キー + 展開先文字列(自己完結)
ファイル構成 .zshrc に全部記述 仕組み・略語定義・alias 定義を分離
Enter フック なし あり(マーカー時は実行抑制)
運用補助 なし abbr-list / abbr-unset

なぜ変えたのか ── 使って分かった 3 つの課題

課題 1: alias テーブルとの二重管理

前回の実装ではabbr()関数の内部でaliasを呼んでいました。

# 前回の実装
abbr(){
    alias "$@"
    ZSH_ABBR_MAP[${1%%=*}]=1
}

しかし実際に運用してみると、略語はZSH_ABBR_MAP(連想配列)と alias テーブルの両方に存在する状態となります。
略語を削除したい場合、unset "ZSH_ABBR_MAP[gst]"とunalias gstの両方を実行しなければなりません。
片方だけ消すと、連想配列に存在するが alias テーブルにはない(またはその逆の)不整合が起きてしまいます。

さらに、aliases.zshで環境設定用の alias (alias ls='ls --color=auto'など)を管理していると、「この alias は略語なのか、環境設定なのか」の境界が alias テーブル上で混ざります。
aliasコマンドで一覧表示した時に、略語も環境設定も同じ場所に出てきて区別ができません。

そこで改善版では辞書登録のみの関数に変更しています。

# 改善版の登録関数(aliasを呼ばず辞書登録のみ)
abbr() {
    local key="$1"
    shift
    ZSH_ABBREVIATIONS[$key]="$*"
}

課題 2: _expand_aliasへの依存

_expand_aliasは zsh の補完システム( compsys )が提供するウィジェットで、alias テーブルの内容をそのまま展開してくれる便利な存在でした。
しかし、補完システムに依存してるということは、compsys の初期化タイミングや設定の影響を受ける可能性があるということでもあります。

自分の環境(Pop!_OS 24.04 LTS)ではたまたま問題なく動いていましたが、展開の挙動を完全にコントロールしたいなら、alias テーブルと_expand_aliasを経由せず、自前の連想配列から直接文字列を取り出してバッファを書き換えるほうが確実と判断しました。

課題 3: .zshrcの肥大化

前回は仕組み(ウィジェット定義・キーバインド)、略語定義、alias 定義をすべて.zshrcに入れていました。
略語を追加するたびに.zshrcのdiffが発生し、chezmoiで管理していると「仕組みの変更」と「略語の追加」が同じファイルの差分に混ざってしまいます。


何を変えたか ── 実装の改善

改善 1: LBUFFER直接書き換えによる展開

前回の展開:

# 前回: _expand_alias に委譲
if (( ${+ZSH_ABBR_MAP[$word]} )); then
    zle _expand_alias
fi

改善後の展開:

# 改善後: 自前で LBUFFER を書き換え
local expansion="${ZSH_ABBREVIATIONS[$word]}"
if [[ -n "$expansion" ]]; then
    LBUFFER="${LBUFFER%$word}$expansion"
fi

${LBUFFER%$word}はLBUFFERの末尾から$wordを削除するパラメータ展開で、そこに$expansion(展開先の文字列)を連結することで略を置換しています。

この変更により、alias テーブルを経由せずに展開が完結するようになりました。
連想配列ZSH_ABBREVIATIONSがキーと展開先の両方を持つので、データの管理が一箇所で済みます。

# 前回: キーだけ保持、展開先は alias テーブルに
ZSH_ABBR_MAP[gst]=1

# 改善後: キーと展開先を両方保持
ZSH_ABBREVIATIONS[gs]="git status -sb"

改善 2: emulate -L zshによる防御

改善版の展開関数には冒頭に emulate -L zsh を追加しています。

_zsh_abbr_expand() {
    emulate -L zsh
    # ...
}

これは「この関数内で zsh のデフォルト設定を強制する」宣言です。
-Lは関数ローカルスコープに限定する意味で、関数の外には影響しません。

前回の記事を書いた時点では気にしていなかったのですが、実際に他のプラグイン(zsh-syntax-highlighting や zsh-autosuggestions など)と共存させると、プラグインがsetoptで変更したシェルオプションが自前ウィジェットの挙動に影響する可能性があります。
たとえばsetopt extended_globが有効だと、パラメータ展開中の#や%の解釈が変わり得ます。

emulate -L zshはこの干渉を遮断する防御壁です。
使ってみて初めて必要性に気づいた部分で、前回の記事の時点では見落としていた観点でした。

改善 3: 区切り文字の設計判断

前回の実装でもカーソル直前の単語を抽出するコードはありましたが、
抽出した単語は連想配列の検索にのみ使い、展開自体は_expand_aliasに丸投げしていました。
そのため区切り文字の選択が多少不正確でも_expand_aliasが正しく処理してくれていました。

しかし改善版では抽出した単語をそのままLBUFFERの書き換えに使うため、
区切り文字の精度が展開の正確性を直接左右するようになります。

改善版の初期実装では区切り文字を空白のみに簡略化していました。

# 改善版の初期実装: 空白のみを区切りとした
local word="${LBUFFER##*[[:space:]]}"

これだとecho hello;gs<Space>のように;の直後に略語を打った場合、
wordが;gsになってしまい展開されません。

これは_expand_aliasを使わなくなったことで引き受けた責務です。
対応として区切り文字にセミコロン;、パイプ|、&、(を追加しました。

# 空白・セミコロン・パイプ・&&/||・サブシェルの ( を区切りとし、
# 直前の単語(コマンド位置の文字列)を抽出する
local word="${LBUFFER##*[[:space:];|&(]}"

改善 4: Enterフックとマーカー時の実行抑制

前回の記事では Enter フックを発展として触れるだけで実装には含めていませんでした。
改善版ではデフォルトで Enter にもフックしています。

_zsh_abbr_expand_and_accept() {
    _zsh_abbr_expand
    if (( _zsh_abbr_cursor_target >= 0 )); then
        CURSOR=$_zsh_abbr_cursor_target
    else
        zle accept-line
    fi
}

ここで重要なのは、_zsh_abbr_cursor_target >= 0の分岐です。
カーソル位置マーカー(%)がある場合、accept-line(コマンド実行)を呼ばない設計にしています。

これは、jc<Enter>でjj commit -m"%"に展開された後、カーソルが位置マーカーの中に移動した状態で即accept-lineが呼ばれると、空のコミットメッセージで実行されてしまうからです。

「マーカーがある = まだ入力が完了していない」という意味を持たせることで、展開後にそのままメッセージを打ち続けることができます。
メッセージを書き終えたら改めて Enter を押せば、その時にはマーカーが存在していないのでaccept-lineが正常に呼ばれます。

前回の記事ではカーソルマーカーと Enter フックを別々の「発展」として扱っていたので、この相互作用に気づけていませんでした。
両方を組み合わせて実際に使用したことで初めて分かった設計判断でした。

改善 5: 展開抑制キーの変更

前回はCtrl+Spaceにmagic-space(展開抑制用 Space)を割り当てていました。

# 前回
bindkey -M main  '^ ' magic-space

改善版では Ctrl+X Space に変更し、magic-space の代わりに単純な Space 挿入にしています。

# 改善版
_zsh_abbr_no_expand_space() {
    LBUFFER+=' '
}
bindkey -M viins '^X '  _zsh_abbr_no_expand_space

変更理由は2つあります。
1つ目はCtrl+SpaceはIMEの切り替えや他のアプリケーションで使われる事が多く干渉しやすい点。
2つ目はmagic-spaceの履歴展開(!!など)は自分の運用では不要だった点。
zsh の emacs キーマップでは ^X に続く複合キー(^Xa で _expand_alias、^Xu で undo 等)が複数デフォルトバインドされており、ユーザー定義のキーバインドを追加しても既存のバインドと衝突しにくいと判断してCtrl+X Spaceを使用しました。

改善 6: 運用補助コマンドの追加

前回の実装には「登録済みの略語を確認する手段」がありませんでした。
日常的に使い始めると「この略語登録してたっけ?」「なんに展開されるんだっけ?」と確認したくなる場面が出てきました。

# 一覧表示
abbr-list() {
    local k
    for k in "${(@ok)ZSH_ABBREVIATIONS}"; do
        printf "%-10s => %s\n" "$k" "${ZSH_ABBREVIATIONS[$k]}"
    done
}

# 削除
abbr-unset() {
    unset "ZSH_ABBREVIATIONS[$1]"
}

前回の実装で略語を削除するにはunset "ZSH_ABBR_MAP[gst]"とunalias gstの2コマンドが必要でした。それが面倒で直接.zshrcを書き直すことになっていました。
改善版はabbr-unset gsの 1 コマンドで済みます。
alias テーブルとの二重管理を解消した判断基準でもあります。


定義ファイルの分離

改善版では、以下の4ファイルに分離しています。

ディレクトリ構成
~/.config/zsh/
├── abbr.zsh            # 展開の仕組み(ウィジェット・キーバインド)
├── abbreviations.zsh   # 略語定義のみ
├── aliases.zsh         # alias 定義のみ
└── functions.zsh       # シェル関数

.zshrc からは source で読み込むだけです。

# ~/.zshrc(関連部分のみ)
source ~/.config/zsh/abbr.zsh
source ~/.config/zsh/abbreviations.zsh
source ~/.config/zsh/aliases.zsh
source ~/.config/zsh/functions.zsh

分離の利点

変更の diff が明確になる

略語を 1 つ追加しただけで、.zshrc全体の diff が出ていたのが、abbreviations.zshだけの差分に収まります。
chezmoi で管理している場合、「どういった目的で変更したか」がファイル名から分かりやすくなります。

仕組みと定義の変更頻度が異なる

abbr.zsh(仕組み)はめったに変わりません。
一方で、abbreviations.zsh(略語定義)は新しいツールを導入したり、使っているうちに追加されていきます。
変更頻度の異なるものを分離しておくと、差分が明確になり管理しやすくなります。単一責任の原則に近い考え方ですね。

alias との責務分離

aliases.zshには「コマンドの動作を常時変更するもの」(alias rm='rm -i'など)だけが入り、abbreviations.zshには「タイピング節約 + 実コマンドの可視化」を目的としたものだけが入っています。
前回の記事で議論した「展開すべき alias の選別」がファイルレベルで分かれる形になりました。


zsh-abbr との比較(再び)

前回の記事でも zsh-abbr との比較を行いましたが、実装方式が変わったことで評価が若干変わる部分がでてきます。

改善版で縮まった差

項目 前回の自前実装 改善版 zsh-abbr
一覧表示 × ○(abbr-list) ○
削除 2 コマンド必要 1 コマンド(abbr-unset) 1 コマンド
Enter フック なし あり あり
alias との独立性 二重管理 完全独立 完全独立
他プラグインとの干渉防御 なし emulate -L zsh あり

依然として zsh-abbr が優れている点

対話的追加
zsh-abbr はabbr add gs='git status'でターミナルからその場で追加が可能で、即座に永続化されます。
自前実装は定義ファイルを編集してsourceもしくはexec zshする必要があります。

fish / git alias からのインポート
大量の alias を一括で略語に変換する仕組みは自前実装にありません。

エッジケース対応の蓄積
クォート内の展開、ヒアドキュメント中の挙動、など zsh-abbr は2200行のコードの中で長年潰してきたエッジケースが無数に存在し、自前実装ではこれらの領域への対応は自己責任となります。

ビルトインコマンド名の上書き警告
zsh-abbr はlsのような既存のコマンド名を略語にしようとすると警告を出してくれます。
自前実装にはこのガードがなく、意図しない上書きが起きる可能性があります。

自前実装が優れている(と思いたい)点

コマンドラインのどの位置でも展開される
zsh-abbr のレギュラーモードはコマンド位置でしか展開を行わず、パイプの後で略語が展開されない場合があります。
グローバルモードにすると引数位置でも該当文字列が展開されてしまうジレンマがあります。
自前実装は位置判定をせず、全ての位置で展開するため、パイプ後でも自然に動きます。
ただし引数として略語名を打ちたい場合はCtrl+X Spaceで抑制する必要があります。

外部依存ゼロ
.zshrcと数個の設定ファイルをコピーするだけで動きます。
プラグインマネージャも clone も不要で、tmux やコンテナ等の制限環境でも動作します。

コードが見える
仕組み部分だけだと80行程度の分量なので、挙動に疑問があればコードを読んで確認できます。


まとめ

前回の記事では「学習用の実装」をまとめましたが、実際に自身で使用する中で「運用するための実装」が立ち上がって今回の改善に至りました。

前回の_expand_aliasを使った実装は、ZLEの組み込みウィジェットを活用することで「 zsh の仕組みを学ぶ」という目的には最適だったと思います。
しかし、実際に毎日使い始めると、alias テーブルとの二重管理、仕組みと定義が混在した.zshrcの管理しづらさといった実務的に不便な点が見えてきました。

改善版でLBUFFERの直接書き換えに移行したことで、alias テーブルへの依存がなくなり、仕組みと定義を別ファイルに分離して管理しやすい構成が実現できました。
その代わりとして区切り文字の管理やemulate -L zshによる防御といった「_expand_alias が裏でやってくれていたこと」を自分で引き受けることになりましたが、結果として展開の挙動をコントロールできるようになりました。

「便利なサービスの基本的な挙動はどうなっているのか」から始めた取り組みでしたが、「学習」と「実践」が相互に補完することでより深い理解に至れたと感じています。

今後も様々なものを展開していきたいと思います。

参考リンク

0
0
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?