はじめに
D言語の公式コンパイラである dmd が更新され、2.113.0 が 2026/08/17 にリリースされました。
今回のリリースには、コンパイラ13件、ランタイム1件、ライブラリ1件、Dub 1件の合計16件の主要な変更と、82件のGitHub Issueの修正が含まれています。
特に、実験的なデータフロー解析 -preview=fastdfa と、実行時のnullポインタ参照の検査 -check=nullderef が同時に追加されました。静的解析と動的検査の両面から、ポインタを扱うコードの問題を見つけやすくするリリースといえます。
以下、注目の変更点や互換性に関わる挙動などをまとめていきます。詳細はChangeLogをご覧ください。
- ChangeLog
- GitHub Release
前回のリリース記事はこちらです。
- D言語の更新まとめ 2026年1月版(dmd 2.112.0)
変更点目次
言語・コンパイラ変更点
変更点
- C形式ビットフィールドでデフォルト値を指定できるようになりました
-
nothrow関数をErrorが巻き戻す場合もデストラクタが実行されるようになりました - nullabilityとtruthinessを解析する実験的なFast DFAが追加されました
- Fast DFAで未初期化変数の読み取りを検出できるようになりました
-
-ftime-traceでテンプレートインスタンスの型引数を識別できるようになりました -
__traits(needsDestruction, T)が追加されました - 重なり合うフィールドを検出する
__traits(isOverlapped, field)が追加されました - nullポインタ参照の実行時検査が追加されました
- 一定の条件を満たす
pragma(printf)呼び出しを@safeから利用できるようになりました - 静的配列の長さを
$で推論できるようになりました -
pragma(inline, true)の関数が専用パスで先にインライン化されるようになりました -
-vgcがクロージャを生成する入れ子の関数とキャプチャ変数の位置を表示するようになりました -
with (auto x = expression())が利用できるようになりました
バグ修正/改善点
今回は2.112系の回帰修正に加え、浮動小数点演算やインライン化など、実行結果に関わる修正も含まれています。以下は公式ChangeLogに載っている71件の日本語要約です。GCとスレッド処理については、次のランタイム変更点でも補足します。
- GitHub 17224: Dランタイムの終了を通知する仕組みがない問題
- GitHub 17531:
^^演算子で独自のpow関数を利用する際の問題 - GitHub 18316: 浮動小数点リテラルを正しい近傍値へ変換できない問題
- GitHub 18337: インライン化された関数のカバレッジが常に0と報告される問題
- GitHub 19163: UDAにデリゲートを使うとコンパイラ内部エラーになる問題
- GitHub 19499:
pragma(lib)とpragma(linkerDirective)がオブジェクトへ重複したエントリを出力する問題 - GitHub 19675: Windows x86_64でMSVCリンカが
LNK1179エラーになる問題 - GitHub 19721:
@safeコードが__traits(getMember)経由でprivateフィールドへアクセスできる問題 - GitHub 19733: Windowsで
realリテラルの値が誤る問題 - GitHub 19829: 空の連想配列の
keysへの追加をコンパイル時に評価できない問題 - GitHub 19905: 関数テンプレートの引数推論で、デリゲート内の型リストが展開されない問題
- GitHub 20053: 引数ファイル内の空白を含む行が複数の引数として扱われる問題
- GitHub 20145: static初期化子で関数をデリゲートへ暗黙変換するとクラッシュする問題
- GitHub 20425: ImportCで三項演算子を使った
double complexへの代入が失敗する問題 - GitHub 20439: 初期化子に
SysTime.maxを使い-cでコンパイルすると未解決参照になる問題 - GitHub 20578:
-inline指定時にWindows・macOS・Linuxでコンパイラがクラッシュする問題 - GitHub 20997: 型による特殊化を指定したaliasテンプレート引数が、正しい引数を拒否する問題
- GitHub 21039: 長さ0の静的配列をスカラー値で初期化するとコンパイラ内部エラーになる問題
- GitHub 21194: 文字列リテラルの
dupで初期化したグローバルchar[]を変更するとクラッシュする問題 - GitHub 21323:
real[1]のコード生成が誤る問題 - GitHub 21381: aliasテンプレートのインスタンス化で、未定義識別子の位置が誤って表示される問題
- GitHub 21399: シングルクォートとダブルクォートの使い分けに関するエラーメッセージの改善
- GitHub 21495:
externブロック内で連想配列の扱いが一貫しない問題 - GitHub 21637: タプルの比較でコンパイラ内部エラーになる問題
- GitHub 21707: シーケンスに対する
foreachと-vcg-astの組み合わせでクラッシュする問題 - GitHub 21839:
void[N].initでコンパイラ内部エラーになる問題 - GitHub 21976: 2.112.0で配列比較が遅くなる回帰
- GitHub 22153: ImportCでライブラリを作る際、static関数の前方宣言を利用できない問題
- GitHub 22229:
scope変数から別の変数へ代入した際、必要なscopeが推論されない問題 - GitHub 22239:
FreeBSD_15のバージョン識別子がない問題 - GitHub 22243: 引数から
scopeが推論された理由を診断に表示する改善 - GitHub 22281:
alias thisによる変換を持つキーで、連想配列へのアクセスが誤る問題 - GitHub 22282:
File型の変数にUDAを付けるとコンパイラがクラッシュする問題 - GitHub 22290: Linuxのinotify用定数
IN_ACCESSの値が誤っている問題 - GitHub 22292: メンバー関数呼び出しのインライン化で、引数が早すぎるタイミングで破棄される問題
- GitHub 22322: 64bitコードで
realからfloatへ変換する際、二重丸めにより結果がずれる問題 - GitHub 22363:
noreturn型の変数へのアクセスが検出されない場合がある問題 - GitHub 22381:
ushortのマスク処理で範囲外アクセスが起きる問題 - GitHub 22394: ラムダ内のエラーで、定義位置に加えて呼び出し位置も表示する改善
- GitHub 22397: 2.112.0で配列リテラルとUDAを使う配列変数の初期化がコンパイルできない回帰
- GitHub 22399: Windows DLLで低レベルスレッドの終了処理が正しく扱われない問題
- GitHub 22406: 2.112系で
sharedな連想配列のlengthを取得できない回帰 - GitHub 22427:
noreturn型の三項演算子が早すぎる段階で除去される問題 - GitHub 22430: 条件式における
noreturnの評価が無視される問題 - GitHub 22463:
SOURCE_DATE_EPOCHの解釈がシステムのタイムゾーンに左右される問題 - GitHub 22481: インライン化でループ内の
returnが削除され、制御の流れが変わる問題 - GitHub 22489: エイリアスがある
realの処理で、最適化・インライン化時のコード生成が誤る問題 - GitHub 22504: 2.112系でPowerPC64LE/Linux向けdruntimeをビルドできない回帰
- GitHub 22512: 2.112系でSPARC V9/Solaris向けdruntimeをビルドできない回帰
- GitHub 22517: 2.106以降、確保した
void[]がポインタを含まない領域として扱われる回帰 - GitHub 22544: 2.112系で
withブロック内の連想配列の添字操作がコンパイルできない回帰 - GitHub 22594: タプルメンバーにだけポインタを持つclassで、ポインタなしの型情報が生成される回帰
- GitHub 22613: postblitがある場合に連続した初期化が失敗する問題
- GitHub 22621: 無名union内の無名structが、ストレージの重なりありと判定されない問題
- GitHub 22647: DMDをライブラリとして利用すると
dub test --coverageでリンクできない問題 - GitHub 22658: コピー不可structの静的配列に対して
__traits(isCopyable)の判定が誤る問題 - GitHub 22659: 静的配列型へキャストしたスライスへの代入でコンパイラ内部エラーになる問題
- GitHub 22667: ImportCの
.di生成でvoidが_IO_lock_tに置き換わる問題 - GitHub 22711:
-ftime-traceのsemantic_analysisの粒度が粗く、詳細を調べにくい問題 - GitHub 22769: 補間文字列内の関数テンプレート引数推論でコンパイラ内部エラーになる問題
- GitHub 22980:
constコンストラクタで名前付き引数が拒否される問題 - GitHub 23065: 2.112.0で自己参照型を含む連想配列の等価比較がコンパイルできない回帰
- GitHub 23081: 並列GCのスキャンスレッドが空回りしてCPUを消費し続ける問題
- GitHub 23133:
GC.collect()で並列スキャン用のスレッドが起動しなくなった回帰 - GitHub 23182: 2.112.0で連想配列の要素の
length操作などが内部宣言の重複エラーになる回帰 - GitHub 23320: 連想配列のキーの
const/immutableの扱いが厳しすぎる問題 - GitHub 23359: タプル引数のUDAが展開後の各要素へ伝播しない問題
- GitHub 22754:
Object.__monitorの定義をコンパイラ側からdruntimeへ移す変更 - GitHub 22925: 2.113の開発版で、不正なcase範囲指定がコンパイラ内部エラーになる回帰
- GitHub 23262: 2.113.0 Betaで、classインスタンスをC++ interfaceへキャストするとコンパイラ内部エラーになる回帰
- GitHub 23524: Windows上でmacOS向けにクロスコンパイルするとコンパイラがクラッシュする問題
ランタイム変更点
変更点
- スレッドの開始関数から抜けた
Throwableを全スレッド共通またはスレッド単位で処理できるようになりました
バグ修正/改善点
ランタイム関連では、DLLのアンロードとGCの走査条件に関する修正が含まれています。以下は公式Issueに記載された症状と対象範囲です。
- GitHub 22399: Windowsで共有druntimeを使うDLLの低レベルスレッドが、DLLのアンロード時に正しく終了処理されない問題が修正されました。
-
GitHub 22517:
new void[n]で確保した領域に、GCの走査対象外を示すNO_SCANが付く回帰が修正されました。 -
GitHub 22594: class内のポインタがすべてタプルメンバー由来の場合に、型情報へ
noPointersが付く回帰が修正されました。 - GitHub 23081: 並列GCのスキャンスレッドが、処理対象のない状態で空回りしてCPUを消費し続ける問題が修正されました。
-
GitHub 23133: 2.109.1以降、明示的な
GC.collect()で並列スキャン用スレッドが起動しなくなった回帰が修正されました。
ライブラリ変更点
変更点
-
std.variantが@disable this()を持つ大きなstructを扱えるようになりました
バグ修正/改善点
- GitHub 9783: 大きなstructを
Variantに格納した際、postblit(コピー後処理)とデストラクタが正しく扱われない問題が修正されました。 - GitHub 9871: 有限rangeの直積を作る
cartesianProductにlengthがなく、要素数を取得できない問題が修正されました。 - GitHub 10062: 大きな値型を保持する
Variantをコピーすると、独立した値ではなく同じ実体を共有してしまう問題が修正されました。(9783と合わせて、後述のstd.variantの注目トピックで詳しく紹介します) - GitHub 10429:
Variantに格納したタプルの要素を添字で取り出すと、型の不一致として例外になる問題が修正されました。 - GitHub 10743:
Nullableに大小比較のopCmpが追加され、値がない状態を含めた並べ替えに対応しました。 - GitHub 10858:
std.loggerのtrace()を使う際、globalLogLevelだけでなく共有logger側のログレベルも設定する必要があることを説明するドキュメントが改善されました。 -
GitHub 10916:
format("%.")やformat("%.*")のように途中で終わった書式指定で、書式エラーを報告する代わりに入力末尾を越えて読み取ってしまう問題が修正されました。 - GitHub 10940:
gammaIncomplete(s, x)で、形状パラメータsが0または無限大のときの扱いが一貫しない問題が修正されました。 - GitHub 11035: 正規表現の複数桁の後方参照で、該当する番号のキャプチャがないときに末尾の数字が消えてしまう問題が修正されました。(訳注: たとえばキャプチャが1つだけの
(a)\12で、2が無視されるケースです)
Dub変更点
変更点
-
dub dustmiteに判定コマンドの実行単位の--timeoutオプションが追加されました
ドキュメント変更点
バグ修正/改善点
-
fullyQualifiedNameのドキュメントが重複していた問題が修正されました - DMDのCLIドキュメントで一部の単語にescapeが必要だった問題が修正されました
注目トピック
以下の実行例は、特に断りがない限りWindows x86_64版のDMD 2.113.0で確認しています。公式の変更点に加え、手元で試して気付いた点も紹介します。
言語・コンパイラ変更点
C形式ビットフィールドでデフォルト値を指定できるようになりました
C形式ビットフィールドは、整数型などの記憶領域を指定したビット幅のフィールドとして扱う機能です。
2.113.0では、structとclassのビットフィールドに初期値を書けるようになりました。
通常のデフォルト初期化とclassのnewで、宣言した値が使われます。フィールドへの代入や、構造体・クラスの初期化式で明示値を与えた場合は、その値で上書きできます。
struct Options
{
uint level : 3 = 5;
bool enabled : 1 = true;
}
void main()
{
Options defaults;
assert(defaults.level == 5);
assert(defaults.enabled);
auto specified = Options(1, false);
assert(specified.level == 1);
assert(!specified.enabled);
}
初期値がビット幅に収まるかはコンパイル時に検査されます。例えば、4bitのintでは-8..7、3bitのuintでは0..7の値を指定できます。
例えば、int b : 2 = 5は、符号付き2bitで表せる範囲が-2..1なので、コンパイルエラーになります。
official_overflow.d(3): Error: default initializer `5` is not representable as bitfield type `int:2`
int b : 2 = 5;
^
official_overflow.d(3): bitfield `b` default initializer must be a value between `-2..1`
int b : 2 = 5;
^
bool:1ではfalseとtrueが利用できます。2は幅超過ではなく、intからboolへ暗黙変換できないという通常の型エラーになります。
バイナリヘッダやハードウェアレジスタなど、ビット単位のフィールドに既定値を持たせたい人は試してみると良いかもしれません。
nothrow 関数を Error が巻き戻す場合もデストラクタが実行されるようになりました
nothrow は、関数から通常の Exception を送出しないことを示す属性です。一方、プログラムの継続が難しい状態を表す Error は、nothrow 関数からも伝播する場合があります。
これまではDMDの最適化によって、nothrow 関数から Error が伝播した際、呼び出し元のデストラクタなどの後始末が省略されることがありました。2.113.0ではこの最適化が既定で無効になりました。
例えば次のコードです。
import core.stdc.stdio;
struct Guard
{
~this()
{
printf("destructor\n");
fflush(stdout);
}
}
void fail() nothrow
{
throw new Error("boom");
}
void main()
{
Guard guard;
fail();
}
Windows版DMD 2.113.0でこの例を実行すると、通常設定では destructor が表示されてから、捕捉されなかった Error により終了します。従来の最適化を再び有効にする -nothrow-optimizations を付けると、destructor は表示されません。
ちなみに、Dの例外処理を使わない -betterC はこの変更の対象外です。今回の例も throw 文を使うため、-betterC ではコンパイルできません。
nullabilityとtruthinessを解析する実験的なFast DFAが追加されました
変数のnullabilityとtruthinessを追跡するFast DFAが追加されました。-preview=fastdfaで有効になる実験的な解析機能です。
DFAとは Data Flow Analysis、データフロー解析の略です。nullabilityは、変数がnullかどうかを表す状態です。truthinessは、条件式としてtrueかfalseかを表す状態です。
Fast DFAは、これらの状態が処理の途中でどう変化するかを追跡します。明らかなnullポインタの参照や、成立しないassertをコンパイルエラーにできます。
ポインタを繰り返し更新する処理や、ループ、状態フラグの多いコードで役立ちます。C API連携や低水準なコードを扱う人は、一度試してみるとよいかもしれません。
公式ChangeLogでは、約10万行のコードで誤検出がなく、解析コストも目立たない水準だったと報告されています。既存コードに追加しやすそうですが、実際の診断やコンパイル時間はプロジェクトごとに見ておくとよさそうです。
例えば、次のloopyでは2回目の繰り返しでnullを参照します。フラグなしではコンパイルできますが、-preview=fastdfaを指定すると、ループ内でptrがnullへ変化することを検出します。
void loopy()
{
int* ptr = new int;
foreach (i; 0 .. 2) // エラー: ptrはnon-nullである必要があるがnullになった
{
int val = *ptr;
ptr = null;
}
}
official_loop.d(5): Error: Variable `ptr` was required to be non-null and has become null
foreach (i; 0 .. 2)
^
ちなみにエラー箇所にはやや癖があり、代入箇所のptr = nullではなく、繰り返しを始めるforeachの行に診断が出ます。
次のdirectNullは、フラグなしではコンパイルできますが、-preview=fastdfaを指定するとnullを参照した行がエラーになります。
void directNull()
{
int* ptr = null;
int value = *ptr;
}
direct_null.d(4): Error: Dereference on null variable `ptr`
int value = *ptr;
^
truthinessでは、falseになったと証明できる変数をassertすると検出されます。次のtruthinessAssertも、フラグなしではコンパイルできますが、Fast DFAを有効にするとエラーになります。
void truthinessAssert()
{
bool condition = true;
condition = false;
assert(condition);
}
truthiness_assert.d(5): Error: Assert can be proven to be false
assert(condition);
^
null参照の検査では、参照する前に有効なポインタへ再代入したり、if (ptr)の内側で参照したりすればコンパイルできます。
Fast DFAは、null参照をすべて検出するものではありません。公式の説明によると、解析が複雑になったり結果が不確かになったりする場合は、診断を出さずに解析を打ち切る方針だそうです。
たとえば次のnullableBranchは、allocate == falseの場合にnullを参照しますが、DMD 2.113.0のFast DFAでは検出されません。
void nullableBranch(bool allocate)
{
int* ptr = null;
if (allocate)
ptr = new int;
int value = *ptr;
}
分割コンパイル、関数ポインタ、再帰的に呼び合う関数にも解析上の制限があります。これらを経由する処理まで、すべて検査されるわけではありません。
まだ実験的な機能なので、まずは通常のビルドとは別に、手元やCIの追加チェックとして試すのがよさそうです。実行時のテストや-check=nullderefと組み合わせると、違う角度から問題を探せます。
Fast DFAで未初期化変数の読み取りを検出できるようになりました
前述のFast DFAの一機能ですが、未初期化変数の読み取りを検出できるようになりました。-preview=fastdfaを指定した場合だけ有効になります。
前節のnullabilityとtruthinessとは、追跡する状態が異なります。前節の機能が追跡するのは、変数の値がnullか、条件としてtrueかfalseかです。
この節で扱うのは、変数に一度でも値が書き込まれたかどうかです。たとえばint value = voidはnullを取り得る型ではありませんが、値を書き込む前に読み取ると検出されます。
反対に、int* ptr = nullは初期化済みですが、ポインタの値がnullなのでnullabilityの検出対象になります。どちらも同じFast DFAを使いますが、見つける問題は別です。
= voidは、変数のデフォルト初期化を省略する指定です。値を代入する前に読み取ると、不定な値を使うことになります。
今回のFast DFAは、直接読み取る場合だけでなく、スタック上の変数をポインタ経由で読み取る場合も追跡します。= voidやスタック上の変数へのポインタを使う低水準なコードでは、一度試してみるとよいかもしれません。
次のreadFromUninitは、フラグなしではコンパイルできますが、Fast DFAを有効にすると直接読み取る行とポインタ経由で読み取る行の両方がエラーになります。
void readFromUninit() @system
{
int val1 = void;
int val2 = val1; // エラー: 未初期化値の直接読み取り
int* ptr = &val1;
int val3 = *ptr; // エラー: pointer経由の未初期化値読み取り
}
official_uninit.d(4): Error: Expression reads from an uninitialized variable, it must be written to at least once before reading
int val2 = val1;
^
official_uninit.d(3): For variable `val1`
int val1 = void;
^
official_uninit.d(7): Error: Expression reads from an uninitialized variable, it must be written to at least once before reading
int val3 = *ptr;
^
official_uninit.d(3): For variable `val1`
int val1 = void;
^
読み取り前に値を代入すれば、Fast DFAを有効にしてもコンパイルできます。ポインタ経由で値を書き込んだ場合も、初期化済みとして扱われます。
デフォルト初期化された浮動小数点数の数学演算も検出対象です。Dの浮動小数点数はデフォルトでNaNになるため、そのまま計算するとNaNが伝播します。
void floatMathDefault()
{
float value;
float result = value * 2;
}
floatMathDefaultを-preview=fastdfa付きでコンパイルすると、デフォルトのNaNのまま使われているvalueを示す診断が出ます。地味にうれしい。
float_math_default.d(4): Error: Expression reads a default initialized variable that is a floating point type
float result = value * 2;
^
float_math_default.d(4): It will have the value of Not Any Number(nan), it will be propagated with mathematical operations
float result = value * 2;
^
float_math_default.d(3): For variable `value`
float value;
^
float_math_default.d(3): Initialize to float.nan or 0 explicitly to disable this error
float value;
^
0またはfloat.nanで明示的に初期化するとコンパイルできます。
単純なコピーなど、数学演算以外ではこの診断は発生しません。未初期化読み取りについても、既存コードから明らかな問題を探す追加チェックとして使うのがよさそうです。
未初期化読み取りの検出はFast DFAの当初スコープには含まれていませんでした。今後も維持されるかは、利用者からのフィードバックに依存すると説明されています。
-ftime-trace でテンプレートインスタンスの型引数を識別できるようになりました
-ftime-trace は、コンパイル処理に費やした時間をトレース JSONとして出力するオプションです。2.113.0ではテンプレートインスタンスのイベント名に型引数が含まれ、同じテンプレートの異なるインスタンス化を区別しやすくなりました。
たとえば、同じテンプレートを異なる型でインスタンス化するコードをトレース対象にします。
template TypeLabel(T)
{
enum TypeLabel = T.stringof;
}
enum intLabel = TypeLabel!int;
enum arrayLabel = TypeLabel!(int[]);
enum stringLabel = TypeLabel!string;
void main() {}
このような小さな例の短いイベントも残すには、記録時間のしきい値を0にします。
dmd -c template_instances.d `
-ftime-trace `
-ftime-trace-granularity=0 `
-ftime-trace-file=trace.json
出力されるJSONでは、型引数ごとに次のようなイベント名で区別できます。
Sema1: Template Instance TypeLabel!(int[])
Sema1: Template Instance TypeLabel!int
Sema1: Template Instance TypeLabel!string
大きなプロジェクトで同じテンプレートが多くの型から使われている場合に、時間のかかったインスタンスを特定しやすくなります。プロファイリング情報を詳しくする変更であり、コンパイル処理自体を高速化する機能ではありません。
__traits(needsDestruction, T) が追加されました
__traits(needsDestruction, T) は、型 T の値を破棄するときにデストラクタ処理が必要かをコンパイル時に調べるtraitです。
明示的なデストラクタを持つstructだけでなく、そのstructをフィールドに持つことでデストラクタが自動生成されるstructもtrueになります。
struct S { ~this(); }
struct Wrapper { S value; }
static assert(__traits(needsDestruction, S)); // 明示的destructor
static assert(__traits(needsDestruction, Wrapper)); // field由来のdestructor
static assert(!__traits(needsDestruction, S[0])); // 要素がない
static assert(__traits(needsDestruction, S[1])); // 要素の破棄が必要
静的配列では要素数も判定に含まれます。S[0]はfalse、S[1]はtrueになります。入れ子の場合も同じで、S[2][3]のように要素を持つ配列はtrue、S[1][0]のように要素数が0になる配列はfalseです。
デストラクタを持つstructを基底型にしたenumもtrueになります。一方、postblitだけを持つstructはfalseです。このtraitはコピー処理ではなく、破棄処理の必要性を判定します。
Dのclass変数はオブジェクトそのものではなく参照値を保持します。参照値の破棄ではオブジェクトのデストラクタを呼ばないため、classにデストラクタがあっても結果はfalseです。次のCもfalseになりますが、これはオブジェクトにデストラクタがないという意味ではありません。
class C { ~this(); }
static assert(!__traits(needsDestruction, C)); // class参照値自体には不要
ポインタと動的配列も、参照先の破棄ではなく値自体の破棄を判定するため、同様にfalseです。
汎用コンテナや未構築のメモリ領域などで、型ごとに後始末処理を組み立てる人に便利な機能です。例えば、要素を破棄する処理が必要かどうかで、コンテナの実装を切り替えるときに使えます。
引数には値ではなく型を1つ指定します。例えば、次のResource.initは型ではなく値なので、コンパイルエラーになります。
struct Resource
{
~this() {}
}
enum result = __traits(needsDestruction, Resource.init);
value_argument.d(6): Error: type expected as second argument of __traits `needsDestruction` instead of `Resource()`
enum result = __traits(needsDestruction, Resource.init);
^
重なり合うフィールドを検出する __traits(isOverlapped, field) が追加されました
__traits(isOverlapped, field) は、指定したフィールドが別のフィールドと同じ記憶領域を共有しているかをコンパイル時に判定します。unionや匿名unionを扱うシリアライズ、コード生成、汎用的なデストラクタ実装などで利用できます。
例えば、次のSでは匿名union内のxとyが同じ記憶領域を使うためtrueになり、通常のフィールドであるaとbはfalseになります。
struct S
{
int a;
union
{
int x; // yとstorageが重なる
float y; // xとstorageが重なる
}
int b;
}
static assert(__traits(isOverlapped, S.x)); // true
static assert(__traits(isOverlapped, S.y)); // true
static assert(!__traits(isOverlapped, S.a)); // false: 通常のfield
static assert(!__traits(isOverlapped, S.b)); // false: 通常のfield
名前付きunionでも同様に判定できます。
union NamedUnion
{
int x;
float y;
}
static assert(__traits(isOverlapped, NamedUnion.x)); // true
static assert(__traits(isOverlapped, NamedUnion.y)); // true
匿名structをunionに入れた場合は、その中のフィールドも重なりを検出できます。
struct S
{
union
{
struct
{
int low;
int high;
}
long whole;
}
}
static assert(__traits(isOverlapped, S.low));
static assert(__traits(isOverlapped, S.high));
static assert(__traits(isOverlapped, S.whole));
この例ではlowとhighのオフセットは異なり、互いには重なりません。wholeが両方の領域にまたがるため、3つのフィールドすべてがtrueになります。
このように、判定結果がtrueでも、すべてのフィールドが互いに重なっているとは限りません。重なる相手やグループを調べるには、オフセットやサイズなど別の情報と組み合わせます。
structだけでなく、class内の匿名unionも判定できます。フィールドが1つだけのunionはfalseです。また、名前付きunion型を通常フィールドとして持つ場合、そのフィールド自体はfalseです。この特性はフィールドの型を再帰的に調べず、指定したフィールド自身の重なりを判定します。
型やローカル変数、フィールドの値そのものを1つ渡した場合は、エラーではなくfalseになります。引数なしまたは2引数の場合は、引数個数を示すコンパイルエラーになります。
no_argument.d(1): Error: expected 1 arguments for `isOverlapped` but had 0
enum result = __traits(isOverlapped);
^
nullポインタ参照の実行時検査が追加されました
ポインタを参照する前に、null検査を挿入する機能が追加されました。いわゆるnull参照が起きると例外が送出される機能です。-check=nullderef=onで有効になり、デフォルトでは無効です。
nullを参照すると送出されるNullPointerErrorは、ExceptionではなくErrorの派生classです。assertの失敗と同様にプログラムの異常を知らせるもので、捕捉して通常の処理を続けるための仕組みではありません。
前述のFast DFAは、nullポインタの参照をコンパイル時に発見する静的解析です。こちらは実際にその処理を実行したときに検出する実行時検査です。
コンパイル時にnullと証明できない場合でも、問題の経路を実行すれば検出できます。nullポインタを参照した位置とバックトレースを確認したい人は、一度試してみるとよいかもしれません。
次のコードをsafe.dに保存し、dmd -g -check=nullderef=on safe.dでビルドして実行する例です。
@safe int readNull()
{
int* ptr;
return *ptr;
}
void main()
{
int value = readNull();
}
この例のreadNullはnullポインタを参照します。Windowsでは、デフォルトと-check=nullderef=offならOSのaccess violationで終了し、Dのバックトレースは得られません。
-check=nullderef=onなら、次のように参照位置を示すNullPointerErrorが発生します。readNullを@systemに変えた場合も同じように検査されます。
core.exception.NullPointerError@safe.d(4): Null pointer dereference
----------------
... in safe.readNull at safe.d(4)
... in D main at safe.d(9)
...
-gを指定してコンパイルすると、バックトレースに関数名とソースの位置も表示されます。
また、このエラーをハンドリングするための仕組みもあります。core.exception.nullDerefHandlerを設定すると、null参照が起きたファイルと行番号をハンドラで受け取れます。
検査失敗時の処理は-checkactionでも変えられます。CならCランタイムのassertの失敗となり、haltならメッセージを出さずに停止します。
また、公式説明では、DMDのバックエンドの制限によって検査を挿入できない場合もあるとのことです。まずはデバッグビルドやテストでonを試し、既存のテストやFast DFAと併用するのがよいでしょう。
一定の条件を満たす pragma(printf) 呼び出しを @safe から利用できるようになりました
一定の条件を満たすpragma(printf)関数を、@safeから呼べるようになりました。
pragma(printf)は、printf形式の書式文字列と引数をコンパイラが検査するためのpragmaです。Cとの連携用の宣言やログ出力APIなど、printf形式の独自関数にも指定できます。
呼び出し先が@safeまたは@trustedで、書式がリテラルになっており、%sなどの文字列の書式指定を使わない場合に許可されます。この3条件はすべて必要です。
次のcheckedPrintfは@trustedとして宣言されています。test内の最初の呼び出しは書式がリテラルで文字列の書式指定もないため呼び出せますが、2番目は%sを使い、3番目は書式が変数なので、どちらもコンパイルエラーになります。
extern(C) pragma(printf)
void checkedPrintf(const char* format, ...) @trusted;
@safe void test(int value, char* text)
{
checkedPrintf("value = %d\n", value);
checkedPrintf("text = %s\n", text);
checkedPrintf(text);
}
official.d(7): Error: calling `pragma(printf)` function `checkedPrintf` with format string `"text = %s\n"` is not allowed in a `@safe` function
checkedPrintf("text = %s\n", text);
^
official.d(8): Error: calling `pragma(printf)` function `checkedPrintf` with non-literal format string is not allowed in a `@safe` function
checkedPrintf(text);
^
test内の最初の呼び出しだけを残せばコンパイルできます。%pによるポインタの表示と、%%によるパーセント記号の表示も許可されます。呼び出し先を@safeと宣言しても、%sやリテラルではない書式は許可されません。
呼び出し先が@systemの場合は、リテラルな%dでも通常の安全でない呼び出しとして拒否されます。
system_literal_int.d(6): Error: `@safe` function `system_literal_int.test` cannot call `@system` function `system_literal_int.checkedPrintf`
checkedPrintf("value = %d\n", value);
^
この点は、標準のcore.stdc.stdio.printfを使う場合にも注意が必要です。DMD 2.113.0付属druntimeではprintfが@systemとして宣言されているため、今回の変更だけでは@safeから直接呼べません。
今回の安全性判定と、既存の書式型検査は別の機能です。例えば、次のように呼び出し先と呼び出し側を@systemにしても、%dにlongの値を渡すと非推奨の診断が出ます。
extern(C) pragma(printf)
void checkedPrintf(const char* format, ...) @system;
@system void test(long value)
{
checkedPrintf("value = %d\n", value);
}
type_mismatch_system.d(6): Deprecation: argument `value` for format specification `"%d"` must be `int`, not `long`
checkedPrintf("value = %d\n", value);
^
通常設定では非推奨の診断を出しながらコンパイルできますが、-deを付けるとエラーとして扱われます。
静的配列の長さを $ で推論できるようになりました
静的配列の長さに$を指定すると、初期化式から要素数を推論できるようになりました。
int[$] arr = [1, 2, 3]; // 長さは3と推論される
static assert(is(typeof(arr) == int[3]));
static assert(arr.length == 3);
モジュール変数、ローカル変数、structのフィールドで利用できます。
空の配列リテラルなら長さは0になります。文字列からchar、wchar、dcharの配列長を求めたり、配列連結の結果や静的配列型の式を初期値にしたりすることもできます。
int[$] empty = []; // int[0]
char[$] text = "abc"; // char[3]
int[$] joined = [1, 2] ~ [3, 4]; // int[4]
int[$][$] matrix = [[1, 2], [3, 4]]; // int[2][2]
多次元配列の内側は最初の要素から推論されます。たとえば[[1, 2], [3]]のように内側の要素数が揃っていないと、推論されたint[2][2]に変換できず、コンパイルエラーになります。
推論するための初期値も必要なので、int[$] values;のように初期化式を省略することはできません。void、動的配列、スカラー値を初期値にする場合や、関数の仮引数にも使えません。
要素型の変換規則は従来どおりです。ubyte[$] values = [1, 256]は長さ2と推論できますが、256がubyteに収まらないためエラーになります。
配列のインデックスアクセスでもarr[$ - 1]のように$を使えますが、こちらも配列長を表すものでした。今回は配列を使うときだけでなく、宣言するときにも使えるようになった、という感じです。
静的なデータの要素を増減したとき、宣言側の長さまで書き直さずに済むのがうれしいところです。
pragma(inline, true) の関数が専用パスで先にインライン化されるようになりました
pragma(inline, true) は、プログラマーがインライン化を強く要求する指定です。2.113.0では通常のインライン候補とは別のパスで先に処理され、指定した関数を呼び出し側へ展開しやすくなりました。
これまでは内側の関数を先にインライン化した結果、pragma(inline, true)を付けた外側の関数が大きくなり、呼び出し側へ展開できない場合がありました。2.113.0では明示指定された関数を先に処理します。
auto staticSquares(uint n)()
{
int[n] arr;
static foreach (i; 0 .. n)
arr[i] = (i + 1) ^^ 2;
return arr;
}
pragma(inline, true) int thirtyThirty()
{
return staticSquares!30[$ - 1];
}
thirtyThirtyを呼ぶ側での展開は、Windows版DMD 2.113.0で試す限りでは次のようになります。いずれも戻り値は900です。
thirtyThirtyの指定 |
コンパイルオプション | 呼び出し側に残る関数呼び出し |
|---|---|---|
pragma(inline, true)なし |
-inlineなし |
thirtyThirty |
pragma(inline, true)あり |
-inlineなし |
staticSquares!30 |
pragma(inline, true)あり |
-inlineあり |
なし |
-inlineなしでも、明示指定したthirtyThirtyは展開されます。さらに-inlineを付けると、通常のインライン候補であるstaticSquares!30も展開されます。
明示したインライン方針を反映しやすくする変更です。速度やバイナリサイズがどう変わるかは、関数やバックエンド、最適化オプションによるので、利用するコードで比較するとよさそうです。
-vgc がクロージャを生成する入れ子の関数とキャプチャ変数の位置を表示するようになりました
-vgc は、コンパイラがGCによるメモリ確保を生成する箇所を報告するオプションです。変更前はクロージャについて外側の関数の位置しか表示されませんでしたが、変更後は入れ子の関数とキャプチャされる変数の宣言位置も表示されます。
auto foo()
{
int x;
int bar() { return x; }
return &bar;
}
この例のbarはfooの局所変数xを参照しています。fooからデリゲートとして返すと、fooの呼び出しが終わった後もxを使えるようにする必要があります。
fooのスタック上にxを置いたままでは、fooから戻った後に使えなくなってしまいます。
そこでDでは、このような変数をGC管理のヒープ上に確保したクロージャのコンテキストへ置きます。これならfooの終了後も、返されたデリゲートからxを参照できます。
Dのデリゲートは、関数ポインタとコンテキストへのポインタの組です。今回の例は次のような構造だと考えると分かりやすいです。
delegate
├─ function pointer ─> barのcode
└─ context pointer ──> GC heap上のclosure context
└─ x
変更前は外側の関数の位置だけが表示されていました。
vgc.d(1): vgc: using closure causes GC allocation
新しい診断では、クロージャを作る関数とキャプチャ変数の位置も表示されます。これはエラーではなく、メモリ確保が発生する場所を知らせる情報です。
official.d(1): vgc: using closure causes GC allocation
official.d(4): vgc: function `bar` closes over variable `x`
official.d(3): vgc: `x` declared here
大きな外側の関数でも、クロージャを作る入れ子の関数とキャプチャ変数へ直接移動できます。意図しないGCによるメモリ確保を調べている人には便利な改善です。
外側の関数の同じ呼び出しで、同じ局所変数を読み書きする2つのデリゲートを作ると、2つは同じコンテキストを共有します。書き込み側でキャプチャ変数を変更すると、読み取り側にも反映されます。次の例では、makeCounter()が返す読み取り用・書き込み用のデリゲートから、同じcountを操作できます。
import core.memory : GC;
import std.stdio : writeln;
struct Counter
{
int delegate() read;
void delegate(int) write;
}
Counter makeCounter()
{
int count = 10;
int read() { return count; }
void write(int value) { count = value; }
auto reader = &read;
auto writer = &write;
assert(reader.ptr == writer.ptr);
assert(GC.addrOf(reader.ptr) !is null);
return Counter(reader, writer);
}
void main()
{
auto counter = makeCounter();
writeln("shared-context=", counter.read.ptr == counter.write.ptr);
writeln("gc-managed-context=", GC.addrOf(counter.read.ptr) !is null);
writeln("before=", counter.read());
counter.write(42);
writeln("after-write=", counter.read());
GC.collect();
writeln("after-collect=", counter.read());
}
shared-context=true
gc-managed-context=true
before=10
after-write=42
after-collect=42
この例では、外側の関数から戻った後にGC.collect()を実行しても、デリゲートから変更後の42を読み取れます。デリゲートが到達可能な間はクロージャのコンテキストもGCに保持されるため、関数を抜けた後も利用できます。
一方、デリゲートを関数内だけで使う場合はscopeを付けられます。この場合はスタック上のコンテキストを使えるため、@nogcでもコンパイルでき、-vgcの診断も出ません。
int useWithinScope() @nogc
{
int value = 7;
int read() @nogc { return value; }
scope reader = &read;
return reader();
}
つまり、キャプチャするだけで必ずGCによるメモリ確保が起きるわけではなく、外側の関数を抜けた後も変数を使うかどうかがポイントです。
詳しい仕様はD言語仕様のDelegates & Closuresとデリゲート型の説明にまとまっています。
関数を深く入れ子にした場合も、中間の関数ではなく、実際に変数を参照する関数の位置が表示されます。入れ子の関数が外へ持ち出されず、GCによるメモリ確保が発生しない例では何も表示されません。
with (auto x = expression()) が利用できるようになりました
withの対象となる式を評価し、その結果を変数へ束縛できるようになりました。要は、オブジェクトのメンバーアクセスでオブジェクト名を省略できる機能に加え、そのオブジェクトに別名を与えることもできるようになります。黒魔術の匂いがしますね。
従来の式を直接渡す形式も引き続き利用できます。
struct Result
{
int status;
string body;
}
int calls;
Result fetch()
{
++calls;
return Result(200, "OK");
}
void record(Result result) {}
void main()
{
with (auto result = fetch())
{
assert(status == 200); // result.statusを短く参照
assert(result.body == "OK");
record(result); // object全体も利用できる
}
assert(calls == 1);
}
従来は名前が必要なら、先に変数を宣言してからwith (result)へ渡していました。新しい形式なら宣言をwith文へまとめ、変数のスコープをブロック内に限定できます。
fetch()は従来のwith (fetch())と同じく1回だけ評価されます。デストラクタを持つstructなら、ブロックを抜ける際に後始末も行われるので、ファイルやセッションのようなRAIIオブジェクトを一時的に扱う場合にも使いやすい形です。
また、withでメンバーのスコープを開けないintなどは対象にできません。
non_aggregate.d(3): Error: `with` expression types must be enums or aggregates or pointers to them, not `int`
with (auto value = 1)
^
ランタイム変更点
スレッドの開始関数から抜けた Throwable を全スレッド共通またはスレッド単位で処理できるようになりました
スレッドの処理から外へ抜けた Throwable に対し、ログを残したり、プログラム全体を終了したりする処理を挟めるようになりました。全スレッド共通のハンドラと、スレッド単位の ThreadBase.filterCaughtThrowable が用意されています。
特に、通常の処理を続けることが難しい Error が起きたとき、何も記録されないままスレッドだけが止まるのを避けたい場合に役立ちそうです。例えば、全スレッド共通のハンドラは次のように設定します。
import core.exception;
void main()
{
filterThreadThrowableHandler = (ref Throwable t) {
import core.stdc.stdio;
import core.stdc.stdlib;
if (auto e = cast(Error) t)
{
auto msg = e.message();
fprintf(stderr, "Errorによりthreadが終了: %.*s\n",
cast(int) msg.length, msg.ptr);
fflush(stderr);
abort();
}
};
}
このハンドラは Error のメッセージを残してから、abort() でプログラム全体を終了します。ハンドラの呼び出しは、join() を待つ側ではなく、例外が発生したスレッド上で行われます。
引数が ref Throwable になっている点もポイントです。
- 値を残して戻ると、
join()からそのThrowableが再送出されます。 -
nullにして戻ると、join()は通常どおり戻ります。回復可能なExceptionを別の仕組みで処理済みと判断できる場合などに使えます。ただし、フィルタが呼ばれる時点でワーカースレッドはすでに終了処理を始めており、処理が再開されるわけではありません。 -
abort()を呼ぶと、スレッドだけでなくプログラム全体が終了します。
スレッドごとに振る舞いを変える場合は、Thread の派生classで filterCaughtThrowable をオーバーライドします。そこで super.filterCaughtThrowable(t) を呼ぶと、共通ハンドラにも処理を渡せます。呼ばなければ、そのスレッド固有の処理だけになります。
通常の例外処理はスレッド内の try / catch で行い、この仕組みはスレッドの外へ漏れた例外を扱う最後の処理として使います。ハンドラで待ち続けるとスレッドの終了も遅れます。上の例でもCの fprintf を使っていますが、終了処理の中でも使いやすい、短く失敗しにくい処理を選ぶのがよさそうです。
ライブラリ変更点
std.variant が @disable this() を持つ大きなstructを扱えるようになりました
std.variant.Variant は、実行時にさまざまな型の値を保持できる型です。値が内部バッファに収まれば直接保持し、収まらなければヒープに格納します。通常の Variant のバッファサイズは決まっていますが、VariantN!N を使えばサイズを指定できます。これまでは、内部バッファに収まらず、かつ @disable this() を持つstructの値を格納しようとするとコンパイルできませんでした。
2.113.0では、引数なしのコンストラクタを呼ばずに値をコピーすることで、このようなstructも扱えるようになりました。
@disable this() は、引数なしのデフォルト構築を禁止する指定です。専用のコンストラクタを通して、有効な状態の値だけを作りたいstructなどで使います。
次の例では、デフォルト構築を禁止した大きなLargeValueを、コンストラクタで初期化してからVariantN!32へ格納します。VariantN!32の内部バッファは32バイトですが、LargeValueは128バイトのpayloadを持つため収まりません。内部バッファではなく、確保したヒープ領域へ値をコピーする場合でも、デフォルト構築が不要になった点がポイントです。
import std.variant : VariantN;
struct LargeValue
{
@disable this();
int value;
ubyte[128] payload;
this(int value)
{
this.value = value;
}
}
void main()
{
alias V = VariantN!32;
static assert(LargeValue.sizeof > 32);
auto stored = V(LargeValue(42));
assert(stored.get!LargeValue.value == 42);
}
V(LargeValue(42))で、コンストラクタに42を渡して作った値を格納しています。最後のassertは、get!LargeValueで取り出した値のvalueが42であることを確かめています。今後は、通常のVariantでも同じように格納・コピーできます。
また、大きなstructを格納したVariantをコピーした際の扱いも修正されています。格納先のヒープ領域が別々に確保されるため、この例のvalueやpayloadをコピー先で変更しても、元のVariant内の値には波及しません。postblitやデストラクタの扱いも修正されています。
専用のコンストラクタを通して作った大きなstructも、そのままVariantへ格納しやすくなる改善です。もしこれまで諦めていたものがあれば試してみるとよさそうです。
Dub変更点
dub dustmite に判定コマンドの実行単位の --timeout オプションが追加されました
dub dustmite は、問題が再現するかを判定するコマンド(oracle)を繰り返し実行し、再現コードを小さくする機能です。今回、そのコマンド1回ごとに制限時間を設定できるようになりました。判定コマンドの終了を待つ時間を制限するために使えます。
次の例では、1回の制限時間を5秒にしています。
dub dustmite <destination-path> --timeout=5 --program-status=0
時間制限にはプログラム本体だけでなく、コンパイルやリンクも含まれます。短すぎると正常なビルドまで打ち切られてしまうので、普段のビルド・実行時間より余裕を持たせて指定するとよいでしょう。
しかし、この機能を使うには、公式ChangeLogに記載されているLinux/macOSのcoreutilsのtimeoutコマンドが必要です。Windows標準の timeout は「指定時間だけ待つ」別のコマンドであり、そのままでは代用できません。
Windowsで使う場合は、自分でGNU版のtimeoutコマンドを用意して対応する必要がありそうです。
非推奨または廃止される機能
今回、新たな非推奨化や、既存機能の廃止・エラー化はありませんでした。物足りない方はFast DFAを試してみましょう。
まとめ
dmd 2.113.0は、コードの問題を見つける仕組みと、日常の書き方を少し楽にする機能が揃ったリリースです。
特に注目したいのは、コンパイル時に状態を追う -preview=fastdfa と、実行時にnullポインタを検査する -check=nullderef です。どちらも明示的に有効にする機能ですが、問題を見つけるタイミングが違うので、用途に合わせて試す価値がありそうです。
一方、静的配列の長さ推論や with の変数宣言、新しい __traits は、普段のコードにも取り入れやすい変更です。大きなstructを Variant に格納する際の制約や、既存の連想配列・GCまわりの不具合も修正されています。
既存コードへの影響では、Errorが伝わる際に、これまで省略されていたデストラクタが呼ばれるようになる点にも注目です。
今回のリリースは、前回の機能追加版から約7ヶ月と、長らく間が空きました。リリース作業のGitHubワークフローへの移行などもあり、まだ安定していないのかもしれません。
今回はErrorを中心に安全性に関する改善が目立つリリースでした。まだ実験段階の機能もありますが、今後の安定化や機能強化にも期待しつつ、引き続き追いかけて実用していきましょう!