0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

Qiitaアクセス数取得

0
Last updated at Posted at 2026-11-14

Qiita APIを利用すると、自分が投稿した記事のアクセス数(PV数)を取得できます。

Qiitaの個人用アクセストークンを発行し、APIの /api/v2/authenticated_user/items を呼び出すと、記事一覧とそれぞれのアクセス数が返ってきます。

実際に作成したPerl製のアクセス解析ツールはこちらです。

アクセス数取得

手順

このツールを使うには、Qiitaの個人用アクセストークンが必要です。

1. Qiitaの設定画面を開く

次のURLにアクセスして、Qiitaにログインします。

Qiita アプリケーション設定

2. アクセストークンを発行する

設定画面から「新しくトークンを発行する」を選択し、次の手順で設定します。

  1. トークンの説明を入力する

    例えば、次のような名前を付けます。

    Perl Qiita Access Analyzer

  2. スコープ(権限)を選択する

    今回必要なのは、次の権限だけです。

    read_qiita

    Qiitaの記事やユーザー情報を読み取るための権限です。

  3. トークンを発行する

  4. 表示されたトークンをコピーする

    ※ トークンは発行時にしか確認できないため、安全な場所に保管してください。

3. Perlプログラムに設定する

トークンはプログラムに直接記述せず、環境変数に設定する方法がおすすめです。

Linux / WSLの場合:

export QIITA_ACCESS_TOKEN="発行したトークン"

※ export はそのターミナルを閉じると消えます。常に使う場合は ~/.bashrc などに書いておきます。

Perl側では、次のように取得できます。

my $token = $ENV{QIITA_ACCESS_TOKEN};

HTTPリクエストには、Authorizationヘッダーを付けます。HTTP::Tiny の場合は次のように書きます。

my $http = HTTP::Tiny->new(
    default_headers => {
        Authorization => "Bearer $token",
    }
);

4. 動作確認

curlを使ってAPIを呼び出し、動作を確認できます。

curl -H "Authorization: Bearer $QIITA_ACCESS_TOKEN" \
  https://qiita.com/api/v2/authenticated_user

自分のQiitaユーザー情報がJSON形式で返ってくれば成功です。

公式ドキュメントはこちらです。

Qiita API v2 ドキュメント

5. Perlサンプルプログラム

実際にQiita APIを呼び出して、自分の記事一覧とアクセス数を取得するサンプルです。
1回に取得できるのは最大100件なので、記事がなくなるまでページを進めて取得しています。

#!/usr/bin/perl
use strict;
use warnings;
use open qw(:std :encoding(UTF-8));
use utf8;
use HTTP::Tiny;
use JSON::PP;

my $token = $ENV{QIITA_ACCESS_TOKEN};
die "QIITA_ACCESS_TOKEN is not set\n" unless $token;

my $http = HTTP::Tiny->new(
    default_headers => {
        Authorization => "Bearer $token",
    }
);

my $json = JSON::PP->new->utf8;

# 自分の記事一覧を取得(100件ずつ、記事がなくなるまで)
my @items;
for (my $page = 1; ; $page++) {
    my $res = $http->get(
        "https://qiita.com/api/v2/authenticated_user/items?per_page=100&page=$page"
    );
    die "$res->{status} $res->{reason}\n" unless $res->{success};

    my $list = $json->decode($res->{content});
    last unless @$list;
    push @items, @$list;
}

# HTMLエスケープ
sub h {
    my $s = shift // '';
    $s =~ s/&/&/g;
    $s =~ s/</&lt;/g;
    $s =~ s/>/&gt;/g;
    $s =~ s/"/&quot;/g;
    $s =~ s/'/&#39;/g;
    return $s;
}

my $total = 0;

print "Content-Type: text/html; charset=utf-8\n\n";
print "<table>\n";

for my $item (
    sort {
        ($b->{page_views_count} // 0) <=> ($a->{page_views_count} // 0)
    } @items
) {
    my $pv    = $item->{page_views_count} // 0;
    my $url   = h($item->{url});
    my $title = h($item->{title});

    print "<tr><th>$pv</th><td><a href='$url'>$title</a></td></tr>\n";

    $total += $pv;
}

print "<tr><th>$total</th><td>合計PV</td></tr>\n";
print "</table>\n";

このサンプルをCGIとして置くか、ターミナルで実行してHTMLをファイルに保存すると、自分の記事ごとのアクセス数と合計PV数を一覧で確認できます。

perl qiita_pv.pl > qiita_pv.html

※ 2026年11月時点で、記事一覧API(authenticated_user/items)から page_views_count を取得できることを確認しています(以前は一覧では null になるという報告もありました)。

0
0
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?