はじめに

初めましての人は初めまして、ChocolaMintです。Qiitaはお久しぶりですね。

今回はあんまり知られていない、Godotのとある「裏ワザ」を紹介します。

スクリプト参照とは

Godotでは、作成したスクリプトに「選択的に」名前を付けることができます。

# MyRefCounted.gd
class_name MyRefCounted extends RefCounted

そして、このクラス名は実は「変数」にアサインできます。

func _ready():
	var x := MyRefCounted
	print(x)

このコードを実行すると、下のようなメッセージが出ます。

<GDScript#-9223372005749815874>

なんと、スクリプトで他のスクリプトのクラス名を使う時、実はそのクラスの「スクリプト」を参照しています！

↑こいつです

ですから、ここのMyRefCountedは「スクリプト参照」と呼びます。

Godotでは、全てのオブジェクト型（= Objectを継承するクラス。つまりNode、Resource、RefCounted）はスクリプトを持つことができます。Object.get_script()でその参照を取得できます。

func _ready():
    var my_script := get_script() as Script # get_script()はVariant型ですからScriptにキャスト

Object.get_script()を使ったことある人はほぼいないと思いますけど、実はちゃんと使い道があるんです！ここからは本題に入ります。

スクリプト参照の使い方

ターン制バトルを採用したRPGでは、ターン経過で効果が発動し続けるバフやデバフがあります。「ぼうぎょ」、「リフレクト」、「どく」とか。

こういうバフやデバフは抽象クラスEffectを継承して実装してみましょう。

Effect（親クラス）
- GuardEffect（ぼうぎょ：受けたダメージを半減）
- ReflectEffect（リフレクト：魔法ダメージを反射）
- PoisonEffect（どく：ターンごと固定ダメージを与える）

ここでキャラクター側にDictionary[Script, Effect]を持たせて、現在適用されているエフェクトを管理します。

class_name Character extends RefCounted

var _effects : Dictionary[Script, Effect]

func add_effect(effect : Effect) -> void:
	var effect_script := effect.get_script() as Script
	_effects[effect_script] = effect

func remove_effect(effect_script : Script) -> bool:
	return _effects.erase(effect_script)

func has_effect(effect_script : Script) -> bool:
	return _effects.has(effect_script)

# ターン経過で全てのエフェクトを発動させ、切れたエフェクトを削除
# エフェクトのインスタンスには「あと何ターンで効果が切れる」、みたいな情報がある
func notify_effects_on_turn_start() -> void:
	var erase_list : Array[Effect]
	for effect_script in _effects:
		var effect := _effects[effect_script]
		effect.on_turn_start(self)
		if effect.is_expired(): # 切れたエフェクトを削除リストに追加
			erase_list.append(effect)
	for effect in erase_list:
		_effects.erase(effect)
		effect.on_expired(self)

こんな感じで「ぼうぎょ」を始めます。

func defend():
    add_effect(GuardEffect.new())

そしてこんな感じで「ぼうぎょ」をやめます。

func stop_defending():
    remove_effect(GuardEffect)

スクリプト参照を使って、キャラクターが特定のバフやデバフを持っているかを確認できます。

例えばダメージ計算では、こんな感じで「ぼうぎょ」の判定ができます。

# 通常時：ダメージ = 攻撃側の攻撃力 x 技の倍率 - 相手の防御力
# 相手が防御している時：ダメージ = 通常時のダメージ / 2
# ダメージは1以下にならない
func calculate_damage(attacker : Character, defender : Character, attack_multiplier : float):
    var damage := int(attacker.get_attack() * attack_multiplier - defender.get_defense())
    if defender.has_effect(GuardEffect): # ここでスクリプト参照
        damage /= 2
    if damage < 1:
        damage = 1
    return damage

これでキャラクターに「ぼうぎょ」用のフラグを持たせなくて済みます。RPGの数式はこういう後付けの「例外」がよくありますから、新しいenumや変数を一々追加することが多いですけど、スクリプト参照を使って既存の情報を使いまわせば色々管理しやすくなると思います。

おわりに

…まあ、そのくらいの使い方かなと思いますね。英語で調べても出てこなかったのでここが初出かもしれません。

もし機会があればぜひ使ってみてください。

それでは、良いゲーム制作生活を！