Autodesk backburnerのアップデート用バッチファイル

Autodesk backburnerのバージョンを更新するバッチファイルです。Autodesk backburnerについてはこちらを参照してください。

コマンドラインでジョブ投入できるのでAutodesk製品以外でもネットワークレンダリングに使用できます。

backburnerは下記URLでAutodesk Accountを作成すれば誰でもダウンロードできます。
https://accounts.autodesk.com/LogOn?theme=light

環境は以下の通り。

ドメイン名: MyDomain
作業ユーザー: backburner(インストール先ホストのadministrator権限あり)
パスワード: backburner
共有フォルダのあるサーバー: server01(MyDomainに参加)
インストーラのある場所: \Setup\backburner

ターゲットのサーバーが5台あり、ホスト名がrender01〜05だとします。その場合下のようなリストファイルを作成します。

hosts_list.txt

render01
render02
render03
render04
render05

現在既にbackbuner 2015がインストールされていて、2017に更新する場合、\\server01\Setup\backburner\2015にアンインストールするbackburnerのインストーラ(backburner.msi)、\\server01\Setup\backburner\2017にインストールするbackburnerのインストーラを置きます。

bb_updata.bat

@echo off

set INSTUSER=backburner
set UNST_VER=2015
set INST_VER=2017
set SVR_PATH=\\server01\Setup\backburner

set UNST_PATH=%SVR_PATH%\%UNST_VER%
set INST_PATH=%SVR_PATH%\%INST_VER%

set DEST_PATH=C:\Users\%INSTUSER%\Desktop
set USERNAME=backburner
set PASSWORD=backburner
set DOMNAME=MYDOMAIN

IF "%1"=="" GOTO NOHOST
IF NOT EXIST "%1" GOTO NOHOSTFILE

FOR /F %%A IN (%1) DO (
rem uninstall backburner %UNST_VER%

call psexec \\%%A -u %DOMNAME%\%USERNAME% -p %PASSWORD%  xcopy %UNST_PATH% %DEST_PATH%\%UNST_VER% /S /Y /I
call psexec \\%%A -u %DOMNAME%\%USERNAME% -p %PASSWORD% msiexec /x   %DEST_PATH%\%UNST_VER%\backburner.msi /qn

rem install backburner %INST_VER%

call psexec \\%%A -u %DOMNAME%\%USERNAME% -p %PASSWORD%  xcopy %INST_PATH% %DEST_PATH%\%INST_VER% /S /Y /I
call psexec \\%%A -u %DOMNAME%\%USERNAME% -p %PASSWORD% msiexec /i   %DEST_PATH%\%INST_VER%\backburner.msi /qn

)

GOTO END

:NOHOST
echo  ホストファイルを指定してください。
GOTO END

:NOHOSTFILE
echo ホストファイル%1が見つかりません。

:END

あとは下のようにホストのリストファイルを引数にバッチファイルを起動すればターゲットのホストのbackburner 2015がアンインストールされてbackburner 2017がインストールされます。

C:\Users\backburner> bb_update.bat hosts_list.txt