DHCP/IP固定変更スクリプト

@echo off
echo DHCP/IP固定変更スクリプト

:: 変数設定
set IFNAME="ワイヤレスネットワーク接続"
set IPADDR="xxx.xxx.xxx.xxx"
set MASK="xxx.xxx.xxx.xxx"
set GW="xxx.xxx.xxx.xxx"
set DNS1="xxx.xxx.xxx.xxx"
set DNS2="xxx.xxx.xxx.xxx"
set LOGFILE="%~dp0network_config_log.txt"

:: 管理者権限チェック
whoami /priv | find "SeDebugPrivilege" > nul
if %errorlevel% neq 0 (
    powershell start-process "%~0" -verb runas
    exit
)

:: 現在の設定をログファイルに保存
echo [変更前の設定: %date% %time%] >> %LOGFILE%
ipconfig /all >> %LOGFILE%
echo. >> %LOGFILE%

:: モード選択
set /p MODE="IP設定を選択してください (1: 固定IP, 2: 動的IP): "

if "%MODE%"=="1" (
    echo 固定IPに設定中...
    netsh interface ipv4 set address name=%IFNAME% static %IPADDR% %MASK% %GW% 1
    netsh interface ipv4 set dnsservers name=%IFNAME% static %DNS1% primary validate=no
    netsh interface ipv4 add dnsservers name=%IFNAME% %DNS2% index=2 validate=no
    echo 固定IP設定が完了しました。
) else if "%MODE%"=="2" (
    echo 動的IPに設定中...
    netsh interface ipv4 set address name=%IFNAME% dhcp
    netsh interface ipv4 set dnsservers name=%IFNAME% dhcp
    echo 動的IP設定が完了しました。
) else (
    echo 無効な選択です。スクリプトを終了します。
    pause
    exit
)

:: 新しい設定をログファイルに保存
echo [変更後の設定: %date% %time%] >> %LOGFILE%
ipconfig /all >> %LOGFILE%
echo. >> %LOGFILE%

:: 表示
echo 設定変更後の情報:
ipconfig /all
pause