概要

GCP上にParsecサーバーを構築する。

目的

Parsec による低遅延リモートデスクトップの検証。
デスクトップ共有により、オンラインプレイ未対応ゲームを無理矢理オンラインプレイする。

事前調査

Parsec
Parsecとは、デスクトップキャプチャアプリケーション……と言うとわかりにくいが、簡単に言うとリモートデスクトップアプリケーションである。
　
Connect to Work or Games from Anywhere | Parsec
　
特徴としては下記が挙げられる。
　
　① 非常に低遅延である
　② デスクトップ共有ソフトウェアとして使用出来る　
　
どれくらい低遅延かと言うと、ホスト上で実行したゲームをローカルからプレイするリモートプレイがサクサクなのである。
しかも、それを共有出来てしまうので、ローカル対戦やローカルCo-opしか対応していないアプリ・ゲームを、遠隔地にいる人とオンラインプレイすることが出来る。
　
もちろん、ローカルPC上にインストールしたParsecでも良いのだが、フレーム単位のラグがプレイに大きく影響するようなゲームだと、ホスト側とクライアント側でのフレーム差から不公平感が生まれてしまうので、今回はクラウド上に構築することにした。
コスト
アプリケーションの性質上、GPU機能が必須となるため、Minecraftサーバーなどと比較するとインスタンス料金はやや高くなる。
調べた感じ、1時間あたり100～200円程度かかるようだ。
ゲーセンで遊ぶコストと比較すれば全然安いが、ガッツリやると思わぬ請求が来るかもしれないので気をつけよう。

1. 構築

インフラ部分については、以前構築したMinecraftサーバー用の物を流用するので、詳細は割愛。

インフラ部分の構築、Minecraftサーバー構築に興味のある方は、下記記事を見ていただけると嬉しい。
【GCP】統合版MinecraftサーバーをGCEで建てる【統合版Minecraft】

Minecraftサーバーについては、統合版→Java版に変更する記事や、バージョンアップの記事なども書いているので、こちらも興味があれば是非。
【GCP】統合版MinecraftサーバーをGCEで建てる2【統合版Minecraft】
【GCP】統合版MinecraftサーバーをGCEで建てる3【統合版Minecraft】
【GCP】Java版MinecraftサーバーをGCEで建てる【Java版Minecraft】
【GCP】GCEで建てたJava版Minecraftサーバー（Spigot）をバージョンアップする（1.18.2→1.19）【Java版Minecraft】

今回のParsecサーバーについては、Windows Server 2022 上に構築する。
また、「Parsec（もしくはリモートデスクトップ）でリモート接続する」以外には、今のところ外部からサーバーに対して何か操作をしたりすることは想定していないので、サービスアカウントやらロールやらと、細かい設計・構築は不要としているが、Firewallについては「3389」の穴開けが必要である。

本記事では、自動構築のためのterraformコードや、sysprep時に実行するスクリプトなどを主な内容とする。

1.1. GCE設計

主要スペックは一旦下記とした。

Parameter	Value
OS	windows-server-2022-dc-v20220712
インスタンスタイプ	n1-standard-4
GPU	nvidia-tesla-t4-vws
ディスクタイプ	pd-standard
ディスク容量	50GB
リージョン	asia-northeast1-a
preemptible	true

ポイントは、GPUが必要なことと、インスタンスタイプ・リージョン・ゾーンなどの組み合わせによって、利用可能なGPUが異なる。
2022年8月現在では、「NVIDIA Tesla T4」を利用する場合、「asia-northeast1-a」もしくは「asia-northeast1-c」を選択する必要がある。

また、Windows Server のバージョンによって、ディスクの最小容量が異なる。
今回選択した「Windows Server 2022 Datacenter」では、最小容量50GBとなる。

1.2. GCE作成用コード

GCE作成用のコードは下記。
元々、Linux想定のコードであったため、Windowsにも対応出来るよう修正した。

service01\service01_gce.tf

service01\service01_gce.tf

resource "google_compute_instance" "service01_gce" {
  for_each = var.gce[terraform.workspace]

  name         = join("-", [var.gcp_common.org_name, var.service01_pj, each.key, terraform.workspace])
  machine_type = each.value.machine_type
  #zone         = var.gcp_common.zone
  zone         = each.value.zone
  project      = join("-", [var.gcp_common.org_name, var.service01_pj, terraform.workspace])

  deletion_protection = each.value.deletion_protection

  tags         = [terraform.workspace, each.key]

  boot_disk {
    auto_delete = true
    device_name = join("-", [var.gcp_common.org_name, var.service01_pj, each.key, terraform.workspace])
    initialize_params {
      image = each.value.image
      type  = each.value.type
      size  = each.value.size
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.service01-gce-subnets.id
    access_config {
      #nat_ip       = google_compute_address.mcs-ip.address
      #network_tier = "STANDARD"
    }
  }

  service_account {
    # Google recommends custom service accounts that have cloud-platform scope and permissions granted via IAM Roles.
    email  = google_service_account.minecraft.email
    scopes = ["cloud-platform"]
  }

  #preemptible設定
  dynamic scheduling {
    for_each = each.value.scheduling

    content {
      preemptible         = scheduling.value.preemptible
      automatic_restart   = scheduling.value.automatic_restart
      on_host_maintenance = scheduling.value.on_host_maintenance
    }
  }

  metadata = {
    startup-script = each.value.metadata_startup_script
    shutdown-script = each.value.metadata_shutdown_script

    block-project-ssh-keys = each.value.block-project-ssh-keys
    # GCE の metadata に必要な形式に整形して設定（改行コードの除去等）
    ssh-keys = "${var.gce_ssh.user}:${replace("${tls_private_key.keygen[each.value.key_name].public_key_openssh}", "\n", "")} ${var.gce_ssh.user}"

    user-data = "${each.value.user-data == null ? null : file("./templates/${each.value.user-data}")}"

    sysprep-specialize-script-ps1 = each.value.init_script == null ? null : file("./templates/${each.value.init_script}")
  }

  dynamic guest_accelerator {
    for_each = each.value.guest_accelerator

    content {
      type = guest_accelerator.value.type
      count = guest_accelerator.value.count
    }
  }

  lifecycle {
    ignore_changes = [
      metadata["ssh-keys"],
    ]
  }

}

ポイントは２つ。

service01\service01_gce.tf

  dynamic guest_accelerator {
    for_each = each.value.guest_accelerator

    content {
      type = guest_accelerator.value.type
      count = guest_accelerator.value.count
    }
  }

今回、用途的にGPUが必要となるため、「guest_accelerator」ブロックが必要となる。
GPU不要なインスタンスともコードを共有するため、dynamicブロックを使用している。
　

service01\service01_gce.tf

  metadata = {
    startup-script = each.value.metadata_startup_script
    shutdown-script = each.value.metadata_shutdown_script

    block-project-ssh-keys = each.value.block-project-ssh-keys
    # GCE の metadata に必要な形式に整形して設定（改行コードの除去等）
    ssh-keys = "${var.gce_ssh.user}:${replace("${tls_private_key.keygen[each.value.key_name].public_key_openssh}", "\n", "")} ${var.gce_ssh.user}"

    user-data = "${each.value.user-data == null ? null : file("./templates/${each.value.user-data}")}"

    sysprep-specialize-script-ps1 = each.value.init_script == null ? null : file("./templates/${each.value.init_script}")
  }

もう１つは、初期設定のための「metadata」ブロック。
Linux系では「user-data」を使用していたが、Windows系では「sysprep～」などになるため、null指定を活用して両対応としている。

また、sysprepの中でも、実行タイミングやスクリプト言語（PowerShell Scriptなのかバッチファイルなのか等）によって、指定するメタデータキーが異なる。
詳しくは下記を参照。
Windows VM での起動スクリプトの使用
 Windows on GCEにおける起動スクリプト Tips

今回は、PowerShell Scriptにて初期設定やユーザー作成などを行いたかったので「sysprep-specialize-script-ps1」としている。

ちなみにファイルパスが「./templates/～」となっているが、terraformのtemplate機能は今回使っていない。
元々は使っていたのだが、変数が多くなりすぎてyaml形式のtfファイルでの記述では管理がしづらくなってしまったのと、スクリプト内でも変数を扱うため、スクリプト内での宣言・使用に寄せた。
スクリプトの詳細については後述する。

tfファイルで宣言・使用している変数は下記。

service01\vars_gce.tf

service01\vars_gce.tf

variable "gce" {
  default = {
    dev = {
      minecraft-game-server = {
        machine_type             = "e2-standard-4"
        image                    = "ubuntu-os-cloud/ubuntu-1804-lts"
        type                     = "pd-standard"
        size                     = "30"
        block-project-ssh-keys   = true
        key_name                 = "mcs_key"
        deletion_protection      = false
        metadata_startup_script  = "cd /opt/minecraft/\nscreen -dmS tskserver java -Xms1024M -Xmx8G -jar spigot.jar --nogui"
        metadata_shutdown_script = null
        zone                     = "asia-northeast1-b"
        user-data                = "cloud-init_ubuntu.yaml"
        init_script              = null
        scheduling = {
          content ={
            preemptible            = true
            automatic_restart      = false
            on_host_maintenance    = "TERMINATE"
          }
        }
        guest_accelerator = {
        }
      }
      parsec-game-server = {
        machine_type             = "n1-standard-4"
        image                    = "windows-cloud/windows-server-2022-dc-v20220712"
        type                     = "pd-standard"
        size                     = "50"
        block-project-ssh-keys   = true
        key_name                 = "pgs_key"
        deletion_protection      = false
        metadata_startup_script  = null
        metadata_shutdown_script = null
        zone                     = "asia-northeast1-a"
        user-data                = null
        init_script              = "winsv2022_init.ps1"
        scheduling = {
          content ={
            preemptible            = true
            automatic_restart      = false
            on_host_maintenance    = "TERMINATE"
          }
        }
        guest_accelerator = {
          content ={
            type = "nvidia-tesla-t4-vws"
            count = 1
          }
        }
      }
    }
    prd = {
    }
  }
}

詳細は「1.1. GCE設計」参照。