LoginSignup
0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

@DamashiGami(コーポれーしょん 騙し髪)

この不親切な手順に救援を　其の６：それにしてもこのカメラ、ボロボロである

Last updated at Posted at 2025-07-15

Dell 7350 Detachable 内蔵 camera ですが
やたら使えなくなって
頻繁に復旧作業が必要になります

DellノートパソコンのカメラがTeams、Zoom、およびWindowsのカメラ アプリケーションで機能しない
https://www.dell.com/support/kbdoc/ja-jp/000248760/dell%E3%83%8E%E3%83%BC%E3%83%88%E3%83%91%E3%82%BD%E3%82%B3%E3%83%B3%E3%81%AE%E3%82%AB%E3%83%A1%E3%83%A9%E3%81%8Cteams-zoom-%E3%81%8A%E3%82%88%E3%81%B3windows%E3%81%AE%E3%82%AB%E3%83%A1%E3%83%A9-%E3%82%A2%E3%83%97%E3%83%AA%E3%82%B1%E3%83%BC%E3%82%B7%E3%83%A7%E3%83%B3%E3%81%A7%E6%A9%9F%E8%83%BD%E3%81%97%E3%81%AA%E3%81%84

Latitude 7350デタッチャブル ノートパソコンで背面カメラが検出されない
https://www.dell.com/support/kbdoc/ja-jp/000226712/latitude-7350%E3%83%87%E3%82%BF%E3%83%83%E3%83%81%E3%83%A3%E3%83%96%E3%83%AB%E3%81%8C%E8%83%8C%E9%9D%A2%E3%82%AB%E3%83%A1%E3%83%A9%E3%82%92%E6%A4%9C%E5%87%BA%E3%81%97%E3%81%AA%E3%81%84

「カメラが見つかりません」(0xA00F4244)エラーを解決する
https://www.dell.com/support/kbdoc/ja-jp/000125158/%E3%82%AB%E3%83%A1%E3%83%A9%E3%81%8C%E8%A6%8B%E3%81%A4%E3%81%8B%E3%82%8A%E3%81%BE%E3%81%9B%E3%82%93-0xa00f4244-%E3%82%A8%E3%83%A9%E3%83%BC%E3%82%92%E8%A7%A3%E6%B1%BA%E3%81%99%E3%82%8B

これらのサイトを照らし合わせて
何台か試してみた所

復旧に必要な前作業として

・BIOSを最新化する
・BIOSのカメラ設定を有効化する
・プライバシー設定をオンにする
・カメラアプリをリセット
・グラフィックス用ドライバを最新にする
・インテル マネージメント エンジン コンポーネントを最新にする

を行ってから

① カメラ関連のデバイスを アンインストール
② Intel-Serial-IO-Driver を インストール
③ Intel-Integrated-Sensor を インストール
④ カメラ用ドライバー を インストール

①～④を順番通りに行う必要があります

これらを一括で行うバッチを用意しました

C:\dell フォルダあたりに
関連のドライバを３つダウンロードして置いて
バッチファイル２つとも同じフォルダに置いて
復旧バッチを管理者として実行して下さい

日本語版は _7350Dtbl-カメラ-復旧.cmd
英語圏版は _7350Dtbl-Revive-Camera.cmd

です

バッチ終了後にカメラアプリを起動しますので
映らなかったらパソコンを再起動して下さい
それでも映らないなら殆どが故障で修理が必要です

日本語版

_7350Dtbl-カメラ-復旧.cmd
@echo off
title 機種選別

Powershell -command  "Get-CimInstance -ClassName Win32_ComputerSystemProduct | Select-Object -Property Name" | find /i "Latitude 7350 Detachable" > nul 2> nul || goto :eof

rem /;
rem /; C:\DELL
rem /; |   _7350Dtbl-カメラ-復旧.cmd ← 管理者として実行
rem /; |   _デバイスマネージャーで元の名前INFから公開名INFを探す.cmd
rem /; |   Intel-2D-Imaging-USB-Bridge-Driver-for-Camera_74.22000.2.22_A05.EXE
rem /; |   Intel-Integrated-Sensor-Solution-Driver_830GM_WIN64_3.10.100.7681_A01_01.EXE
rem /; |   Intel-Serial-IO-Driver_HNDHH_WIN64_30.100.2318.58_A00_02.EXE
rem /;

Title 7350Dtbl カメラ復旧

rem /;
rem /; デバイスをアンインストール
rem /;

rem /;                                                                                       Intel AVStream Camera
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "iacamera64.inf"')                   do pnputil /delete-driver %%0 /uninstall /force & echo;
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "iacamera64_ext_dell_kenai.inf"')    do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                                       Camera Sensor OG0VA1B
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "og0va1b.inf"')                      do pnputil /delete-driver %%0 /uninstall /force & echo;
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "og0va1b_extension_dell_kenai.inf"') do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                                       Camera Sensor OV08X40
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "ov08x40.inf"')                      do pnputil /delete-driver %%0 /uninstall /force & echo;
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "ov08x40_extension_dell_kenai.inf"') do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                                       Camera Sensor OV8856
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd"  "ov8856.inf"')                      do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                                       Intel Control Logic
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd" "iactrllogic64.inf"')                do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                                       Intel Imaging Signal Processor
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd"       "iaisp64.inf"')                do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                                       Intel Integrated Sensor Solution
for /f "delims=" %%0 in ('call "%~dp0_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd"        "ishoed.inf"')                do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;
rem /; デバイスドライバをインストール（サイレント）
rem /;

for /f "delims=" %%0 in ('dir /o:d /b "%~dp0*Serial-IO-Driver*"')  do set CAMFile=%%0
start "" /Wait                                                     "%~dp0%CAMFile%" /s
for /f "delims=" %%0 in ('dir /o:d /b "%~dp0*Integrated-Sensor*"') do set CAMFile=%%0
start "" /Wait                                                     "%~dp0%CAMFile%" /s
for /f "delims=" %%0 in ('dir /o:d /b "%~dp0*2D-Imaging*"')        do set CAMFile=%%0
start "" /Wait                                                     "%~dp0%CAMFile%" /s

rem /;
rem /; カメラ起動
rem /;

start "" microsoft.windows.camera:
_デバイスマネージャーで元の名前INFから公開名INFを探す.cmd
@echo off

rem /;
rem /; ★ デバイスマネージャーの 元の名前.inf から 公開名.inf を 調べるだけ
rem /;
rem /;    デバイスのアンインストール を 行うには
rem /;      pnputil /delete-driver 公開名.inf /uninstall /force
rem /;    で 実行する
rem /;
rem /;    公開名.inf は 元の名前.inf を 元に調べる必要があり
rem /;    元の名前.inf は
rem /;    デバイスマネージャーの対象デバイスのプロパティで
rem /;    詳細タブのプロパティで 【 Inf 名 】 が 元の名前.inf
rem /;
rem /;    "バッチファイル名" "元の名前.inf" で 公開名.inf が 出力される
rem /;
rem /;    pnputil /enum-drivers の 出力 が
rem /;
rem /;    公開名:     oem0.inf
rem /;    元の名前:      ov5678.inf
rem /;    プロバイダー名:      Intel Corporation
rem /;    クラス名:         システム デバイス
rem /;    クラス GUID:         {4d36e97d-e325-11ce-bfc1-08002be10318}
rem /;    ドライバー バージョン:     10/13/2021 60.22000.6053.1
rem /;    署名者名:        Microsoft Windows Hardware Compatibility Publisher
rem /;
rem /;    公開名:     oem1.inf
rem /;    元の名前:      ov8856.inf
rem /;    プロバイダー名:      Intel Corporation
rem /;    クラス名:         システム デバイス
rem /;    クラス GUID:         {4d36e97d-e325-11ce-bfc1-08002be10318}
rem /;    ドライバー バージョン:     10/13/2021 60.22000.6053.1
rem /;    署名者名:        Microsoft Windows Hardware Compatibility Publisher
rem /;
rem /;    の 場合
rem /;
rem /;    元の名前 ov5678.inf の デバイスをアンインストールしたい場合
rem /;    pnputil /delete-driver oem0.inf /uninstall /force
rem /;
rem /;    "バッチファイル名" "ov5678.inf" で oem0.inf が 出力される
rem /;

set                                      公開名=

for /f "tokens=1-2 delims=: "     %%1 in ('Pnputil /Enum-Drivers ^| Findstr "公開名 元の名前"') do (
   if      /i                    "%%1"=="公開名" (
       call                         set "公開名=%%2"
     ) else (
       if      /i "%%1-%%2"=="元の名前-%~1" (
           call                   echo;%%公開名%%
       )
   )
)

英語圏版

_7350Dtbl-Revive-Camera.cmd
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

Title Select Model

Powershell -command  "Get-CimInstance -ClassName Win32_ComputerSystemProduct | Select-Object -Property Name" | find /i "Latitude 7350 Detachable" > nul 2> nul || goto :eof

rem /;
rem /; C:\DELL
rem /; |   _7350Dtbl-Revive-Camera.cmd <- run as administrator
rem /; |   _OEM_INF-From-Original_INF.cmd
rem /; |   Intel-2D-Imaging-USB-Bridge-Driver-for-Camera_74.22000.2.22_A05.EXE
rem /; |   Intel-Integrated-Sensor-Solution-Driver_830GM_WIN64_3.10.100.7681_A01_01.EXE
rem /; |   Intel-Serial-IO-Driver_HNDHH_WIN64_30.100.2318.58_A00_02.EXE
rem /;

Title 7350 Dtbl Revive the Camera

rem /;
rem /; Uninstall Device
rem /;

rem /;                                                                Intel AVStream Camera
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "iacamera64.inf"')                   do pnputil /delete-driver %%0 /uninstall /force & echo;
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "iacamera64_ext_dell_kenai.inf"')    do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                Camera Sensor OG0VA1B
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "og0va1b.inf"')                      do pnputil /delete-driver %%0 /uninstall /force & echo;
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "og0va1b_extension_dell_kenai.inf"') do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                Camera Sensor OV08X40
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "ov08x40.inf"')                      do pnputil /delete-driver %%0 /uninstall /force & echo;
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "ov08x40_extension_dell_kenai.inf"') do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                Camera Sensor OV8856
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd"  "ov8856.inf"')                      do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                Intel Control Logic
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd" "iactrllogic64.inf"')                do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                Intel Imaging Signal Processor
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd"       "iaisp64.inf"')                do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;                                                                Intel Integrated Sensor Solution
for /f "delims=" %%0 in ('call "%~dp0_OEM_INF-From-Original_INF.cmd"        "ishoed.inf"')                do pnputil /delete-driver %%0 /uninstall /force & echo;

rem /;
rem /; Install Device Driver (Silent)
rem /;

for /f "delims=" %%0 in ('dir /o:d /b "%~dp0*Serial-IO-Driver*"')  do set CAMFile=%%0
start "" /Wait                                                     "%~dp0%CAMFile%" /s
for /f "delims=" %%0 in ('dir /o:d /b "%~dp0*Integrated-Sensor*"') do set CAMFile=%%0
start "" /Wait                                                     "%~dp0%CAMFile%" /s
for /f "delims=" %%0 in ('dir /o:d /b "%~dp0*2D-Imaging*"')        do set CAMFile=%%0
start "" /Wait                                                     "%~dp0%CAMFile%" /s

rem /;
rem /; Camera Start
rem /;

start "" microsoft.windows.camera:
_OEM_INF-From-Original_INF.cmd
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

set                                      Published=

for /f "tokens=1-4 delims=: "     %%1 in ('Pnputil /Enum-Drivers ^| Findstr "Published Original"') do (
   if      /i                    "%%1"=="Published" (
       call                         set "Published=%%3"
     ) else (
       if      /i "%%1-%%3"=="Original-%~1" (
           call                   echo;%%Published%%
       )
   )
)
0
0
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
Sign upLogin
0
0

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?