Help us understand the problem. What is going on with this article?

WindowsでiTunesによるiPhone/iPad等のバックアップ先を一発で変更する方法

More than 3 years have passed since last update.

バックアップ先変更方法

何も考えずに、以下のバッチを管理者として実行したコマンドプロンプトで実行してください。

例として、バックアップ先をD:\iPhone\Backupに変更しています。
このパスはご自分の環境に書き換えてご利用ください。

change_apple_backup_dir.bat
@echo off
cd /d %~dp0
setlocal


@REM *************** Change here ***************

set APPLE_NEW_BKDIR=D:\iPhone\Backup

@REM *******************************************


@REM *******************************************
@REM ************ Define variables *************
@REM *******************************************

set APPLE_ORG_BKDIR=C:\Users\%USERNAME%\AppData\Roaming\Apple Computer\MobileSync\Backup
set TMP_DATE=%DATE%
set TMP_TIME=%TIME: =0%
set TMP_BKNAME=Backup_%TMP_DATE:~-10,4%%TMP_DATE:~-5,2%%TMP_DATE:~-2,2%%TMP_TIME:~0,2%%TMP_TIME:~3,2%%TMP_TIME:~6,2%


@REM *******************************************
@REM ****** Rename original backup folder ******
@REM *******************************************

IF NOT EXIST "%APPLE_ORG_BKDIR%" GOTO :SKIP_RENAME

rename "%APPLE_ORG_BKDIR%" "%TMP_BKNAME%"
echo %APPLE_ORG_BKDIR%%TMP_BKNAME% にリネームしてバックアップしました。

:SKIP_RENAME


@REM *******************************************
@REM ******** Create new backup folder *********
@REM *******************************************

IF EXIST "%APPLE_NEW_BKDIR%" GOTO :SKIP_MKDIR

mkdir "%APPLE_NEW_BKDIR%"
echo %APPLE_NEW_BKDIR% フォルダを作成しました。

:SKIP_MKDIR


@REM *******************************************
@REM ********** Create symbolic link ***********
@REM *******************************************

echo mklink /J "%APPLE_ORG_BKDIR%" "%APPLE_NEW_BKDIR%"
mklink /J "%APPLE_ORG_BKDIR%" "%APPLE_NEW_BKDIR%"


endlocal

ネットで軽く検索したところ手動操作が多くイヤだったのでバッチ化してみました。
現在のバックアップ先を知りたい場合はC:\Users\%USERNAME%\AppData\Roaming\Apple Computer\MobileSync配下のBackupのリンク先を確認してください。

すでにバックアップフォルダがあったらバックアップ&新しいバックアップ先がなければmkdirしてます。
エラー処理は行ってないのでエラーになったら適当に対処してください。

変更した設定を元に戻す方法

C:\Users\%USERNAME%\AppData\Roaming\Apple Computer\MobileSyncに移動して、
シンボリックリンクBackupを削除した後、Backupフォルダを新規に作ったり、
本バッチでバックアップしたBackup日付時刻フォルダをリネームしたりして元に戻します。

Why not register and get more from Qiita?
  1. We will deliver articles that match you
    By following users and tags, you can catch up information on technical fields that you are interested in as a whole
  2. you can read useful information later efficiently
    By "stocking" the articles you like, you can search right away
Comments
No comments
Sign up for free and join this conversation.
If you already have a Qiita account
Why do not you register as a user and use Qiita more conveniently?
You need to log in to use this function. Qiita can be used more conveniently after logging in.
You seem to be reading articles frequently this month. Qiita can be used more conveniently after logging in.
  1. We will deliver articles that match you
    By following users and tags, you can catch up information on technical fields that you are interested in as a whole
  2. you can read useful information later efficiently
    By "stocking" the articles you like, you can search right away
ユーザーは見つかりませんでした