計算式プラグインで、テーブルを集計し別テーブルに反映できるようになりました。
区分毎や担当者毎に数値を集計することが計算式の指定だけで対応できます。
※計算式プラグイン Ver.48以降でサポート

概要

テーブルの計算式に、TLTABLE：テーブル集計関数を指定することで、集計結果を別テーブルに反映できます。

例１　ドロップダウンごとに集計

テーブル２の計算式：
TLTABLE(テーブル,
　TPFILTER(数値>0),
　TPKEY(ドロップダウン),
　TPVAL(数値),
　TPOUT(ドロップダウンT2,数値T2))

TLTABLE(テーブル：　集計元テーブル
TPFILTER(数値>0)：　数値が 1以上を集計
TPKEY(ドロップダウン),：　集計キー
TPVAL(数値),：　集計項目
TPOUT(ドロップダウンT2,数値T2))：　出力先項目

※TPSORT を指定しない場合は、TPKEY の集計ーで昇順にソート

例２　ドロップダウンごとに集計し、数値の降順でソート

テーブル２の計算式：
TLTABLE(テーブル,
　TPFILTER(数値>0),
　TPKEY(ドロップダウン),
　TPVAL(数値),
　TPOUT(ドロップダウンT2,数値T2),
　TPSORT(数値T2,0)
)

TPSORT(数値T2,0) ：　数値T2 で降順(1:昇順,0:降順)にソート

テーブルの計算式

テーブルに、TLTABLE 関数を指定することで、集計します。

TLTABLE：　テーブルの集計関数
- TLTABLE(テーブル,
  
  TPKEY(日付,ドロップダウン),　：キー項目
  
  TPVAL(数値),　：集計項目[,"sum","max","min","join","uniq"]
  
  TPOUT(日付T2,ドロップダウンT2,数値),　：出力先項目
  
  [TPOPT("MAXROWS",10)...])
- TPKEY：　集計キーとなる項目：　TPKEY(日付,ドロップダウン,文字列)
- TPVAL：　集計項目（計算式可）と集計方法（規定値："sum"）
  - 集計方法：　"sum","max","min","join","uniq"
  - TPVAL(数値,数値,"max")
  - TPVAL(チェックボックス,"uniq",SEL_CODE(ユーザー選択,"array"),"uniq")
- TPOUT：　出力先項目
  - キー項目と集計項目の数の合計と同じ出力先項目数を指定
  - TPKEY(日付),TPVAL(数値),TPOUT(日付1,数値1)
- [TPOPT] 関数で、オプションを指定
  - MAXROWS: 規定値　""　：最大行数
- [TPFILTER(条件)]：　出力するテーブル行の条件を指定　
  - TPFILTER(数量>0)
- [TPSORT(項目[,フラグ]...)]：　出力するテーブル行のソートを指定
  - フラグ：　1:　昇順、0: 降順
    - TPSORT(項目1,0,項目2)
- [TPLABEL("ラベル"[,"ラベル"...])：　出力する項目名を変更
  - TPLABEL("区分","金額")
- 例 TLTABLE(テーブル,TPKEY(文字列),TPVAL(数値),TPOUT(文字列2,数値2)
- 例 TLTABLE(テーブル,TPFILTER(数値>0),TPKEY(文字列),TPVAL(数値),TPOUT(文字列2,数値2)
  - 数値>0 の行のみ集計
- 例 TLTABLE(テーブル,TPKEY(文字列),TPVAL(数値),TPOUT(文字列2,数値2),
  TPSORT(数値2,0)
  - 数値2 の降順で出力
- 例 TLTABLE(テーブル,TPKEY(文字列),
  
  TPVAL(チェックボックス,"uniq",SEL_CODE(ユーザー選択,"array"),"uniq"),
  
  TPOUT(チェックボックス2,ユーザー選択2))
  - チェックボックス、ユーザー選択の値を重複なしで集約

ユーザー選択、チェックボックスの集計

ユーザー選択、チェックボックスなども集計できます。
日付ごとに、ユーザー選択、チェックボックスを集計します。

テーブル２の計算式：
TLTABLE(テーブル,
　TPKEY(日付),
　TPVAL(SEL_CODE(ユーザー選択,"array"),"uniq",
　　ARRAY(チェックボックス),"uniq",
　　ARRAY(チェックボックス),"uniq",
　　数値),
　TPOUT(日付T2,ユーザー選択T2,チェックボックスT2,文字列2A,数値T2),
)

TPVAL(SEL_CODE(ユーザー選択,"array"),"uniq", ：　ユーザー選択を配列で取り出す

ARRAY(チェックボックス),"uniq",　：　チェックボックスを配列で取り出す

ARRAY(チェックボックス),"uniq",　：　チェックボックスを配列で取り出す

数値),　：　数値を集計
TPOUT(日付T2,ユーザー選択T2,チェックボックスT2,文字列2A,数値T2),　：集計先項目を指定
- キー項目と集計項目分の集計先項目をしてします。
- 日付 -> 日付T2
- SEL_CODE(ユーザー選択,"array"),"uniq"　-> ユーザー選択T2
- ARRAY(チェックボックス),"uniq" -> チェックボックスT2
- ARRAY(チェックボックス),"uniq" -> 文字列2A
- 数値 [,"sum"] -> 数値T2

※ uniq で、集計すると値が重複しないように、集計します。

ドロップダウン項目、日付の集計

教科ごとに、日付を文字列に集計します。

計算式

.js

// 集計テーブル
TLTABLE(テーブル,
  TPKEY(教科),
  TPVAL(DATE_FORMAT(日付),"uniq"),
  TPOUT(教科T,日付T),
)

複数ドロップダウン項目、日付の集計

テーブルの複数項目について、日付の集計を行います。

.js

// 集計テーブル
ARRAY_COUNT(TDS(科目1,科目2,科目3))
// 科目T
LET(w1,ARRAY_SORT(TDS(科目1,科目2,科目3)),
  ARRAY_GET(w1,ROWNO(集計テーブル))
)
// 日付T
LET(w1,科目T,
  w2,TDSIF(IN(w1,科目1,科目2,科目3),DATE_FORMAT(日付)),
  ARRAY_SORT(w2)
)

複数ドロップダウン項目、日付の集計（ドロップダウン項目を日付順にソート）

作業用項目「日付項目」の内容例
作業用項目「日付項目」を追加
ドロップダウン項目を日付順にソートするため、ソート用に「日付項目」を追加します。

.js

// 集計テーブル
ARRAY_COUNT(TDS(科目1,科目2,科目3))
// 科目T
LET(w1,ARRAY_GET(SPLIT(日付科目,","),ROWNO(集計テーブル)),
  ARRAY_GET(SPLIT(w1,"_"),1)
)
// 日付T
LET(w1,科目T,
  w2,TDSIF(IN(w1,科目1,科目2,科目3),DATE_FORMAT(日付)),
  ARRAY_SORT(w2)
)
// 日付科目
LET(w1,ARRAY_SORT(TDS(科目1,科目2,科目3)),
  w2,ARRAY_MAP(w1,xx,
    DATE_FORMAT(MINIF(IN(xx,科目1,科目2,科目3),
       日付))&"_"&xx),
  ARRAY_SORT(w2)
)

複数ドロップダウン項目、数値の集計

テーブルの複数項目について、数値の集計を行います。

集計テーブルは、4 の固定行数として、科目別に時間数を集計します。

.js

// 集計テーブル SUBTABLE
4

// 集計テーブル.科目T DROP_DOWN
ARRAY_GET(
  ARRAY("算数","国語","理科","社会"),
  ROWNO(集計テーブル)
)

// 集計テーブル.時間T NUMBER
LET(a,科目T,
  SUM(IF(科目1=a,時間1),IF(科目2=a,時間2),IF(科目3=a,時間3))
)

rex0220 計算式プラグイン テーブル集計

概要