More than 1 year has passed since last update.

rex0220 計算式プラグインテーブル内集計消費税計算

kintone

Posted at 2023-10-18

kintone のテーブルで、小計に税抜金額、消費税、税込金額を計算してみます。
計算式プラグイン、項目検証プラグイン、項目書式プラグイン、ちょっと便利なプラグインを使います。

概要

税抜金額、消費税、税込金額を計算し、小計行でセット毎の小計を表示します。
テーブルに、小計の計算用項目を追加して、非表示にします。
※テーブル行数が多くなると、計算処理に時間がかかります。

詳細画面
編集画面
小計の計算用項目

操作例

計算式プラグインの設定

「循環参照を許可」、「非同期計算」をチェックします。

.js

OPTION: 循環参照を許可, 非同期計算

// 税抜金額合計 NUMBER
SUMIF(分類="小計",税抜金額)

// 消費税10%合計:消費税10合計 NUMBER
SUMIF(分類="小計",消費税10)

// 消費税8%合計:消費税8合計 NUMBER
SUMIF(分類="小計",消費税8)

// 税込金額合計 NUMBER
SUMIF(分類="小計",税込金額)

// テーブル.No NUMBER
ROWNO(テーブル)+1

// テーブル.商品 SINGLE_LINE_TEXT (editable)
IF(分類="小計",SUBTABLE(セット名,ROWNO(テーブル)-1),
  商品
)

// テーブル.数量 NUMBER (editable)
IF(分類="明細",数量)

// テーブル.単価 NUMBER (editable)
IF(分類="明細",単価)

// テーブル.税抜金額 NUMBER
SWITCH(分類,
  "明細",単価*数量,
  "小計",SUBTABLE(税抜金額累計,ROWNO(テーブル)-1),
  ""
)

// テーブル.税区分 DROP_DOWN (editable)
IF(分類="明細",税区分)

// テーブル.消費税10%:消費税10 NUMBER
IFS(AND(税区分="10",分類="明細"),
  ROUNDDOWN(単価*数量*税区分/100),
  分類="小計",SUBTABLE(消費税10累計,ROWNO(テーブル)-1),
)

// テーブル.消費税8%:消費税8 NUMBER
IFS(AND(税区分="8",分類="明細"),
  ROUNDDOWN(単価*数量*税区分/100),
  分類="小計",SUBTABLE(消費税8累計,ROWNO(テーブル)-1),
)

// テーブル.税込金額 NUMBER
IF(分類!="概要",TR_SUM(税抜金額,消費税10,消費税8))

// テーブル.セット名 SINGLE_LINE_TEXT (hide)
IF(分類="概要",商品,SUBTABLE(セット名,ROWNO(テーブル)-1))

// テーブル.税抜金額累計 NUMBER (hide)
IF(分類!="概要",
  TR_SUM(税抜金額,SUBTABLE(税抜金額累計,ROWNO(テーブル)-1))
)

// テーブル.消費税10%累計:消費税10累計 NUMBER (hide)
IF(分類!="概要",
  TR_SUM(消費税10,SUBTABLE(消費税10累計,ROWNO(テーブル)-1)),
)

// テーブル.消費税8%累計:消費税8累計 NUMBER (hide)
IF(分類!="概要",
  TR_SUM(消費税8,SUBTABLE(消費税8累計,ROWNO(テーブル)-1)),
)