Windowsのサインイン画面に表示される壁紙をコピーするバッチ

Windowsのサインイン画面に表示される壁紙（Spotlight）がキレイなものが多くて気に入ったので、200kB以上の画像があればPictureにコピーするコマンドラインバッチを作ってみた。
clon的な感じで、タスクスケジューラに入れておけば、取りそびれることもない。

適当な名前でSJISのファイルを作成する
例）spotligntGetter.bat

setlocal
echo OFF

rem =========== 変数宣言箇所 ===============

rem コピーするファイルの最低サイズ(byte)
set LOWER_LIMIT_SIZE=200000
rem コピー先のディレクトリ
set TARGET_PATH=C:\Users\【ユーザ名】\Pictures\spotlignt
rem Spotligntの画像があるディレクトリ
set SPOTLIGNT_DIR=C:\Users\【ユーザ名】\AppData\Local\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets

rem =========== 変数宣言終了 ===============

echo Windowsのログイン画面に出る画像の中から%LOWER_LIMIT_SIZE%byte以上のファイルをPicturesに保存するバッチ

rem =========== コピー先ディレクトリが無ければ作る ===============
if not exist %TARGET_PATH% mkdir %TARGET_PATH%  
echo ■保存先は：%TARGET_PATH%

rem =========== コピー対象のファイルがあるディレクトリに移動する ===============
cd %SPOTLIGNT_DIR%
echo ■Spotlightディレクトリは：%SPOTLIGNT_DIR%
echo ---------------------------------------


rem =========== コピー処理開始 ===============
for %%F in ( * ) do (
    if %%~zF GEQ %LOWER_LIMIT_SIZE% (
        if exist %TARGET_PATH%\%%F.png (
            echo %%F is already exists.
        ) else (
            echo %%F is copied.
            copy %%F %TARGET_PATH%\%%F.png
        )
    )
)


pause

endlocal