[EXCEL]日付、時刻の対応している表示形式全パターン

日付や時刻の文字列をシリアル値に変換する場合、Excelの自動認識に対応している形式の文字列の場合、文字列に演算を加えるだけで変換されます。
Excelの対応している表示形式を調べましたので、参考までに載せます。

対応しているの定義ですが、シリアル値をTEXT変換かけたものと再度シリアル値に変換したのち、TEXT変換した文字列が一致していることとします。

次の式でTRUEになること
=TEXT(シリアル値,表示形式)=TEXT(TEXT(シリアル値,表示形式)*1,表示形式)

※１、d/mについてですが、9月1日を変換すると　1/9　になり、これを再変換すると1月9日になり変換と再変換が一致しませんが、9月28日のように13日以降であれば正しく判定できているので一覧に載せました。
同じく、yy/mも32/9は 2032年9月と認識するので載せています。

全てのパターンを網羅したつもりですが、もしこの一覧にない日付　時間の表示形式があればお知らせください。

上記一覧を生成する、LAMBDA関数を作りましたので、公開します。
下記コードはExcelの名前の管理で _DFORMの名前で登録すると
=_DFORM()
でExcelの標準対応している表示形式一覧が得られます。

_DFORM().

=LAMBDA([user],LET(
  _Y1, {"yy"; "yyyy"},
  _Y2, VSTACK(_Y1, "ggge", "gggee"),
  _m1, {"m"; "mm"},
  _m2, {"mmm"; "mmmm"},
  _d, {"d"; "dd"},
  _ge, {"ge"; "gee"},
  _s1, {"/", "-"},
  _s2, HSTACK(_s1, "."),
  _h1, {"h"; "hh"; "[h]"},
  _ss1, {"s"; "ss"},
  _s3, {":"},
  COMBIS, LAMBDA(a, b, c, TOCOL(TOCOL(a) & TOROW(TOCOL(b) & TOROW(c)))),
  COMBIS2, LAMBDA(y, m, d, sy, sm, sd, _f1, _f2,
    LET(
      a, COMBIS(m, sm, d) & sd,
      b, IF(_f1, COMBIS(a, sy, y), COMBIS(y, sy, a)),
      c, IF(_f2, b, VSTACK(a, b)),
      z, c,
      z
    )
  ),
  COMBIS3, LAMBDA(h, m, ss, s,
    LET(
      a, COMBIS(h, s, m),
      b, a & s,
      c, COMBIS(a, s, ss),
      d, c & s,
      e, VSTACK(h & s, a, b, c, d),
      z, e,
      z
    )
  ),
  _a1, COMBIS2(_Y1, _m1, _d, _s1, _s1, "", , ),
  _a5, COMBIS(_d, _s1, _m1),
  _a1a, COMBIS(_Y1, _s1, _m1),
  _a2, COMBIS2(_ge, _m1, _d, _s2, _s2, "", , TRUE),
  _a3, COMBIS2(_Y2, _m1, _d, "年", "月", "日", , ),
  _a3a, COMBIS(_Y1, "年", _m1) & "月",
  _a4, COMBIS2(_Y1, _d, _m2, _s1, _s1, "", TRUE, ),
  _a4a, COMBIS(_m2, _s1, "yyyy"),
  _b1, COMBIS3(_h1, _m1, _ss1, _s3),
  _a, VSTACK(_a1, _a5, _a1a, _a2, _a3, _a3a, _a4, _a4a, _b1, "G/標準"),
  _y, IF(ISTEXT(user), VSTACK(TOCOL(user, 3), _a), (_a)),
  z, _y,
  (z)
))