👀概要
Microsoftが提供する生成AIアプリ・AIエージェント開発のための統合プラットフォーム「Azure AI Foundry」について、要点だけをコンパクトに整理します。
※内容は2026年9月時点の情報に基づいています。
👨👩👧👦対象者(Who)
- Azure AI Foundryという名前を聞いたことはあるが、実態がよくわかっていない方
- 生成AIアプリ・AIエージェントの開発をこれから検討している方
📌関連リンク
🗒️目次
- Azure AI Foundryとは
- サンプルコードでAI Foundryモデルを構築してみる
📝 内容
Azure AI Foundryとは
Azure AI Foundryは、生成AIアプリやAIエージェントの開発に必要な要素(モデル、ツール、プロジェクト管理、評価・監視、セキュリティなど)を1つのAzureリソースに統合したプラットフォームです。
| AI Foundryの階層 | 役割 | Terraformリソース |
|---|---|---|
| Foundryアカウント | RBAC・ネットワーク・ポリシーなどを一括管理する単一の管理単位。kind = "AIServices" のCognitive Servicesアカウントとして作成される。 |
azurerm_cognitive_account |
| プロジェクト | アカウント配下に作成する作業単位。モデルの利用・エージェントの構築・評価などはこの単位で行う。 | azurerm_cognitive_account_project |
| モデルデプロイ | モデルカタログから選んだモデル(例: gpt-4o)を、実際に呼び出し可能な状態にしたもの。 |
azurerm_cognitive_deployment |
「Azureリソースとしてのアカウントを1つ作り、その中にプロジェクトを作り、モデルをデプロイする」という3段階が、AI Foundryを利用する上での基本の型になります。次の章では、実際にこの構成をTerraformで構築してみます。
サンプルコードでAI Foundryモデルを構築してみる
以下Azure AI Foundryを試せる最小構成のTerraformコードです。
ここでは以下4つのリソースを作成しました。
-
azurerm_resource_group: リソースグループ。 -
azurerm_cognitive_account: Azure AI Foundry アカウント -
azurerm_cognitive_account_project: Azure AI Foundry プロジェクト -
azurerm_cognitive_deployment: デプロイモデル。
terraform {
required_version = ">= 1.13.3"
required_providers {
azurerm = {
source = "hashicorp/azurerm"
version = "4.72.0"
}
}
}
provider "azurerm" {
features {}
}
resource "azurerm_resource_group" "this" {
name = "rg-ai-foundry-sample"
location = "japaneast"
}
########################################
# AI Foundry
########################################
# AI Foundry アカウント (Cognitive Services / AIServices)
resource "azurerm_cognitive_account" "this" {
name = "aif-foundry-sample"
location = azurerm_resource_group.this.location
resource_group_name = azurerm_resource_group.this.name
kind = "AIServices"
sku_name = "S0"
custom_subdomain_name = "aif-foundry-sample"
project_management_enabled = true
identity {
type = "SystemAssigned"
}
}
# AI Foundry プロジェクト
resource "azurerm_cognitive_account_project" "this" {
name = "sample-project"
location = azurerm_cognitive_account.this.location
cognitive_account_id = azurerm_cognitive_account.this.id
identity {
type = "SystemAssigned"
}
}
# モデルデプロイ (gpt-4o)
resource "azurerm_cognitive_deployment" "this" {
name = "gpt-4o"
cognitive_account_id = azurerm_cognitive_account.this.id
sku {
name = "GlobalStandard"
capacity = 1
}
model {
format = "OpenAI"
name = "gpt-4o"
version = "2024-11-20"
}
}
ここでのデプロイが正常に完了すると、AzureポータルのAI Foundryページに以下のようなリソースが作成されます。
この画面は「AzureのリソースとしてのAI Foundry」としてのコンソール画面であり、「AIモデルのプロンプトチューニング」はFoundryポータルという別画面で行います。
「Foundryポータルに移動」を押下することで、AIモデルのプレイグラウンド等が確認可能なページに遷移します。
以下の「モデル」タブから確認できる gpt-4o というモデルが、Terraformリソース azurerm_cognitive_deployment に該当するモデルです。
試しにチャットすると、それらしい返答が返ってきました。
また、「モデルを呼び出す」タブを押すことでこのモデルをプログラムから呼び出せるサンプルコードが手に入ります。
まとめ
Azure AI Foundryは、生成AIアプリ・AIエージェント開発に必要な要素を1つのAzureリソースに統合したプラットフォームです。
- アカウントで一括管理
- その配下にプロジェクトを作成して作業単位を分離
- プロジェクト内でモデルをデプロイして実際に呼び出し可能にする
という3階層の構造を理解しておくことが、AI Foundryを扱う上での第一歩になります。
今回はTerraformで最小構成を作成しましたが、実際の開発ではここにAgent Serviceやモデルカタログから選んだ様々なモデル、評価・監視の仕組みなどを組み合わせていく形になります。
まずは小さな構成で触ってみて、全体構造を体感するのがおすすめです。