サクラエディタの設定を他のPCへコピーする

サクラエディタの設定を他のPCで行う場合、
通常は手作業で設定することになるかと思います。
いちいち設定するのが面倒なので、設定をコピーするバッチを書いてみました。

バッチ実行の前の準備

まず、
登録してある各言語で使用するキーワード、ルール、ヘルプなどのファイル
についてはユーザープロファイル配下のパスには配置しないよう設定を変更しておきます。
コピー元とコピー先のPCでログオンしているユーザーが異なっていた場合、都度修正を行うのを避けるためです。
※コピー元とコピー先のPCでログオンしているユーザーが同じであれば変更不要です。

そして、下記ファイルを1つのフォルダーにまとめておきます。

• 登録してある各言語で使用するキーワード、ルール、ヘルプなどのファイル
• プラグインのフォルダー(%appdata%\sakura\のpluginsフォルダー)
• sakura.iniファイル(%appdata%\sakuraにあります)
• サクラエディタのインストーラーをsakura_install.exeの名前にして配置

sakura.iniファイルを編集します。
[Grep]の個所までは下記内容に書き換えます。
元のファイルには開いたファイルの履歴などが残っているので、それを消すために行います。

sakura.ini

[MRU]
_ExceptMRU_Counts=0
_MRUFOLDER_Counts=0
_MRU_Counts=0

[Keys]
_REPLACEKEY_Counts=0
_SEARCHKEY_Counts=0

[Grep]
GREPFILE[00]=*.*
_GREPEXCLUDEFILE_Counts=0
_GREPEXCLUDEFOLDER_Counts=0
_GREPFILE_Counts=1
_GREPFOLDER_Counts=0

また、未インストールPCにてコマンドプロンプトなどで次コマンドを実行し、サクラエディタを仮でインストールを行います。
このとき、現行でインストールされているのと同じ設定にてインストールを実施します。
このコマンドでカレントディレクトリに作成されたsakura.infを上記フォルダーに配置します。
※sakura.infを絶対パスで記載すればフォルダー指定が可能です。
このsakura.infはインストール時の設定内容が書かれたファイルで、
この後実行するバッチではサイレントインストール時にこのファイルを読み込ませて設定を行っています。

仮インストール

akura_install.exe /saveinf="sakura.inf"

バッチ

これで準備が完了しましたので、
バッチの実行となります。
下記バッチを各種ファイルをまとめたフォルダーに配置し、
そのフォルダーごとインストール先PCに持って行ってバッチを実行します。
なお、このバッチはサクラエディタがインストールされていたら一度アンインストールを行い、
再度インストールしなおしをするため、タスクバーとかに設定されていた場合は消えてしまい、再度設定が必要になります。

設定コピー

@echo off

rem 管理者権限強制実行
whoami /priv | find "SeDebugPrivilege" > nul
if %errorlevel% neq 0 (
  @powershell start-process %~0 -verb runas
  exit
)

rem バッチのあるフォルダーへ移動
cd /d %~dp0

rem インストールされていた場合はいったんアンインストール
if exist "C:\Program Files (x86)\sakura\unins000.exe" (
  "C:\Program Files (x86)\sakura\unins000.exe" /SILENT
)

echo.
echo サクラエディタインストール
rem インストールファイルはsakura_install.exe固定
start /wait /b sakura_install.exe /SP- /SILENT /norestart /LOADINF="sakura.inf"
rem 設定ファイルコピー
rem 新規インストールの場合sakuraフォルダー作成
if not exist %appdata%\sakura (
  mkdir %appdata%\sakura
)
copy /y sakura.ini %appdata%\sakura
mkdir %appdata%\sakura\plugins
xcopy plugins %appdata%\sakura\plugins /e /y /h
rem デフォルトにコピーすることで新たに作成したユーザーにも適用されるようにする 
mkdir C:\Users\Default\AppData\Roaming\sakura
copy /y sakura.ini C:\Users\Default\AppData\Roaming\sakura
mkdir C:\Users\Default\AppData\Roaming\sakura\plugins
xcopy plugins C:\Users\Default\AppData\Roaming\sakura\plugins /e /y /h

rem キーワード、ルール、ヘルプなどのファイルの数だけ記載する
rem 例：copy /y tmp.kwd c:\tmp
copy /y キーワード、ルール、ヘルプなどのファイル 配置するパス

おわりに

もしもサクラエディタの設定を変更した場合はsakura.iniを変更するだけでOKとなります。