Spresense用のNeoPixelボードですが
ハードウェア的には動いていましたが、どうしても使い慣れたadafruit / Adafruit_NeoPixelを使いたいと思っていました。
色々調べていたら、 KotaMeiwa/nepils というライブラリを見つけましたので情報を共有します。
2023-03-31に公開されたばかりみたいです。
どうりで、NeoPixelボードの動作テストをしてる時にたどり着けなかった訳です。
概要部分を ChatGPTに訳してもらいました
Spresense用のNeoPixelライブラリは、adafruit/Adafruit_NeoPixelの補足ライブラリです。
（私は思うに）adafruit/Adafruit_NeoPixelは、Arduinoプラットフォーム上でNeoPixel LEDストリップを制御するための最も有名なライブラリです。しかし、2023年3月現在、それはソニーのSpresenseプラットフォームでは動作しません。このライブラリを使えば、ソニーのSpresenseでLEDストリップを楽しむことができます！
このライブラリの主要なクラスであるAdafruit_NeoPixel_Spresenseは、adafruit/Adafruit_NeoPixelのAdafruit_NeoPixelクラスを継承しているため、Adafruit_NeoPixel_SpresenseにはAdafruit_NeoPixelと同じメソッドがあります。
Arduino IDEにライブラリをインストールします
GitHubから.zipをダウンロードして、Arduino IDEに zip形式でライブラリに追加してください。Adafruit_NeoPixelのサンプルの strandtest を動かしてみました。
変更箇所ですが
#include <Adafruit_NeoPixel.h> を
#include <Adafruit_NeoPixel_Spresense.h> に
Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800); を
Adafruit_NeoPixel_Spresense strip(LED_COUNT, LED_PIN); に変更します。
それとLEDに接続しているPIN番号とLEDの数を合わせます。
// Which pin on the Arduino is connected to the NeoPixels?
// On a Trinket or Gemma we suggest changing this to 1:
// #define LED_PIN 6
#define LED_PIN 18
// How many NeoPixels are attached to the Arduino?
// #define LED_COUNT 60
#define LED_COUNT 30
変更した後のソースコードはこのようになります。
// A basic everyday NeoPixel strip test program.
// NEOPIXEL BEST PRACTICES for most reliable operation:
// - Add 1000 uF CAPACITOR between NeoPixel strip's + and - connections.
// - MINIMIZE WIRING LENGTH between microcontroller board and first pixel.
// - NeoPixel strip's DATA-IN should pass through a 300-500 OHM RESISTOR.
// - AVOID connecting NeoPixels on a LIVE CIRCUIT. If you must, ALWAYS
// connect GROUND (-) first, then +, then data.
// - When using a 3.3V microcontroller with a 5V-powered NeoPixel strip,
// a LOGIC-LEVEL CONVERTER on the data line is STRONGLY RECOMMENDED.
// (Skipping these may work OK on your workbench but can fail in the field)
// #include <Adafruit_NeoPixel.h>
#include <Adafruit_NeoPixel_Spresense.h>
#ifdef __AVR__
#include <avr/power.h> // Required for 16 MHz Adafruit Trinket
#endif
// Which pin on the Arduino is connected to the NeoPixels?
// On a Trinket or Gemma we suggest changing this to 1:
// #define LED_PIN 6
#define LED_PIN 18
// How many NeoPixels are attached to the Arduino?
// #define LED_COUNT 60
#define LED_COUNT 30
// Declare our NeoPixel strip object:
// Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);
Adafruit_NeoPixel_Spresense strip(LED_COUNT, LED_PIN);
// Argument 1 = Number of pixels in NeoPixel strip
// Argument 2 = Arduino pin number (most are valid)
// Argument 3 = Pixel type flags, add together as needed:
// NEO_KHZ800 800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
// NEO_KHZ400 400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
// NEO_GRB Pixels are wired for GRB bitstream (most NeoPixel products)
// NEO_RGB Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
// NEO_RGBW Pixels are wired for RGBW bitstream (NeoPixel RGBW products)
// setup() function -- runs once at startup --------------------------------
void setup() {
// These lines are specifically to support the Adafruit Trinket 5V 16 MHz.
// Any other board, you can remove this part (but no harm leaving it):
#if defined(__AVR_ATtiny85__) && (F_CPU == 16000000)
clock_prescale_set(clock_div_1);
#endif
// END of Trinket-specific code.
strip.begin(); // INITIALIZE NeoPixel strip object (REQUIRED)
strip.show(); // Turn OFF all pixels ASAP
strip.setBrightness(50); // Set BRIGHTNESS to about 1/5 (max = 255)
}
// loop() function -- runs repeatedly as long as board is on ---------------
void loop() {
// Fill along the length of the strip in various colors...
colorWipe(strip.Color(255, 0, 0), 50); // Red
colorWipe(strip.Color( 0, 255, 0), 50); // Green
colorWipe(strip.Color( 0, 0, 255), 50); // Blue
// Do a theater marquee effect in various colors...
theaterChase(strip.Color(127, 127, 127), 50); // White, half brightness
theaterChase(strip.Color(127, 0, 0), 50); // Red, half brightness
theaterChase(strip.Color( 0, 0, 127), 50); // Blue, half brightness
rainbow(10); // Flowing rainbow cycle along the whole strip
theaterChaseRainbow(50); // Rainbow-enhanced theaterChase variant
}
// Some functions of our own for creating animated effects -----------------
// Fill strip pixels one after another with a color. Strip is NOT cleared
// first; anything there will be covered pixel by pixel. Pass in color
// (as a single 'packed' 32-bit value, which you can get by calling
// strip.Color(red, green, blue) as shown in the loop() function above),
// and a delay time (in milliseconds) between pixels.
void colorWipe(uint32_t color, int wait) {
for(int i=0; i<strip.numPixels(); i++) { // For each pixel in strip...
strip.setPixelColor(i, color); // Set pixel's color (in RAM)
strip.show(); // Update strip to match
delay(wait); // Pause for a moment
}
}
// Theater-marquee-style chasing lights. Pass in a color (32-bit value,
// a la strip.Color(r,g,b) as mentioned above), and a delay time (in ms)
// between frames.
void theaterChase(uint32_t color, int wait) {
for(int a=0; a<10; a++) { // Repeat 10 times...
for(int b=0; b<3; b++) { // 'b' counts from 0 to 2...
strip.clear(); // Set all pixels in RAM to 0 (off)
// 'c' counts up from 'b' to end of strip in steps of 3...
for(int c=b; c<strip.numPixels(); c += 3) {
strip.setPixelColor(c, color); // Set pixel 'c' to value 'color'
}
strip.show(); // Update strip with new contents
delay(wait); // Pause for a moment
}
}
}
// Rainbow cycle along whole strip. Pass delay time (in ms) between frames.
void rainbow(int wait) {
// Hue of first pixel runs 5 complete loops through the color wheel.
// Color wheel has a range of 65536 but it's OK if we roll over, so
// just count from 0 to 5*65536. Adding 256 to firstPixelHue each time
// means we'll make 5*65536/256 = 1280 passes through this loop:
for(long firstPixelHue = 0; firstPixelHue < 5*65536; firstPixelHue += 256) {
// strip.rainbow() can take a single argument (first pixel hue) or
// optionally a few extras: number of rainbow repetitions (default 1),
// saturation and value (brightness) (both 0-255, similar to the
// ColorHSV() function, default 255), and a true/false flag for whether
// to apply gamma correction to provide 'truer' colors (default true).
strip.rainbow(firstPixelHue);
// Above line is equivalent to:
// strip.rainbow(firstPixelHue, 1, 255, 255, true);
strip.show(); // Update strip with new contents
delay(wait); // Pause for a moment
}
}
// Rainbow-enhanced theater marquee. Pass delay time (in ms) between frames.
void theaterChaseRainbow(int wait) {
int firstPixelHue = 0; // First pixel starts at red (hue 0)
for(int a=0; a<30; a++) { // Repeat 30 times...
for(int b=0; b<3; b++) { // 'b' counts from 0 to 2...
strip.clear(); // Set all pixels in RAM to 0 (off)
// 'c' counts up from 'b' to end of strip in increments of 3...
for(int c=b; c<strip.numPixels(); c += 3) {
// hue of pixel 'c' is offset by an amount to make one full
// revolution of the color wheel (range 65536) along the length
// of the strip (strip.numPixels() steps):
int hue = firstPixelHue + c * 65536L / strip.numPixels();
uint32_t color = strip.gamma32(strip.ColorHSV(hue)); // hue -> RGB
strip.setPixelColor(c, color); // Set pixel 'c' to value 'color'
}
strip.show(); // Update strip with new contents
delay(wait); // Pause for a moment
firstPixelHue += 65536 / 90; // One cycle of color wheel over 90 frames
}
}
}
Arduino IDEでコンパイルしたら以下のなエラーとなりました。
Arduino：1.8.19 (Windows 10), ボード："Spresense, MainCore, 768 KB (Default), Disabled, 115200"
D:\users\Dropbox\Git\Arduino\Spresense_NeoPixel_strandtest\Spresense_NeoPixel_strandtest.ino: In function 'void colorWipe(uint32_t, int)':
Spresense_NeoPixel_strandtest:85:33: error: no matching function for call to 'Adafruit_NeoPixel_Spresense::setPixelColor(int&, uint32_t&)'
85 | strip.setPixelColor(i, color); // Set pixel's color (in RAM)
| ^
In file included from D:\users\Dropbox\Git\Arduino\Spresense_NeoPixel_strandtest\Spresense_NeoPixel_strandtest.ino:14:
D:\users\Dropbox\Git\Arduino\libraries\nepils-main/Adafruit_NeoPixel_Spresense.h:32:7: note: candidate: 'void Adafruit_NeoPixel_Spresense::setPixelColor(uint16_t, uint8_t, uint8_t, uint8_t, uint8_t)'
32 | void setPixelColor(uint16_t n, uint8_t r, uint8_t g, uint8_t b, uint8_t w){}
| ^~~~~~~~~~~~~
D:\users\Dropbox\Git\Arduino\libraries\nepils-main/Adafruit_NeoPixel_Spresense.h:32:7: note: candidate expects 5 arguments, 2 provided
D:\users\Dropbox\Git\Arduino\Spresense_NeoPixel_strandtest\Spresense_NeoPixel_strandtest.ino: In function 'void theaterChase(uint32_t, int)':
Spresense_NeoPixel_strandtest:100:37: error: no matching function for call to 'Adafruit_NeoPixel_Spresense::setPixelColor(int&, uint32_t&)'
100 | strip.setPixelColor(c, color); // Set pixel 'c' to value 'color'
| ^
In file included from D:\users\Dropbox\Git\Arduino\Spresense_NeoPixel_strandtest\Spresense_NeoPixel_strandtest.ino:14:
D:\users\Dropbox\Git\Arduino\libraries\nepils-main/Adafruit_NeoPixel_Spresense.h:32:7: note: candidate: 'void Adafruit_NeoPixel_Spresense::setPixelColor(uint16_t, uint8_t, uint8_t, uint8_t, uint8_t)'
32 | void setPixelColor(uint16_t n, uint8_t r, uint8_t g, uint8_t b, uint8_t w){}
| ^~~~~~~~~~~~~
D:\users\Dropbox\Git\Arduino\libraries\nepils-main/Adafruit_NeoPixel_Spresense.h:32:7: note: candidate expects 5 arguments, 2 provided
D:\users\Dropbox\Git\Arduino\Spresense_NeoPixel_strandtest\Spresense_NeoPixel_strandtest.ino: In function 'void theaterChaseRainbow(int)':
Spresense_NeoPixel_strandtest:141:37: error: no matching function for call to 'Adafruit_NeoPixel_Spresense::setPixelColor(int&, uint32_t&)'
141 | strip.setPixelColor(c, color); // Set pixel 'c' to value 'color'
| ^
In file included from D:\users\Dropbox\Git\Arduino\Spresense_NeoPixel_strandtest\Spresense_NeoPixel_strandtest.ino:14:
D:\users\Dropbox\Git\Arduino\libraries\nepils-main/Adafruit_NeoPixel_Spresense.h:32:7: note: candidate: 'void Adafruit_NeoPixel_Spresense::setPixelColor(uint16_t, uint8_t, uint8_t, uint8_t, uint8_t)'
32 | void setPixelColor(uint16_t n, uint8_t r, uint8_t g, uint8_t b, uint8_t w){}
| ^~~~~~~~~~~~~
D:\users\Dropbox\Git\Arduino\libraries\nepils-main/Adafruit_NeoPixel_Spresense.h:32:7: note: candidate expects 5 arguments, 2 provided
exit status 1
no matching function for call to 'Adafruit_NeoPixel_Spresense::setPixelColor(int&, uint32_t&)'
「ファイル」メニューの「環境設定」から
「より詳細な情報を表示する：コンパイル」を有効にすると
より詳しい情報が表示されます。
このライブラリのGitHubのページに以下の記述がありました。
the following API is disabled
void setPin(int16_t p)
void setPixelColor(uint16_t n, uint8_t r, uint8_t g, uint8_t b, uint8_t w)
void updateLength(uint16_t n)
void updateType(neoPixelType t)
setPixelColor()関数が無効化されているみたいです。
やり方が間違っているかもしれませんが、先ほどインストールしたライブラリの
Adafruit_NeoPixel_Spresense.h の 32行目の
void setPixelColor(uint16_t n, uint8_t r, uint8_t g, uint8_t b, uint8_t w){}
コメントアウトしてコンパイルを通しました。
protected: //diabled super class's method
void setPin(int16_t p){}
// void setPixelColor(uint16_t n, uint8_t r, uint8_t g, uint8_t b, uint8_t w){}
void updateLength(uint16_t n){}
void updateType(neoPixelType t){}
実際に動かしいてる動画です。
ただしこの動画は2系統同時に動かしているので、先ほどのプログラムを若干変更しています。
SpresenseでNeoPixelを動かす時 RTC と同時に動かすと表示の乱れが発生するとの情報を頂いていますので
これに関しては改めて検証します。
この記事は、KotaMeiwa様によって開発された SpresenseNeoPixel ライブラリ を使用しています。
この素晴らしいライブラリを開発公開してくれた KotaMeiwa様 に感謝します。
SpresenseNeoPixelはこちらで公開されています