Delphi Starter Edition でメモ帳クローンを作る (後編)

// 続き

これは Delphi Advent Calendar 2017 8 日目の記事です。前編はこちら。

コードを記述するよ！

プログラムの構造

実際にコードを記述する前に、ソースコードのファイル構成を説明しておきます。Pascal の文法で記述できるファイルは基本的には 2 つあります。プロジェクトファイルである .dpr と ユニットファイル である .pas です。

「あれ？」と思われた方もいらっしゃるでしょう。最初にプロジェクトを保存した時のファイルは .dproj でしたよね？.dpr は古い Delphi ではプロジェクトファイルも兼ねていましたが、実際の所はプログラムのファイルです。.dproj は比較的新しい Delphi のプロジェクトファイルで、コンパイルオプション等を保持している XML ファイルです。C 言語でいう所の makefile に近いかもしれません。

実際の所 .dproj を削除しても .dpr を開けば .dproj は自動生成されます。但し、バージョン情報など、コンパイル用のオプションはすべて消えてしまいます。

では .dpr の中身を確認してみましょう。オブジェクトインスペクタで notepad_clone.exe となっている部分を右クリックして [ソースの表示 (V)] を選んでみます。

エディタのタブが一つ増え、notepad_clone.dpr が開かれました。これがプログラムファイルです。

プログラムファイルは

program プログラム名;

uses
  // ユニットの依存関係のリスト

begin

end.

の様式になっています。begin と end の中にコードを記述します。

原始的な Pascal はソースコードの分割機能がなく、「Pascal はソースコードを分割できない」と揶揄する人もいますが、少なくとも Object Pascal においては正しくない発言です。Object Pascal では .dpr にすべてのコードを記述する事もできますが、基本的には機能毎にユニットに分割してプログラムを構成します。

ここで一旦〔Shift〕+〔Ctrl〕+〔S〕を押し、プロジェクトを保存してください。[ファイル | すべて保存] でも構いません。〔Ctrl〕+〔S〕での保存は現在のタブを保存する事を意味し、〔Shift〕+〔Ctrl〕+〔S〕はプロジェクトファイル中の編集したすべてのタブを保存する事を意味します。

[ファイル | 新規作成 | その他] を選びます。

[Delphi プロジェクト] でコンソールアプリケーションを選び、[OK] ボタンを押します。

すると以下のようなコードが表示されると思います。

プロジェクトマネージャで確認してもユニットファイルはありません。コンソールアプリケーションの場合、初期状態では単一のファイルでプログラムが構成されている事がわかります。

さて、notepad_clone に戻りましょう。notepad_clone のプロジェクトを再び開くには、[ファイル | プロジェクトを開く...] または、[開きなおす] から開きます。コンソールアプリケーションを保存するか尋ねられますが、[いいえ] を押して破棄してください。

改めてユニットファイルを確認してみましょう。frmuMain のタブを選択し、

フォームデザイナが表示されていれば〔F12〕を押してコードエディタに切り替えます。

ユニットファイルは

unit ユニット名;

interface

uses
  // ユニットの依存関係のリスト

// クラス、手続き、関数の宣言部


implementation

uses
  // ユニットの依存関係のリスト

// クラスのメソッド、手続き、関数の実装部


initialization

// ユニット初期化コード

finalization

// ユニット終了コード

end.

の様式になっています。省略できるセクションがあるため、違うように見えるかもしれません。

フォームのあるプログラム...つまり、今作成している VCL フォームアプリケーション では、フォームはユニットとして管理されます。ユニットは .pas で、フォームの定義は .dfm (フォームファイル) に保存されます。フォームファイルは独自のテキストファイルで、フォームデザイナの状態で〔Alt〕+〔F12〕を押すか、右クリックして [エディタで表示] を選ぶとエディタで編集できます。

下手にいじるとフォームが壊れてしまうので、慣れてくるまでは手動で編集しない方がいいと思います。この状態でさらに〔Alt〕+〔F12〕を押すか、右クリックして [フォームとして表示] を選ぶとフォームデザイナに戻ります。

今度は [プロジェクト | オプション] を開き、[フォーム] を確認してみましょう。

このプロジェクト (プログラム) にはフォームが一つだけあり、これがメインフォームとして自動生成されている事が分かります。複数のフォームがあった場合、最初にすべてのフォームを自動生成してもいいのですが、メモリを消費してしまいます。最初からフォームを用意しておく必要がない場合には [使用可能フォーム] の方に移動しておき、使う時だけインスタンスを生成する方法を採ります。

メインフォームの生成ロジックは .dpr にありましたよね。

notepad_clone.dpr

program notepad_clone;

uses
  Vcl.Forms,
  frmuMain in 'frmuMain.pas' {Form1}; // frmuMain をこのプログラムで使用する

{$R *.res}

begin
  Application.Initialize;                // VCL フォームアプリケーションを初期化する
  Application.MainFormOnTaskbar := True; // オマジナイ
  Application.CreateForm(TForm1, Form1); // TForm 型の Form1 を生成する
  Application.Run;                       // VCL フォームアプリケーションを実行する
end.

• uses 句では使用するユニットが列挙されています。
• Form1 という TForm1 型の変数は frmuMain.pas 内で定義されています。

frmuMain.pas

unit frmuMain;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, System.Actions,
  Vcl.ActnList, Vcl.Menus;

type
  TForm1 = class(TForm)
    (中略)
  end;

var
  Form1: TForm1; // <- コレ

implementation

{$R *.dfm}

end.

• var は変数の宣言ブロックです。interface セクションにあるので、この変数は uses したプログラムまたはユニットから見る事ができます。implementation セクションに var ブロックを置くとここに置かれた変数は implementation セクション内のクラスのメソッド、手続き、関数からしか見えません。

VCL フォームアプリケーションでは、メインフォームが閉じられるとアプリケーションも終了するようになっています。なんとなく Delphi プロジェクトの構造が解ってきたでしょうか？

• プログラムとユニット（Delphi）(DocWiki)

コードを記述

ではコードを記述してみます。メモ帳の [ファイル (F)] のメニューで一番簡単な処理は [メモ帳の終了(X)] でしょう。アクションリストのコンポーネントエディタにある acExit をダブルクリックするか、

オブジェクトインスペクタで acExit を選択し、[イベント] タブをクリック、

OnExecute イベントの値部分をダブルクリックします。

そうすると、ソースコードにイベントハンドラ用のコードが追加されます。

acExit の onExcute はメニューアイテムが選択された時に実行されるイベントです。このイベントを処理するメソッドがイベントハンドラ acExitExecute() です。イベントハンドラの名前は自動で付けられますが、オブジェクトインスペクタから名前を変更する事も出来ます。

このイベントハンドラに何を書けばアプリケーションを終了させられるでしょうか？このフォームはメインフォームですから...そう、メインフォームを閉じればアプリケーションを終了させる事ができます。

TForm1 の自身を示す Self を用いて、Self.Close; と記述するか、

procedure TForm1.acExitExecute(Sender: TObject);
begin
  Self.Close;
end;

或いは単に Close; と書けばフォームは閉じます。

procedure TForm1.acExitExecute(Sender: TObject);
begin
  Close;
end;

Close メソッドは TForm1 が持つフォームを閉じるメソッドです。Delphi では引数のないメソッドの括弧を省略する事ができます。もちろん、Close(); と書いても構いません。

〔F9〕でコンパイルして実行してみましょう。今度は [メモ帳の終了(X)] がグレーアウトしていませんね。[メモ帳の終了(X)] を選択すると、メモ帳クローンが終了します。

〔Alt〕,〔F〕,〔X〕と順に押しても [メモ帳の終了(X)] が実行される事を確認してください。

• イベント（Delphi）(DocWiki)

コードエディタのショートカットも覚えておくといいでしょう。コーディングの効率が上がります。

• デフォルトのキーボード ショートカット (DocWiki)

[開く(O)...] の実装

[開く(O)...] を実装してみます。実際にメモ帳で [開く(O)...] をやってみるとファイルオープンダイアログが表示され、ここでファイルを選ぶとそれが開かれるという処理です。

ところが...です。メモ帳のファイルオープンダイアログは特殊なもので、下に [文字コード(E)] というコンボボックスがあります。これと全く同じダイアログはありませんので TOpenTextFileDialog を使うことにします。TOpenTextFileDialog はツールパレットの [Dialogs] タブの中にあります。

コンポーネント名は判っていてもどのタブにあるのか分らない場合には、ツールパレット上部の虫眼鏡アイコンのある検索ボックスに数文字入力するとコンポーネントを絞り込む事ができます。

フォームデザイナに OpenTextFileDialog1 が貼り付けられました。

この OpenTextFileDialog1 をダブルクリックすると実際のダイアログがプレビューできます。

メモ帳のダイアログとはちょっと異なりますが、なんとかなりそうです。

フィルタ

[ファイルの種類] をドロップダウンしても空白のままですが、実際のメモ帳には テキスト文章(*.txt) と すべてのファイル (*.*) があります。

これを指定するにはオブジェクトインスペクタで OpenTextFileDialog1 の Filter プロパティを設定します。

Filter の値部分をダブルクリックするか、右側の […] ボタンを押すと、Filter プロパティのプロパティエディタが起動します。

左の列にフィルタ名を、右の列にフィルタを入力します。具体的には以下のように入力します。

フィルタ名	フィルタ
テキスト文章 (*.txt)	*.txt
すべてのファイル (*.*)	*.*

[OK] ボタンを押して確定し、OpenTextFileDialog1 をダブルクリックしてダイアログをプレビューするとフィルターが指定されています。

選択したフィルタによって FilterIndex プロパティの値が変化します。値はフィルタの順番です (0 オリジン)。

エンコーディング (文字コード)

エンコーディングはイロイロと入っていますが...

オリジナルのメモ帳はこんな感じです。

メモ帳と同じにするには Encodings プロパティを編集します。

Encodings の値部分をダブルクリックするか、右側の […] ボタンを押すと、Encodings プロパティのプロパティエディタが起動します。

これを以下のように書き換えます。

ANSI
Unicode
Unicode big endian
UTF-8

[OK] ボタンを押して確定し、OpenTextFileDialog1 をダブルクリックしてダイアログをプレビューするとエンコーディングが指定されています。

選択したエンコーディングによって EncodingIndex プロパティの値が変化します。値はエンコーディングの順番です (0 オリジン)。

コード

コードは acOpen の onExecute イベントのイベントハンドラに書きます。

ここに書くべき処理は以下の通りです。

1. OpenTextFileDialog1 を開く
2. ファイルが選択されて [OK] ボタンが押されたら (有効なファイル名が渡されたら)
3. ファイルを指定されたエンコーディングで Memo1 に読み込み

コーディングにフィルターは何も影響しませんが、エンコーディングは影響します。エンコーディングの ANSI とはデフォルトの ANISI コードページ (ACP) の事です。日本語版 Windows の場合、デフォルトの ANSI コードページは 932 (SHIFT_JIS) となります。

OpenTextFileDialog1 を開いて [OK] ボタンが押されて有効なファイル名が渡されたかどうかを判定するには以下のようなコードになります。

frmuMain.pas

procedure TForm1.acOpenExecute(Sender: TObject);
begin
  if OpenTextFileDialog1.Execute then
    begin

    end;
end;

OpenTextFileDialog1 でダイアログを開くメソッドは Execute() で、[OK] ボタンが押されて有効なファイル名が渡されると戻り値として True を返します。ファイル名は FileName プロパティに格納されます。

Delphi の構造化文に関しては以下のドキュメントを参照してください。

• 宣言と文（Delphi）(DocWiki)
• 改めて Delphi の構造化文 (VCL によるテクニック＆アルゴリズム)

ファイルの読み込みですが、TMemo の Lines プロパティ (TString 型) には LoadFromFile() というファイルを読み込むメソッドがあります。

procedure LoadFromFile(const FileName: string); overload; virtual;
procedure LoadFromFile(const FileName: string; Encoding: TEncoding); overload; virtual;

• System.Classes.TStrings.LoadFromFile (DocWiki)

二番目の構文を使うとエンコーディングを指定して読み込めます。具体的には以下のようなコードになります。

frmuMain.pas

procedure TForm1.acOpenExecute(Sender: TObject);
var
  Enc: TEncoding;
begin
  if OpenTextFileDialog1.Execute then
    begin
      // EncodingIndex によりエンコーディングを指定
      case OpenTextFileDialog1.EncodingIndex of
        1: Enc := TEncoding.Unicode;
        2: Enc := TEncoding.BigEndianUnicode;
        3: Enc := TEncoding.UTF8;
      else
        Enc := TEncoding.Default; // 0: ANSI
      end;
      // エンコーディングを指定して読み込み
      Memo1.Lines.LoadFromFile(OpenTextFileDialog1.FileName, Enc);
    end;
end;

ファイル保存の事を考えると、FileName と EncodingIndex はどこかに保存しておくと便利そうです。クラスの private なフィールドとして定義しておきましょう。

frmuMain.pas

(前略)
    N3: TMenuItem;
    OpenTextFileDialog1: TOpenTextFileDialog;
    procedure acExitExecute(Sender: TObject);
    procedure acOpenExecute(Sender: TObject);
  private
    { Private 宣言 }
    FFileName: String;       // 追加
    FEncodingIndex: Integer; // 追加
  public
    { Public 宣言 }
  end;
(後略)

OpenTextFileDialog1 で正しくファイルを選択された時のみ値を保存しておくことにします。

frmuMain.pas

procedure TForm1.acOpenExecute(Sender: TObject);
var
  Enc: TEncoding;
begin
  if OpenTextFileDialog1.Execute then
    begin
      // 値を保存
      FFileName := OpenTextFileDialog1.FileName;
      FEncodingIndex := OpenTextFileDialog1.EncodingIndex;
      // EncodingIndex によりエンコーディングを指定
      case FEncodingIndex of                    // <- 変更
        1: Enc := TEncoding.Unicode;
        2: Enc := TEncoding.BigEndianUnicode;
        3: Enc := TEncoding.UTF8;
      else
        Enc := TEncoding.Default; // 0: ANSI
      end;
      // エンコーディングを指定して読み込み
      Memo1.Lines.LoadFromFile(FFileName, Enc); // <- 変更
    end;
end;

このままでは初期値が不定なので、フィールド (FFileName / FEncodingIndex) の値を初期値で初期化しておきます。初期化はフォームの作成時のイベント (onCreate) で行う事にしますので、オブジェクトインスペクタで Form1 を選び、[イベント] タブで onCreate の値の部分をダブルクリックしてイベントハンドラを作成します。

FormCreate イベントハンドラでフィールドの値を初期化します。

frmuMain.pas

procedure TForm1.FormCreate(Sender: TObject);
begin
  FFileName := '';
  FEncodingIndex := 0;
end;

オリジナルのメモ帳は "ファイル名 - メモ帳" という形式でキャプションバーにファイルを表示するようになっており、ファイル名が決定していない場合には "無題" と表示されます。このキャプションを更新するメソッドを実装しましょう。

メソッドは値を返す必要がないため手続き (Procedure)で実装します。値を返す必要がある場合は関数 (Function)で実装します。

引数もありませんので、宣言は以下のようになります。

frmuMain.pas

(前略)
  private
    { Private 宣言 }
    FFileName: String;       
    FEncodingIndex: Integer; 
    procedure UpdateCaption; // 追加
  public
    { Public 宣言 }
  end;
(後略)

Delphi (Pascal) では戻り値の有無で手続きと関数が明示的に区別されています。文脈上、手続きと関数を区別しないでいい場所ではまとめてルーチンと呼ばれます。クラスのメンバーなルーチンはメソッドと呼ばれますが、面倒くさいので全部ひっくるめてメソッドと呼ぶ事が多いです。

• 手続きと関数（Delphi）(DocWiki)
• メソッド（Delphi）(DocWiki)

実装部は以下のように記述します。implementation セクションにならどこに書いても構いませんが、最後 (end. の前) に追加してみます。

frmuMain.pas

(前略)
implementation

(中略)

procedure TForm1.FormCreate(Sender: TObject);
begin
  // 値を初期化
  FFileName := '';
  FEncodingIndex := 0;
end;

procedure TForm1.UpdateCaption;
begin

end;

end.

1. ファイル名が空だったら "無題"
2. ファイル名が空でなかったらファイル名部分のみを取得 (ディレクトリ部分は無視)。
3. "ファイル名 - メモ帳クローン" というキャプションにする。

このロジックのために必要なコードの変更点は以下の通りです。

frmuMain.pas

unit frmuMain;

interface

uses
  ..., System.IOUtils; // 末尾に System.IOUtils を追加

(中略)

implementation

(中略)

procedure TForm1.acOpenExecute(Sender: TObject);
var
  Enc: TEncoding;
begin
  if OpenTextFileDialog1.Execute then
    begin
      // 値を保存
      FFileName := OpenTextFileDialog1.FileName;
      FEncodingIndex := OpenTextFileDialog1.EncodingIndex;
      // キャプションを変更
      UpdateCaption; // <-------------------------------------------------------追加
      // EncodingIndex によりエンコーディングを指定
      case FEncodingIndex of
        1: Enc := TEncoding.Unicode;
        2: Enc := TEncoding.BigEndianUnicode;
        3: Enc := TEncoding.UTF8;
      else
        Enc := TEncoding.Default;
      end;
      // エンコーディングを指定して読み込み
      Memo1.Lines.LoadFromFile(FFileName, Enc);
    end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
 // 値を初期化
  FFileName := '';
  FEncodingIndex := 0;
  Memo1.Lines.Clear; // Memo1 の中身を消去する。
  // キャプションを変更
  UpdateCaption; // <-------------------------------------------------------追加
end;

procedure TForm1.UpdateCaption;
var
  Dmy: String;
begin
  if FFileName = '' then
    Dmy := '無題'
  else
    Dmy := TPath.GetFileName(FFileName);
  Self.Caption := Dmy + ' - メモ帳クローン';
end;

end.

TPath.GetFileName はフルパスファイル名からファイル名だけを取り出すメソッドです。TPath は構造体 (record)ですが、パス名を操作するメソッドを備えています。TPath は System.IOUtils 名前空間で定義されており、利用するには uses に名前空間を追加する必要があります。

• Delphi での名前空間の使い方 (DocWiki)
• System 名前空間 (DocWiki)
• Vcl 名前空間 (DocWiki)

TPath にどんなメンバーがあるのかは、TPath. と入力してそのままちょっと待ってみましょう。コード補完機能により、プロパティ / メソッド / イベントの一覧が表示されます。 その後、項目を選択して Enter キーを押すかマウスでクリックするとコードに追加できます。一覧を強制的に表示するには 〔Ctrl〕+〔Space〕を押します。

また、TPath という単語にカーソルを置いて〔F1〕キーを押すとヘルプを開く事ができます。ここで [メソッド] をクリックすると...

TPath が持つメソッドの一覧が表示されます。メソッド名をクリックするとそのメソッドの詳細が表示されます。

さて、話はそれましたが〔F9〕を押してメモ帳クローンを実行し、[ファイル | 開く(O)...] で任意のファイルを開いてみましょう。

マウスホイールでスクロールできない？それはスクロールバーを表示していないからです。Memo1 の ScrollBars プロパティを ssBoth に設定しましょう。

今度はマウスホイールでスクロールできるはずです。

〔Alt〕,〔F〕,〔O〕と順に押しても [開く(O)...] が実行される事を確認してください。〔Ctrl〕+〔O〕でも実行されます。

[上書き保存(S)] の実装

上書き保存の実装は簡単です。

コード

TMemo の Lines プロパティ (TString 型) には SaveToFile() というファイルを保存するメソッドがあります。

procedure SaveToFile(const FileName: string); overload; virtual;
procedure SaveToFile(const FileName: string; Encoding: TEncoding); overload; virtual;

• System.Classes.TStrings.SaveToFile (DocWiki)

二番目の構文を使うとエンコーディングを指定して保存できますので、acSave アクションの onExecute イベントに対応する acSaveExecute イベントハンドラに処理を記述します。

frmuMain.pas

procedure TForm1.acSaveExecute(Sender: TObject);
var
  Enc: TEncoding;
begin
  // EncodingIndex によりエンコーディングを指定
  case FEncodingIndex of
    1: Enc := TEncoding.Unicode;
    2: Enc := TEncoding.BigEndianUnicode;
    3: Enc := TEncoding.UTF8;
  else
    Enc := TEncoding.Default;
  end;
  // エンコーディングを指定して保存
  Memo1.Lines.SaveToFile(FFileName, Enc);
end;

しかしながらこのロジックでは新規作成時であっても...つまりファイル名が未定 (空) であってもファイルを保存しようとしてしまいます。これではエラーになってしまうでしょう。よって、FFileName が空かどうかを判定し、空なら [名前を付けて保存(A)...] のロジックに飛ばすようにしましょう。[名前を付けて保存(A)...] はまだ実装していないので、とりあえず何もしない事にします。

frmuMain.pas

procedure TForm1.acSaveExecute(Sender: TObject);
var
  Enc: TEncoding;
begin
  if (FFileName = '') then
    begin
      // 名前を付けて保存 (未実装)
    end
  else
    begin
      // EncodingIndex によりエンコーディングを指定
      case FEncodingIndex of
        1: Enc := TEncoding.Unicode;
        2: Enc := TEncoding.BigEndianUnicode;
        3: Enc := TEncoding.UTF8;
      else
        Enc := TEncoding.Default;
      end;
      // エンコーディングを指定して保存
      Memo1.Lines.SaveToFile(FFileName, Enc);
    end;
end;

ついでにこのファイル保存ロジックはメソッドにしてしまいましょう。

frmuMain.pas

(前略)
  private
    { Private 宣言 }
    FFileName: String;
    FEncodingIndex: Integer;
    procedure SaveFile;        // <- 追加
    procedure UpdateCaption;
  public
    { Public 宣言 }
  end;

(中略)

procedure TForm1.acSaveExecute(Sender: TObject);
begin
  if (FFileName = '') then
    begin
      // 名前を付けて保存 (未実装)
    end
  else
    begin
      // 上書き保存
      SaveFile;
    end;
end;

procedure TForm1.SaveFile;
var
  Enc: TEncoding;
begin
  // EncodingIndex によりエンコーディングを指定
  case FEncodingIndex of
    1: Enc := TEncoding.Unicode;
    2: Enc := TEncoding.BigEndianUnicode;
    3: Enc := TEncoding.UTF8;
  else
    Enc := TEncoding.Default;
  end;
  // エンコーディングを指定して保存
  Memo1.Lines.SaveToFile(FFileName, Enc);
end;
(後略)

〔Alt〕,〔F〕,〔S〕と順に押しても [上書き保存(S)] が実行される事を確認してください。〔Ctrl〕+〔S〕でも実行されます。

[名前を付けて保存(A)...] の実装

[開く(O)] の逆です。ファイル保存ダイアログを出し、指定されたファイル名でファイルを保存します。ファイル保存ダイアログ用のコンポーネントとして TSaveTextFileDialog を使います。

ツールパレットで絞り込んで探し、フォームデザイナに貼っておきます。

フィルターとエンコーディング

こちらも TOpenTextFileDialog と同様にフィルターとエンコーディングを処理しておきます。

手順は TOpenTextFileDialog と同じなので省略します。

TSaveTextFileDialog では DefaultExt プロパティに txt を指定しておきます。これはファイル名として拡張子を指定しなかった時に追加される拡張子です。例えば "ABC" という名前で保存すると、"ABC.txt" という具合に拡張子を自動で追加します。

そして Options プロパティの ofOverwritePrompt フラグを True にします。これはファイルが既に存在する時に上書き確認のダイアログを出してくれるようになるフラグです。

コード

acSaveAs アクションの onExecute イベントに対応する acSaveAsExecute イベントハンドラに処理を記述します。

先程、[上書き保存(S)] の実装の時にファイルを保存するメソッドは作ったので、ここで行う処理は...

1. SaveTextFileDialog1 を開く
2. ファイルが選択されて [OK] ボタンが押されたら (有効なファイル名が渡されたら)
3. Memo1 の内容を指定されたエンコーディングでファイルに保存

このようになります。

frmuMain.pas

procedure TForm1.acSaveAsExecute(Sender: TObject);
begin
  if SaveTextFileDialog1.Execute then
    begin
      // 値を保存
      FFileName := SaveTextFileDialog1.FileName;
      FEncodingIndex := SaveTextFileDialog1.EncodingIndex;
      // キャプションを変更
      UpdateCaption;
      // ファイルへ保存
      SaveFile;
    end;
end;

procedure TForm1.acSaveExecute(Sender: TObject);
begin
  if (FFileName = '') then
    begin
      // 名前を付けて保存
      acSaveAs.Execute;          // <- 追加
    end
  else
    begin
      // 上書き保存
      SaveFile;
    end;
end;

アクション acSaveAs は、Execute() メソッドで実行する事ができます。実行すると OnExecute イベントのイベントハンドラが実行されます。

〔Alt〕,〔F〕,〔A〕と順に押しても [名前を付けて保存(A)...] が実行される事を確認してください。

[新規(N)] の実装

FormCreate イベントハンドラ内の初期化処理を実行すればよさそうです。

コード

acNew アクションの onExecute イベントに対応する acNewExecute イベントハンドラに処理を記述します。

FormCreate での処理を Init() メソッドとして外に出し、FormCreate と acNewExecute イベントハンドラ内でそれぞれ実行します。

frmuMain.pas

(前略)
  private
    { Private 宣言 }
    FFileName: String;
    FEncodingIndex: Integer;
    procedure Init;                  // <- 追加
    procedure SaveFile;
    procedure UpdateCaption;
  public
    { Public 宣言 }
  end;

(中略)

procedure TForm1.FormCreate(Sender: TObject);
begin
  Init;
end;

procedure TForm1.acNewExecute(Sender: TObject);
begin
  Init;
end;

procedure TForm1.Init;
begin
 // 値を初期化
  FFileName := '';
  FEncodingIndex := 0;
  Memo1.Lines.Clear; // Memo1 の中身を消去する。
  // キャプションを変更
  UpdateCaption;
end;

(後略)

〔Alt〕,〔F〕,〔N〕と順に押しても [新規(N)] が実行される事を確認してください。

おわりに } end.

いかがでしたでしょうか？Delphi でメモ帳クローンを作るのは難しくないという事がおわかり頂けたかと思います。もちろん、実装していない機能はまだまだあり、メモ帳は見た目ほど簡単なアプリケーションではないという事も認識できたかと思います。

テキストエディタとしては最低限の機能しか実装していないので、残りの部分については次の記事 (来週です！) でやろうと思っております。今回の分の全ソースコードを掲載しておきますので、興味がある方は残りの部分を実装してみてください。

ソースコード中の TMenuItem の定義部分、F1 とか N1 とかは IDE が自動で付けた名前ですので、名前が異なるかもしれませんが気にしないでください。

frmuMain.pas

unit frmuMain;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, System.Actions,
  Vcl.ActnList, Vcl.Menus, Vcl.ExtDlgs, System.IOUtils;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    MainMenu1: TMainMenu;
    ActionList1: TActionList;
    acNew: TAction;
    acOpen: TAction;
    acSave: TAction;
    acSaveAs: TAction;
    acPageSetup: TAction;
    acPrint: TAction;
    acExit: TAction;
    F1: TMenuItem;
    N1: TMenuItem;
    O1: TMenuItem;
    S1: TMenuItem;
    A1: TMenuItem;
    U1: TMenuItem;
    P1: TMenuItem;
    X1: TMenuItem;
    N2: TMenuItem;
    N3: TMenuItem;
    OpenTextFileDialog1: TOpenTextFileDialog;
    SaveTextFileDialog1: TSaveTextFileDialog;
    procedure FormCreate(Sender: TObject);
    procedure acExitExecute(Sender: TObject);
    procedure acOpenExecute(Sender: TObject);
    procedure acSaveExecute(Sender: TObject);
    procedure acSaveAsExecute(Sender: TObject);
    procedure acNewExecute(Sender: TObject);
  private
    { Private 宣言 }
    FFileName: String;
    FEncodingIndex: Integer;
    procedure Init;
    procedure SaveFile;
    procedure UpdateCaption;
  public
    { Public 宣言 }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
// フォーム作成時
begin
  Init;
end;

// [FILE] Actions

procedure TForm1.acNewExecute(Sender: TObject);
// Action: 新規(N)
begin
  Init;
end;

procedure TForm1.acOpenExecute(Sender: TObject);
// Action: 開く(O)...
var
  Enc: TEncoding;
begin
  if OpenTextFileDialog1.Execute then
    begin
      // 値を保存
      FFileName := OpenTextFileDialog1.FileName;
      FEncodingIndex := OpenTextFileDialog1.EncodingIndex;
      // キャプションを変更
      UpdateCaption;
      // EncodingIndex によりエンコーディングを指定
      case FEncodingIndex of
        1: Enc := TEncoding.Unicode;
        2: Enc := TEncoding.BigEndianUnicode;
        3: Enc := TEncoding.UTF8;
      else
        Enc := TEncoding.Default;
      end;
      // エンコーディングを指定して読み込み
      Memo1.Lines.LoadFromFile(FFileName, Enc);
    end;
end;

procedure TForm1.acSaveExecute(Sender: TObject);
// Action: 上書き保存(S)
begin
  if (FFileName = '') then
    begin
      // 名前を付けて保存
      acSaveAs.Execute;
    end
  else
    begin
      // 上書き保存
      SaveFile;
    end;
end;

procedure TForm1.acSaveAsExecute(Sender: TObject);
// Action: 名前を付けて保存(A)...
begin
  if SaveTextFileDialog1.Execute then
    begin
      // 値を保存
      FFileName := SaveTextFileDialog1.FileName;
      FEncodingIndex := SaveTextFileDialog1.EncodingIndex;
      // キャプションを変更
      UpdateCaption;
      // ファイルへ保存
      SaveFile;
    end;
end;

procedure TForm1.acExitExecute(Sender: TObject);
// Action: メモ帳の終了(X)
begin
  Self.Close;
end;

// メソッド

procedure TForm1.Init;
// エディタの初期化
begin
 // 値を初期化
  FFileName := '';
  FEncodingIndex := 0;
  Memo1.Lines.Clear; // Memo1 の中身を消去する。
  // キャプションを変更
  UpdateCaption;
end;

procedure TForm1.SaveFile;
// Memo の内容をファイルに保存
var
  Enc: TEncoding;
begin
  // EncodingIndex によりエンコーディングを指定
  case FEncodingIndex of
    1: Enc := TEncoding.Unicode;
    2: Enc := TEncoding.BigEndianUnicode;
    3: Enc := TEncoding.UTF8;
  else
    Enc := TEncoding.Default;
  end;
  // エンコーディングを指定して保存
  Memo1.Lines.SaveToFile(FFileName, Enc);
end;

procedure TForm1.UpdateCaption;
// キャプション (ファイル名) の更新
var
  Dmy: String;
begin
  if FFileName = '' then
    Dmy := '無題'
  else
    Dmy := TPath.GetFileName(FFileName);
  Self.Caption := Dmy + ' - メモ帳クローン';
end;

end.

余談:
この記事を書くのに Windows 8.1 を使っているのは何故かというと、Delphi は他のグレードの Delphi と共存できないからです。Windows 10 の実機には Delphi (正確には RAD Studio) 10.2 Tokyo Professional Edition がインストールされており、Starter Edition がインストールできそうな余ってた VM は Windows 8.1 だけだったのです。

P.S.
{ } は Object Pascal でのブロックコメントです。何の事？って右上にあるリスト (インデックス) の事です

=> to be continued.