【自作焙煎ロガー】RP2040とMAX6675でArtisanに2chの温度(BT/ET)をModbus送信する

Last updated at 2026-02-23Posted at 2026-02-23

【コスパ最強】RP2040とMAX6675でコーヒー焙煎用温度ロガーを自作し、ArtisanとModbus通信する

コーヒーの自家焙煎をしていると、だんだん「Artisan（焙煎プロファイル記録ソフト）で温度を可視化したい！」という欲求が湧いてきますよね。
今回は、マイコン（RP2040）と温度センサー（MAX6675）を使って、PC直結のコスパ最強温度ロガーを自作した備忘録です。

実は最初は「小さいOLEDディスプレイを付けようかな」「ESP32でWebSocket通信にしてワイヤレスにしようかな」と夢を膨らませていました。

しかし、

「いや、焙煎中はPC画面を見るし、安定性重視のコスパ最強構成にして焙煎そのものに注力するべきだ！」

と思い直し、今回の有線シンプル構成に落ち着きました。

ただ、この構成に行き着くまでにネット上に情報がなさすぎて10時間くらい溶かしたトラップがあったので、同じ犠牲者を出さないために共有します。

😫 最大のハマりポイント：複数チャネルのデータ渡しとModbusの採用

結論から言うと、

「Artisanに2つの温度（BT：豆温度、ET：環境温度）を同時に渡すなら、おとなしくModbusを使え！」

という話です。

Artisanとマイコンをシリアル通信させる際、ネット上の情報を見ると「シリアル出力で Behmor BT/CT や TC4 などの既存デバイスプロトコルをエミュレートしてArtisanに読み込ませる」という手法が散見されます。
私も最初はそれに倣って実装したのですが、どうしてもArtisan側に1チャネル分のデータしか渡らない、もしくはエラーという事象に直面しました。

BT（豆温度）とET（環境温度）の2つを同時にモニタリングしたいのに、片方しか認識されない。ソースコードをいじったりArtisanの設定をこねくり回したりと、気づけば10時間ほど経過……。

結果的に、
「Modbus RTUプロトコルを使って、Artisan側からレジスタを指定して読みに行かせる」
という方法に切り替えたところ、あっさりと2チャネル同時の通信に成功しました。複数センサーを扱うならModbus一択です。

🛠 用途・コンセプト

PCと直接接続する（有線シリアル通信）
とにかくコスパ重視（余計なモジュールは付けない）
ArtisanにBT（豆温度）とET（環境温度）を安定して渡す

📦 使用するパーツ

1. RP2040（マイコン）：352円

以下のようなやつを利用。以前に大量購入したものを利用。
RP2040 (Amazon)

2. MAX6675モジュール × 2個（温度センサーIC）：999円

MAX6675温度センサーモジュール (Amazon)
Kタイプ熱電対の温度を読み取るICです。BT用とET用に2セット用意します。Kタイプ熱電対は付属のものでもOKですが、焙煎機の形状に合わせて適切な長さや太さのものを別途購入しても良いです。

🔌 RP2040とMAX6675のピン配線

以下のように配線しました。共通化もできるのですが、一応ノイズとかあるのかな？と思ったので別にわけました。

MAX6675ピン	BT(豆温度)用のRP2040ピン	ET(環境温度)用のRP2040ピン
SO (DO)	GP 0	GP 12
CS	GP 1	GP 13
SCK (CLK)	GP 2	GP 14
VCC	3V3	5V
GND	GND	GND（共有）

💻 Arduino IDEでの開発準備

1. RP2040のボードマネージャ追加

Arduino IDEの Preferences（環境設定）を開き、「追加のボードマネージャのURL」に以下をコピペします。
https://github.com/earlephilhower/arduino-pico/releases/download/global/package_rp2040_index.json

その後、ボードマネージャからRP2040を追加し、ボード設定は "Raspberry Pi Pico" を選択します。

2. 必要なライブラリのインストール

以下のライブラリを追加します。（IDEのライブラリマネージャから検索、またはZIPで追加）

3. スケッチ（ソースコード）

以下のコードをコピーしてRP2040に書き込みます。オンボードLEDを利用して、
「正常時は緑、エラー時（センサー未接続など）は赤」
が一瞬光るようにしています。動作確認に便利です。

#include <max6675.h>
#include <ModbusRtu.h>
#include <Adafruit_NeoPixel.h>

// -------------------------
// ピン設定（MAX6675）
// -------------------------
// 1個目：BT(豆温度)用
#define DO_BT   0
#define CS_BT   1
#define CLK_BT  2

// 2個目：ET(環境温度)用
#define DO_ET   12
#define CS_ET   13
#define CLK_ET  14

// -------------------------
// ピン設定（RP2040 Zero オンボードLED）
// -------------------------
#define PIN_LED  16 // RP2040 ZeroのオンボードLEDはGP16
#define NUM_LEDS 1

// 各種インスタンス作成
MAX6675 thermoBT(CLK_BT, CS_BT, DO_BT);
MAX6675 thermoET(CLK_ET, CS_ET, DO_ET);
Adafruit_NeoPixel strip(NUM_LEDS, PIN_LED, NEO_GRB + NEO_KHZ800);
Modbus slave(1, 0, 0); 

// Modbus共有データ配列 (BT=0番, ET=1番)
uint16_t au16data[16] = { 0 };

// 時間管理用の変数
unsigned long lastReadTime = 0;
unsigned long ledOffTime = 0;

void setup() {
  Serial.begin(115200);
  slave.begin(115200);

  // LEDの初期設定
  strip.begin();
  strip.setBrightness(50); // 眩しすぎないように明るさを調整(0〜255)
  strip.show(); // 一旦消灯

  delay(500); // センサー安定待ち
}

void loop() {
  // 500ms(0.5秒)おきに温度を更新
  if (millis() - lastReadTime > 500) {
    
    float tempBT = thermoBT.readCelsius();
    float tempET = thermoET.readCelsius();

    bool isError = false;

    // BTの処理
    if (!isnan(tempBT)) {
      au16data[0] = (uint16_t)(tempBT * 100.0);
    } else {
      isError = true; // 読み取り失敗
    }

    // ETの処理
    if (!isnan(tempET)) {
      au16data[1] = (uint16_t)(tempET * 100.0);
    } else {
      isError = true; // 読み取り失敗
    }
    
    // --- LEDを光らせる処理 ---
    if (isError) {
      // エラー時（センサー未接続など）は「赤」
      strip.setPixelColor(0, strip.Color(255, 0, 0)); 
    } else {
      // 正常に読めている時は「緑」
      strip.setPixelColor(0, strip.Color(0, 255, 0)); 
    }
    strip.show(); // 点灯
    
    // 100ms後にLEDを消すための時間をセット（一瞬だけ光らせる）
    ledOffTime = millis() + 100;
    
    lastReadTime = millis();
  }

  // セットされた時間(100ms後)になったらLEDを消灯する処理
  if (ledOffTime > 0 && millis() > ledOffTime) {
    strip.setPixelColor(0, strip.Color(0, 0, 0));
    strip.show();
    ledOffTime = 0; // タイマーをリセット
  }

  // Modbusの通信リクエストに応答（ループを止めずに常時回す）
  slave.poll(au16data, 16);
}