.tar.gz ファイルを扱うことが多いが 7-zip などのツールで圧縮・展開すると2段階の操作が必要で手間がかかるので、右クリックメニューに追加してみた。快適。

まずはバッチファイルを2つ作り、任意のパスに配置する

バッチファイルなので文字コードは Shift-Jis, 改行は CRLF にする。

targz圧縮.bat

@echo on

:: フォルダ名を取得
for %%A in (%1) do set "FOLDER_NAME=%%~nxA"

:: 親フォルダのフルパスを取得
for %%A in (%1) do set "PARENT_FOLDER=%%~dpA"

:: 結果を表示（確認用）
echo フォルダ名: "%FOLDER_NAME%"
echo 親フォルダのフルパス: "%PARENT_FOLDER%"
:: 親フォルダへ移動    
cd %PARENT_FOLDER%
:: 圧縮
tar -zcvf "%FOLDER_NAME%.tar.gz" ".\%FOLDER_NAME%"

pause

targz展開.bat
```
@echo on
tar -zxvf %1
pause
```

個人用のレジストリに登録する

MS-DOSを起動する(管理者権限でなくても可)

下のコマンドを順番に実行する

:: バッチファイルのパスの設定(任意のパスに設定する)
set BAT_PATH1=C:\Users\yourname\script\targz圧縮.bat
set BAT_PATH2=C:\Users\yourname\script\targz展開.bat

:: ファイルの右クリックメニューに「tar.gz圧縮」を追加
reg add "HKCU\Software\Classes\*\shell\tar.gz圧縮" /ve /d "tar.gz圧縮" /f
reg add "HKCU\Software\Classes\*\shell\tar.gz圧縮\command" /ve /d "\"%BAT_PATH1%\" \"%1\"" /f

:: フォルダの右クリックメニューに「tar.gz圧縮」を追加
reg add "HKCU\Software\Classes\Directory\shell\tar.gz圧縮" /ve /d "tar.gz圧縮" /f
reg add "HKCU\Software\Classes\Directory\shell\tar.gz圧縮\command" /ve /d "\"%BAT_PATH1%\" \"%1\"" /f

:: ファイルの右クリックメニューに「tar.gz展開」を追加
reg add "HKCU\Software\Classes\*\shell\tar.gz展開" /ve /d "tar.gz展開" /f
reg add "HKCU\Software\Classes\*\shell\tar.gz展開\command" /ve /d "\"%BAT_PATH2%\" \"%1\"" /f

追加したメニューを削除する場合は以下のとおり

reg delete "HKCU\Software\Classes\*\shell\tar.gz圧縮" /f
reg delete "HKCU\Software\Classes\Directory\shell\tar.gz圧縮" /f
reg delete "HKCU\Software\Classes\*\shell\tar.gz展開" /f