【ESP32】乾電池駆動を目指したDeepSleep実験備忘録

Posted at 2026-01-02

はじめに

みなさま、あけましておめでとうございます。
今年もコツコツと技術を楽しみながら進んでいきたいと思います。
本年もどうぞよろしくお願いいたします。

さて、今回は「ESP32を電池で動かしたい」というテーマに挑戦します。
コンセントの位置に縛られず、好きな場所にセンサーを置けたら便利ですよね。
ということで、ESP32の乾電池駆動にトライしてみました。

準備

まずは単三乾電池3本を格納できる電池パックを用意しました。
乾電池1本は約1.5Vですが、実測すると3本で約4.8Vありました。

配線は以下の通りです。

電池パックの＋ → ESP32 の 5V
電池パックの − → ESP32 の GND

ESP32 DevKitCの5Vピンにはレギュレータが載っているため、乾電池3本の電圧でもそのまま給電できます。

ソースコード

DeepSleepを使って 10分おきに起動 → DHT22の計測 → データ送信 → 再びDeepSleep という流れです。

#include <WiFi.h>
#include <Ambient.h>
#include <DHT.h>

#define channelId xxxxx
#define writeKey "xxxxx"

WiFiClient client;
Ambient ambient;

#define DHTPIN 13
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);

const char *ssid = "xxxxx";
const char *password = "xxxxx";

// DeepSleep時間10分
#define SLEEP_US (600ULL * 1000000ULL)

void setup() {
  Serial.begin(115200);
  delay(1000);

  // DHT初期化
  dht.begin();
  delay(2000); // DHT22は起動後2秒待つ必要あり

  // 温湿度取得
  float t = dht.readTemperature();
  float h = dht.readHumidity();

  if (isnan(t) || isnan(h)) {
    Serial.println("[ERROR] Measurement failed!");
    esp_sleep_enable_timer_wakeup(SLEEP_US);
    esp_deep_sleep_start();
  }

  Serial.println("[INFO] Temperature: " + String(t, 1) + "C   Humidity: " + String(h, 1) + "%");

  // Wi-Fi接続
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.print("[INFO] Connecting to WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\n[INFO] Connected!");

  // Ambient初期化
  ambient.begin(channelId, writeKey, &client);

  // Ambient送信
  ambient.set(1, t);
  ambient.set(2, h);

  if (ambient.send()) {
    Serial.println("[INFO] Ambient Send Success!");
  } else {
    Serial.println("[ERROR] Ambient Send Failed!");
  }

  Serial.println("[INFO] Going to DeepSleep...");
  delay(100);

  // DeepSleep設定
  esp_sleep_enable_timer_wakeup(SLEEP_US);
  esp_deep_sleep_start();
}

void loop() {
  // DeepSleepワンショット方式なので使わない
}