More than 1 year has passed since last update.

CryptoGames株式会社

[ERC6982] ガス効率よくNFTをロックする仕組みを理解しよう！

Posted at 2023-10-23

はじめに

初めまして。
CryptoGamesというブロックチェーンゲーム企業でエンジニアをしている cardene（かるでね） です！
スマートコントラクトを書いたり、フロントエンド・バックエンド・インフラと幅広く触れています。

代表的なゲームはクリプトスペルズというブロックチェーンゲームです。

今回は、ロック可能なERC721トークンへのガス効率の良いアプローチを提案している規格であるERC6982についてまとめていきます！

以下にまとめられているものを翻訳・要約・補足しながらまとめていきます。

6982は現在（2023年10月19日）では「Review」段階です。

他にも様々なERCについてまとめています。

概要

この提案は、ERC721トークンのロック可能なインターフェースを導入し、不要なイベントを省いてガスの使用効率を向上させるものです。
このインターフェースは、ロック可能なERC721トークンの作成と管理の基盤を提供します。
具体的には、コントラクトをデプロイする際にDefaultLocked(bool locked)イベントを発行し、すべてのトークンの初期ロック状態を設定します。
その後、個々のトークンのステータス変更に関しては、Locked(uint256 indexed tokenId, bool locked)イベントを使用します。
また、このインターフェースには、view関数であるlocked(uint256 tokenId)が含まれており、トークンの現在のロック状態を取得するために使用できます。
さらに、新しく生成されたトークンのデフォルトのステータスをクエリするためのビュー関数defaultLocked()も提供されています。

このERC721コントラクトは、トークンのロックとアンロックを管理するためのガス効率の良い方法を提供します。
デプロイメント時にデフォルトのロック状態を設定し、その後のトークンのステータス変更にはLocked(uint256 indexed tokenId, bool locked)イベントを使用します。
locked(uint256 tokenId)関数を使用して、トークンの現在のロック状態を取得し、defaultLocked()関数を使用して新しく生成されたトークンのデフォルトのロック状態を調べることができます。
これにより、トークンのロックとアンロックを効率的に管理できます。

ERC721については以下を参考にしてください。

動機

従来のロック可能なトークン提案では、トークンがミントされるたびにイベントを発行することが一般的でした。
これは、特にトークンが永久にロックされる場合（例：ソウルバウンドや移動不可のバッジなど）に、不必要なガス消費を引き起こします。
この提案は、よりガス効率の良い解決策を提供し、コントラクトがデプロイされる時点と個々のトークンのステータスが変更される時点でのみイベントを発行する方法を提案しています。

通常のトークン提案では、トークンが作成されるたびにイベントが発生し、これによりガスが無駄に消費されます。
しかし、この提案ではコントラクトがデプロイされる時と個々のトークンのステータスが変更される時にのみイベントを発行します。
これにより、トークンが永久にロックされる場合など、不必要なガスの浪費を削減できます。

仕様

インターフェイスは以下のように定義されています。

// ERC165 interfaceId 0x6b61a747
interface IERC6982 {
  // This event MUST be emitted upon deployment of the contract, establishing 
  // the default lock status for any tokens that will be minted in the future.
  // If the default lock status changes for any reason, this event 
  // MUST be re-emitted to update the default status for all tokens.
  // Note that emitting a new DefaultLocked event does not affect the lock 
  // status of any tokens for which a Locked event has previously been emitted.
  event DefaultLocked(bool locked);

  // This event MUST be emitted whenever the lock status of a specific token 
  // changes, effectively overriding the default lock status for this token.
  event Locked(uint256 indexed tokenId, bool locked);

  // This function returns the current default lock status for tokens.
  // It reflects the value set by the latest DefaultLocked event.
  function defaultLocked() external view returns (bool);

  // This function returns the lock status of a specific token.
  // If no Locked event has been emitted for a given tokenId, it MUST return 
  // the value that defaultLocked() returns, which represents the default 
  // lock status.
  // This function MUST revert if the token does not exist.
  function locked(uint256 tokenId) external view returns (bool);
}

ERC165で使用するインターフェースIDは0x6b61a747です。

ERC165については以下を参考にしてください。

補足

この標準は、ガス消費を最小限に抑えるために、イベントの頻度を最適化することを目指しています。
DefaultLockedイベントは、すべてのトークンのロック状態を確立するために設計されており、新しいトークンがミントされるたびにイベントを発行する必要がありません。
重要なのは、DefaultLockedイベントはいつでも発行でき、Lockedイベントが発行される前だけでなく、その後でも発行できることです。

トークンは特定の状況下でその振る舞いを変更することがあります（たとえば、リビール後など）、新しいデフォルトのステータスを反映するためにDefaultLockedイベントを再発行することがあります。
ここでの主要な目標は、デフォルトのステータスが変更された場合に、各トークンごとにLockedイベントを発行する必要を回避することにより、ガスの使用を節約することです。

Lockedイベントは、個々のトークンのロック状態の変更を記録するために使用されます。

defaultLocked関数は、トークンの現在のデフォルトのロック状態を返します。
この関数は他のコントラクトとのやり取りを容易にし、最終段階にあるERC5192との潜在的な衝突を避けるのに役立ちます。

ERC5192とERC6982は、Ethereumの非代替トークン（NFT）のロック機能に関する異なるアプローチを提供しています。
それぞれの提案は、トークンのロック状態を制御するための機能を提供するが、実装と目的が異なります。

ERC5192: Soulbound NFTs

ERC5192は、EIP721を拡張し、特定のトークンを一つのアカウントに「結びつける」（soulbound）ための最小のインターフェースを提案しています。
この提案では、locked(uint256 tokenId)という名前の関数を使ってトークンのロック状態を照会できます。
トークンがロックされている場合、すべてのEIP721関数はトークンの転送を拒否する必要があります。

ERC-6982: Efficient Default Lockable Tokens

ERC6982は、EIP721トークンのロック可能なインターフェースを導入し、不必要なイベントを削除することでガス使用量を最適化します。
このインターフェースは、DefaultLocked(bool locked)イベントを発行することで、すべてのトークンの初期ロック状態を設定し、個々のトークンのロック状態の変更をLocked(uint256 indexed tokenId, bool locked)イベントで処理します。
さらに、defaultLocked()という名前のview関数を提供して、新しく発行されたトークンのデフォルトのロック状態を照会できます。

潜在的な衝突

ERC6982のdefaultLocked()関数は、他のコントラクトとのやり取りを促進し、ERC5192との潜在的な衝突を回避することを目的としています。
これは、defaultLocked()関数が他のコントラクトとのやり取りを容易にし、ERC5192のようにトークンのロック状態を異なる方法で制御する提案との間に潜在的な衝突を回避するのに役立つためです。

ERC5192については以下を参考にしてください。

locked関数は、特定のトークンの現在のロック状態を提供し、他のコントラクトとのやり取りを助けます。
特定のトークンIDに変更が加えられていない場合、この関数はdefaultLocked関数が提供する値を返すべきです。

トークンが「ロックされた」と指定されていることは、必ずしもそのトークンが完全に譲渡できないことを意味しません。
特定の条件下では、トークンがロックされていても譲渡できる場合があります。
主に、ロック状態はマーケットプレイスや外部取引所でのトークンの譲渡可能性に関連しています。

例として、Crunaプロトコルを考えてみましょう。
このシステムでは、NFTの所有者は「イニシエータ」と呼ばれるものをアクティベートできます。
これは、キー取引を開始する特権を持つサブウォレットです。イニシエータを設定すると、トークンのステータスが「ロック」されます。
しかし、指定されたイニシエータからのtransferの開始があれば、トークンの譲渡は妨げられません。

後方互換性

この標準は、既存のERC721コントラクトと完全に後方互換性があります。
この標準では、既存のコントラクトに新しい機能を追加するためのシームレスな方法を提供します。
言い換えれば、既存のトークンや契約に変更を加えることなく、ERC7507を導入できるということです。

ERC7507は既存のトークンやアプリケーションに対して、新しい機能やガス効率の向上をもたらす可能性を秘めています。
この標準を使用することで、既存のトークンと連携しながら、新しい要件やニーズに対応できます。
そして、それを行う時には、既存のトークンやコントラクトに問題や混乱をもたらすことなく、スムーズに統合できます。

参考実装

以下のGithubには、特定の使用ケースを解決するための具体的な実装例が含まれています。

この実装の主な目的は、トークンの所有者がアセットをプールにステーキングする時に、通常の状況では所有権を失わないようにすることです。
通常、トークンをステーキングすると、そのトークンの所有権が移動し、所有者が取り戻すことが難しくなります。
しかし、この実装では、プールがアセットをロックすることができ、同時にトークンの所有者に所有権を保持させることができます。

具体的な手順やコントラクトのコンパイルおよびテスト方法については、READMEファイルに詳細が記載されています。
この実装は、所有者とプールの間でトークンのやり取りを管理し、特定の使用ケースにおいてトークンの流動性と所有権を維持するのに役立つものです。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.19;

// Authors: Francesco Sullo <francesco@sullo.co>

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "./IERC721Lockable.sol";
import "./IERC6982.sol";

// This is an example of lockable ERC721 using IERC6982 as basic interface

contract ERC721Lockable is IERC6982, IERC721Lockable, Ownable, ERC721, ERC721Enumerable {
  using Address for address;

  mapping(address => bool) private _locker;
  mapping(uint256 => address) private _lockedBy;

  bool internal _defaultLocked;

  modifier onlyLocker() {
    require(_locker[_msgSender()], "Not a locker");
    _;
  }

  constructor(
    string memory name,
    string memory symbol,
    bool defaultLocked_
  ) ERC721(name, symbol) {
    updateDefaultLocked(defaultLocked_);
  }

  function defaultLocked() external view override returns (bool) {
    return _defaultLocked;
  }

  function updateDefaultLocked(bool defaultLocked_) public onlyOwner {
    _defaultLocked = defaultLocked_;
    emit DefaultLocked(defaultLocked_);
  }

  function _beforeTokenTransfer(
    address from,
    address to,
    uint256 tokenId,
    uint256 batchSize
  ) internal override(ERC721, ERC721Enumerable) {
    require(
      // during minting
      from == address(0) ||
        // later
        !locked(tokenId),
      "Token is locked"
    );
    super._beforeTokenTransfer(from, to, tokenId, batchSize);
  }

  function supportsInterface(bytes4 interfaceId) public view override(ERC721, ERC721Enumerable) returns (bool) {
    return
      interfaceId == type(IERC6982).interfaceId ||
      interfaceId == type(IERC721Lockable).interfaceId ||
      super.supportsInterface(interfaceId);
  }

  function locked(uint256 tokenId) public view virtual override returns (bool) {
    require(_exists(tokenId), "Token does not exist");
    return _lockedBy[tokenId] != address(0);
  }

  function lockerOf(uint256 tokenId) public view virtual override returns (address) {
    return _lockedBy[tokenId];
  }

  function isLocker(address locker) public view virtual override returns (bool) {
    return _locker[locker];
  }

  function setLocker(address locker) external virtual override onlyOwner {
    require(locker.isContract(), "Locker not a contract");
    _locker[locker] = true;
    emit LockerSet(locker);
  }

  function removeLocker(address locker) external virtual override onlyOwner {
    require(_locker[locker], "Not an active locker");
    delete _locker[locker];
    emit LockerRemoved(locker);
  }

  function hasLocks(address owner) public view virtual override returns (bool) {
    uint256 balance = balanceOf(owner);
    for (uint256 i = 0; i < balance; i++) {
      uint256 id = tokenOfOwnerByIndex(owner, i);
      if (locked(id)) {
        return true;
      }
    }
    return false;
  }

  function lock(uint256 tokenId) external virtual override onlyLocker {
    // locker must be approved to mark the token as locked
    require(isLocker(_msgSender()), "Not an authorized locker");
    require(getApproved(tokenId) == _msgSender() || isApprovedForAll(ownerOf(tokenId), _msgSender()), "Locker not approved");
    _lockedBy[tokenId] = _msgSender();
    emit Locked(tokenId, true);
  }

  function unlock(uint256 tokenId) external virtual override onlyLocker {
    // will revert if token does not exist
    require(_lockedBy[tokenId] == _msgSender(), "Wrong locker");
    delete _lockedBy[tokenId];
    emit Locked(tokenId, false);
  }

  // emergency function in case a compromised locker is removed
  function unlockIfRemovedLocker(uint256 tokenId) external virtual override {
    require(locked(tokenId), "Not a locked tokenId");
    require(!_locker[_lockedBy[tokenId]], "Locker is still active");
    require(ownerOf(tokenId) == _msgSender(), "Not the asset owner");
    delete _lockedBy[tokenId];
    emit ForcefullyUnlocked(tokenId);
  }

  // manage approval

  function approve(address to, uint256 tokenId) public virtual override(IERC721, ERC721) {
    require(!locked(tokenId), "Locked asset");
    super.approve(to, tokenId);
  }

  function getApproved(uint256 tokenId) public view virtual override(IERC721, ERC721) returns (address) {
    if (locked(tokenId) && lockerOf(tokenId) != _msgSender()) {
      return address(0);
    }
    return super.getApproved(tokenId);
  }

  function setApprovalForAll(address operator, bool approved) public virtual override(IERC721, ERC721) {
    require(!approved || !hasLocks(_msgSender()), "At least one asset is locked");
    super.setApprovalForAll(operator, approved);
  }

  function isApprovedForAll(address owner, address operator) public view virtual override(IERC721, ERC721) returns (bool) {
    if (hasLocks(owner)) {
      return false;
    }
    return super.isApprovedForAll(owner, operator);
  }
}

`_locker`

mapping(address => bool) private _locker;

概要
アドレスごとにブール値（真偽値）を関連付ける配列。

詳細

_locker マッピングは、各アドレスに対して、そのアドレスが「ロッカー」として機能するかどうかを示すブール値を関連付けます。
_locker[_msgSender()]は_msgSender()関数が返す現在の呼び出し元アドレスに対応するブール値を返します。
_lockerマッピングはプライベートなので、外部からは直接アクセスできません。

パラメータ

address
- アドレスとそのロッカーの状態（真偽値）を関連付けるためのキーと値のペアが含まれます。

`_lockedBy`

mapping(uint256 => address) private _lockedBy;

概要
トークンIDごとにロッカーのアドレスを関連付ける配列。
特定のトークンがどのアドレスによってロックされているかを追跡します。

詳細

_lockedByマッピングは、各トークンIDに対して、そのトークンをロックしたアドレスを関連付けます。
_lockedBy[トークンID]は、指定したトークンIDに対応するロッカーのアドレスを返します。
_lockedByマッピングもプライベートなので、外部からは直接アクセスできません。

パラメータ

uint256
- トークンIDとそのロックを実行したアドレスが関連付けられます。

`_defaultLocked`

bool internal _defaultLocked;

概要
デフォルトのロック状態を示すブール値（真偽値）。
デフォルトでトークンがロックされているかどうかを示します。

詳細

_defaultLockedブール値は、コントラクト内でデフォルトのロック状態を定義します。
トークンがデプロイされたときの初期状態を表します。
_defaultLockedがtrueの場合、デフォルトでトークンはロックされた状態となり、falseの場合はロックされていない状態となります。
この変数はinternalなので、同じコントラクト内で継承されたコントラクトからアクセスできます。

パラメータ

bool
- デフォルトのロック状態を示すブール値です。
- trueはロック状態を示し、falseはロック解除状態を示します。

`onlyLocker`

modifier onlyLocker() {
    require(_locker[_msgSender()], "Not a locker");
    _;
}

概要
特定の条件を満たす呼び出し元にのみアクセスを許可する修飾子。
呼び出し元が「ロッカー」として設定されている場合にのみ、関数やコードブロックにアクセスできます。

詳細

onlyLocker修飾子は、トランザクションが実行される前に特定の条件をチェックします。
条件として、_locker[_msgSender()]がtrue（つまり、呼び出し元がロッカーである）であるかどうかを確認します。
もし条件が満たされない場合、requireステートメントによりエラーメッセージ「Not a locker」が表示され、トランザクションが中断されます。
条件が満たされると、修飾子が付いた関数やコードブロックが実行されます。

`defaultLocked`

function defaultLocked() external view override returns (bool) {
    return _defaultLocked;
}

概要
デフォルトのロック状態が設定されているか取得する関数。

詳細

デフォルトのロック状態が設定されているかどうかを外部から取得するために使用されます。
関数の修飾子としてexternal view overrideが指定されており、外部から読み取り専用でアクセス可能です。
関数は_defaultLocked変数の値を返します。

戻り値

bool
- デフォルトのロック状態。
- trueはロックされていることを示し、falseはロック解除状態を示します。

`updateDefaultLocked`

function updateDefaultLocked(bool defaultLocked_) public onlyOwner {
    _defaultLocked = defaultLocked_;
    emit DefaultLocked(defaultLocked_);
}

概要
デフォルトのロック状態を更新する関数。
オーナーによって呼び出されます。

詳細

updateDefaultLocked関数は、デフォルトのロック状態を指定された値に更新し、それに応じて DefaultLockedイベントを発行します。
関数は_defaultLocked変数の値を更新します。
この関数はオーナーによってのみ呼び出すことができます。

引数

defaultLocked_
- デフォルトのロック状態を指定するブール値。
- trueはロックされていることを示し、falseはロック解除状態を示します。

戻り値

なし。

`_beforeTokenTransfer`

function _beforeTokenTransfer(
    address from,
    address to,
    uint256 tokenId,
    uint256 batchSize
) internal override(ERC721, ERC721Enumerable) {
    require(
        // during minting
        from == address(0) ||
        // later
        !locked(tokenId),
        "Token is locked"
    );
    super._beforeTokenTransfer(from, to, tokenId, batchSize);
}

概要
トークンのtransferが行われる前に実行される前処理を担当する関数。
トークンがロックされている場合、トークンのtransferを拒否します。

詳細

トークンのtransferが行われる前に呼び出され、transferの条件を検証します。
条件として、fromアドレスからのtransferの場合（ミント中）、またはトークンがロックされていない場合にtransferを許可します。
それ以外の場合、エラーメッセージ「Token is locked」が表示されてtransferが中断されます。
この関数はERC721やERC721Enumerableの関数をオーバーライドしています。
最後に、親クラスの_beforeTokenTransfer関数を呼び出します。

引数

from
- トークンの送信元アドレス。
to
- トークンの送信先アドレス。
tokenId
- トークンのID。
batchSize
- バッチ処理の際のバッチサイズ。

`supportsInterface`

function supportsInterface(bytes4 interfaceId) public view override(ERC721, ERC721Enumerable) returns (bool) {
    return
        interfaceId == type(IERC6982).interfaceId ||
        interfaceId == type(IERC721Lockable).interfaceId ||
        super.supportsInterface(interfaceId);
}

概要
指定されたインターフェースがサポートされているかを確認する関数。
複数のインターフェースに対応しています。

詳細

指定されたインターフェースIDがサポートされているかを確認します。
サポートされているインターフェースにはIERC6982やIERC721Lockableが含まれます。
また、親クラスのERC721やERC721Enumerableのインターフェースもサポートされています。
関数はinterfaceIdを受け取り、それに対応するインターフェースがサポートされている場合にtrueを返します。

引数

interfaceId
- インターフェースIDを表すバイト列。

戻り値

bool
- 指定されたインターフェースがサポートされている場合はtrue、それ以外はfalseを返します。

`locked`

function locked(uint256 tokenId) public view virtual override returns (bool) {
    require(_exists(tokenId), "Token does not exist");
    return _lockedBy[tokenId] != address(0);
}
``

`

**概要**
指定されたトークンがロックされているかを確認する関数。

**詳細**
- `locked`関数は、指定されたトークンIDに対して、そのトークンがロックされているかどうかを確認します。
- トークンが存在しない場合はエラーメッセージ「**Token does not exist**」を表示します。
- ロックされている場合、対応するアドレスが空ではないかを確認します。
- 非空であればトークンはロックされています。

**引数**
- `tokenId`
  - 確認するトークンのID。

**戻り値**
- `bool`
  - 指定されたトークンがロックされている場合は`true`、それ以外は`false`を返します。

---

### `lockerOf`

```javascript
function lockerOf(uint256 tokenId) public view virtual override returns (address) {
    return _lockedBy[tokenId];
}

概要
指定されたトークンのロッカー（ロックを実行したアドレス）を取得する関数。

詳細

指定されたトークンIDに対応するロッカーのアドレスを取得します。
トークンが存在しない場合でも、対応するアドレスを返しますが、このアドレスは通常トークンがロックされていない場合には空のアドレスとなります。

引数

tokenId
- ロッカーを取得するトークンのID。

戻り値

address
- 指定されたトークンのロッカーのアドレス。

`isLocker`

function isLocker(address locker) public view virtual override returns (bool) {
    return _locker[locker];
}

概要
指定されたアドレスがロッカーであるか確認する関数。

詳細

指定されたアドレスがロッカーであるかどうかを確認します。
ロッカーである場合、trueを返し、そうでない場合はfalseを返します。

引数

locker
- 確認するアドレス。

戻り値

bool
- 指定されたアドレスがロッカーである場合はtrue、それ以外はfalseを返します。

`setLocker`

function setLocker(address locker) external virtual override onlyOwner {
    require(locker.isContract(), "Locker not a contract");
    _locker[locker] = true;
    emit LockerSet(locker);
}

概要
ロッカー（コントラクト）を設定する関数。

詳細

指定されたアドレスをロッカーとして設定します。
ロッカーとして設定するアドレスがコントラクトであることを確認します。
ロッカーが正常に設定された場合、関数は_lockerマッピングを更新し、LockerSetイベントを発行します。
コントラクトの所有者のみが実行できます。

引数

locker
- 設定するロッカー（コントラクト）のアドレス。

`removeLocker`

function removeLocker(address locker) external virtual override onlyOwner {
    require(_locker[locker], "Not an active locker");
    delete _locker[locker];
    emit LockerRemoved(locker);
}

概要
アクティブなロッカーを削除する関数。

詳細

指定されたアドレスがアクティブなロッカーであることを確認し、それを削除します。
アクティブなロッカーであるかどうかを_lockerマッピングを通じて確認します。
ロッカーが正常に削除された場合、関数は_lockerマッピングからロッカーを削除し、LockerRemovedイベントを発行します。
コントラクトの所有者のみが実行できます。

引数

locker
- 削除するアクティブなロッカーのアドレス。

`hasLocks`

function hasLocks(address owner) public view virtual override returns (bool) {
    uint256 balance = balanceOf(owner);
    for (uint256 i = 0; i < balance; i++) {
        uint256 id = tokenOfOwnerByIndex(owner, i);
        if (locked(id)) {
            return true;
        }
    }
    return false;
}

概要
所有者がロックされたトークンを持っているかどうか確認する関数。

詳細

指定された所有者がロックされたトークンを持っているかどうかを確認します。
所有者のトークン数を取得し、それぞれのトークンがロックされているかどうかを確認します。
ロックされたトークンがある場合はtrueを返し、すべてのトークンがロック解除されている場合はfalseを返します。

引数

owner
- ロックされたトークンを持つ所有者のアドレス。

戻り値

bool
- 所有者がロックされたトークンを持っている場合はtrue、それ以外はfalseを返します。

`lock`

function lock(uint256 tokenId) external virtual override onlyLocker {
    require(isLocker(_msgSender()), "Not an authorized locker");
    require(getApproved(tokenId) == _msgSender() || isApprovedForAll(ownerOf(tokenId), _msgSender()), "Locker not approved");
    _lockedBy[tokenId] = _msgSender();
    emit Locked(tokenId, true);
}

概要
トークンをロックする関数。

詳細

指定されたトークンをロックし、トークンの所有者にロック権限を与えます。
ロッカーが正当な権限を持っていることを確認し、トークンがロッカーによって承認されているかどうかも確認します。
トークンが正常にロックされた場合、関数は_lockedByマッピングを更新し、Lockedイベントを発行します。

引数

tokenId
- ロックするトークンのID。

`unlock`

function unlock(uint256 tokenId) external virtual override onlyLocker {
    require(_lockedBy[tokenId] == _msgSender(), "Wrong locker");
    delete _lockedBy[tokenId];
    emit Locked(tokenId, false);
}

概要
トークンのロックを解除する関数。

詳細

指定されたトークンのロックを解除します。
ロックを解除する権限を持つロッカーであるかどうかを確認し、正当なロッカーであることを確認します。
トークンが正常にロック解除された場合、関数は_lockedByマッピングからロック情報を削除し、Lockedイベントを発行します。

引数

tokenId
- ロックを解除するトークンのID。

`unlockIfRemovedLocker`

function unlockIfRemovedLocker(uint256 tokenId) external virtual override {
    require(locked(tokenId), "Not a locked tokenId");
    require(!_locker[_lockedBy[tokenId]], "Locker is still active");
    require(ownerOf(tokenId) == _msgSender(), "Not the asset owner");
    delete _lockedBy[tokenId];
    emit ForcefullyUnlocked(tokenId);
}

概要
ロッカーが削除された場合にトークンのロックを強制的に解除する関数。

詳細

指定されたトークンのロックを強制的に解除します。
トークンがロックされていることを確認し、ロッカーがまだアクティブでないこと、および呼び出し元がアセットの所有者であることを確認します。
トークンが正常に強制的にロック解除された場合、関数は_lockedByマッピングからロック情報を削除し、ForcefullyUnlockedイベントを発行します。

引数

tokenId
- 強制的にロック解除するトークンのID。

セキュリティ考慮事項

このEIPは、既知のセキュリティ上の考慮事項を導入していません。
しかし、他のスマート・コントラクト標準と同様に、このインターフェースの実装には厳格なセキュリティ対策を実装することが重要です。

引用

Francesco Sullo (@sullof), Alexe Spataru (@urataps), "ERC-6982: Efficient Default Lockable Tokens [DRAFT]," Ethereum Improvement Proposals, no. 6982, May 2023. [Online serial]. Available: https://eips.ethereum.org/EIPS/eip-6982.

最後に

今回は「ロック可能なERC721トークンへのガス効率の良いアプローチを提案している規格であるERC6982」についてまとめてきました！
いかがだったでしょうか？

質問などがある方は以下のTwitterのDMなどからお気軽に質問してください！

Twitter @cardene777

他の媒体でも情報発信しているのでぜひ他も見ていってください！

You get articles that match your needs
You can efficiently read back useful information
You can use dark theme

What you can do with signing up