LoginSignup
0
0

More than 3 years have passed since last update.

@bothbossandboss

【GW自由研究】Arduinoで簡易洗濯機を作りたい

Last updated at Posted at 2021-05-10

背景

GWだけどステイホームで外出できないため，家でできる電子工作にチャレンジした．
コロナ対策としてガーゼマスク1を妻が使っているが，手洗いする必要があるため，その手間を省こうと，簡易洗濯機を作ろうと思い立った．
この記事はその挫折記録である．

先行研究

子供用おもちゃとしてミニチュア洗濯機が販売されている．こちらのように水を入れて使用できないタイプが多いが，某100円ショップで販売されているミニ洗濯機は実際に洗濯ができると話題になった．100円ショップで買えるとあって非常に安価だが，速度調整やきちんとした脱水ができないなど，通常の洗濯機の機能とは乖離がある．（あと近くの店で売ってない．）
家電にも小型洗濯機というジャンルがある．勿論機能面は申し分がない．しかし，値段が数千円台とそこそこするのと，GW暇だから電子工作をしたいという本来の目的にそぐわない．
手動洗濯機も販売されている．要するに小さい手動洗濯機を自動で回す制御部分を作れば目的を達成できる．が，マスクを洗うという目的には少しサイズが大きい．

アプローチ

大きく3つのステップで作成することを検討．

  • step1 制御部作成

  • step2 洗濯槽作成

  • step3 合体

本記事では，step1の制御部作成について記載する．
今回は，大学生の頃に購入し眠っていたArduino Leonardoを活用することにした．
はんだごてすら持っていないので，ジャンプワイヤやブレッドボードでできる範囲で実装した．

制御部の要件

  • 洗濯物が絡まるのを防ぐため，回転方向を左右交互に繰り返すことができる．

  • 洗濯時間を手動で設定できる．

  • 残り時間などを簡単に把握できる．

これらの要件を満たすため，L298Nモータードライバを用いてモータの回転速度と方向を変化させ，タクトスイッチを用いて洗濯時間を変化できるようにし，OLEDディスプレイを用いて残り時間や現在の状態を表示し，洗濯終了の通知として，ブザーを用いて音を鳴らすことを検討した．また，モータの回転軸の変換および減速のため，ユニバーサルギアボックスを用いた．

回路図

試行錯誤の結果，図のような回路を構成した．
回路図.png
LEDは状態遷移を分かりやすくするために配置した．
回路図はFritzingを使いたかったが有料だったので，draw.ioで一から描いた．ダイオード・抵抗・ブザーなどの記号はあったので助かった．

プログラム

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <Buzzer.h>

#define OLED_RESET 4
#define RED_LED_PIN 13
#define GREEN_LED_PIN 12
#define MACHINE_STATE_BUTTON_PIN 10
#define START_BUTTON_PIN 8
#define DEFAULT_TIME 5
#define MOTOR_ENA_PIN 5
#define MOTOR_INPUT1_PIN 6
#define MOTOR_INPUT2_PIN 7
#define BUZZER_PIN 11

Adafruit_SSD1306 display(OLED_RESET);
Buzzer buzzer(BUZZER_PIN);
int machine_state = 0; // 0: init, 1: washing and drying, 2: finished
boolean switch_on = false;
int switch_count = 0;
int washing_time = DEFAULT_TIME;

void setup() {
    // LED
    pinMode(RED_LED_PIN, OUTPUT); // wash, red
    pinMode(GREEN_LED_PIN, OUTPUT); // dry, green

    // input pin
    pinMode(MACHINE_STATE_BUTTON_PIN, INPUT);
    pinMode(START_BUTTON_PIN, INPUT);

    // motor
    pinMode(MOTOR_ENA_PIN, OUTPUT);
    pinMode(MOTOR_INPUT1_PIN, OUTPUT);
    pinMode(MOTOR_INPUT2_PIN, OUTPUT);

    display.begin(SSD1306_SWITCHCAPVCC, 0x3C);  // initialize with the I2C addr 0x3D (for the 128x64)
    display.clearDisplay();
    display.setTextSize(2);
    display.setTextColor(WHITE);
    display.setCursor(0,0);
    display.println("Hello");
    display.println("(^_^)");
    display.display();
    delay(1000);
    display.clearDisplay();
    Serial.begin(9600);
}


void rotation(int start_v, int peak_v, int step_v, int peak_time, int stop_time, int step_time){
    digitalWrite(MOTOR_INPUT1_PIN, HIGH);
    digitalWrite(MOTOR_INPUT2_PIN, LOW);
    for (int i = start_v; i <= peak_v; i+=step_v) {
        analogWrite(MOTOR_ENA_PIN, i);
        delay(step_time);
    }
    delay(peak_time);
    for (int i = peak_v; i >= start_v; i-=step_v) {
        analogWrite(MOTOR_ENA_PIN, i);
        delay(step_time);
    }
    digitalWrite(MOTOR_INPUT1_PIN, LOW);
    digitalWrite(MOTOR_INPUT2_PIN, LOW);
    delay(stop_time);
    digitalWrite(MOTOR_INPUT1_PIN, LOW);
    digitalWrite(MOTOR_INPUT2_PIN, HIGH);
    for (int i = start_v; i <= peak_v; i+=step_v) {
        analogWrite(MOTOR_ENA_PIN, i);
        delay(step_time);
    }
    delay(peak_time);
    for (int i = peak_v; i >= start_v; i-=step_v) {
        analogWrite(MOTOR_ENA_PIN, i);
        delay(step_time);
    }
    digitalWrite(MOTOR_INPUT1_PIN, LOW);
    digitalWrite(MOTOR_INPUT2_PIN, LOW);
    delay(stop_time);
}

void wash(){
    // ( (peak_v - start_v) / step_v + 1 ) * step_time * 4 + peak_time * 2 + stp_time * 2
    // = 20 sec
    // --> * 3 --> 1 min
    for (int k = 0; k < 3; k++){
        rotation(80, 150, 10, 4800, 2000, 200);
    }
}

void washing(int washing_step, int drying_step){
    char buf[64];
    digitalWrite(RED_LED_PIN, HIGH);
    for(int i = washing_step; i > 0; i--){
        display.clearDisplay();
        display.setCursor(0,0);
        sprintf(buf, "Washing %d", i);
        display.println(buf);
        sprintf(buf, "Drying  %d", drying_step);
        display.println(buf);
        display.display();
        wash();
    }
    digitalWrite(RED_LED_PIN, LOW);
}

void dry(){
    // ( (peak_v - start_v) / step_v + 1 ) * step_time * 4 + peak_time * 2 + stp_time * 2
    // = 20 sec
    // --> * 3 --> 1 min
    for (int k = 0; k < 3; k++){
        rotation(80, 250, 10, 4400, 2000, 100);
    }
}

void drying(int washing_step, int drying_step){
    char buf[64];
    digitalWrite(GREEN_LED_PIN, HIGH);
    for(int i = drying_step; i > 0; i--){
        display.clearDisplay();
        display.setCursor(0,0);
        sprintf(buf, "Washing %d", washing_step);
        display.println(buf);
        sprintf(buf, "Drying  %d", i);
        display.println(buf);
        display.display();
        dry();
    }
    digitalWrite(GREEN_LED_PIN, LOW);
    display.clearDisplay();
    display.setCursor(0,0);
    display.println("Washing 0");
    display.println("Drying  0");
    display.display();
    delay(1000);
}

void play_music(){
    buzzer.begin(10);
    buzzer.sound(NOTE_C3, 600);
    buzzer.sound(NOTE_D3, 300);
    buzzer.sound(NOTE_E3, 300);
    buzzer.sound(NOTE_F3, 300);
    buzzer.sound(NOTE_G3, 300);
    buzzer.sound(NOTE_A3, 300);
    buzzer.sound(NOTE_B3, 300);
    buzzer.sound(NOTE_C4, 600);
    buzzer.sound(NOTE_B3, 300);
    buzzer.sound(NOTE_A3, 300);
    buzzer.sound(NOTE_G3, 300);
    buzzer.sound(NOTE_F3, 300);
    buzzer.sound(NOTE_E3, 300);
    buzzer.sound(NOTE_D3, 300);
    buzzer.sound(NOTE_C3, 600);
    buzzer.end(2000);
}

void loop() {
    Serial.print("machine state");
    Serial.println(machine_state);
    Serial.print("slide switch");
    Serial.println(digitalRead(START_BUTTON_PIN));
    boolean t = digitalRead(START_BUTTON_PIN);
    // machine_state = switch_count % 3;
    if (machine_state == 0) {
        boolean now_switch_state = digitalRead(MACHINE_STATE_BUTTON_PIN);
        if (now_switch_state && !switch_on) {
            switch_count++;
        }
        delay(50); // チャタリング防止用．本当はハードでも対処した方が良いが今回はスキップ
        switch_on = now_switch_state;
        washing_time = (switch_count + DEFAULT_TIME - 1) % 10 + 1;
        display.clearDisplay();
        display.setCursor(0,0);
        display.print("Washing ");
        display.println(washing_time);
        display.print("Drying ");
        display.println(washing_time);
        display.display();
        if (digitalRead(START_BUTTON_PIN)) {
            machine_state = 1;
        }
    } else if (machine_state == 1) {
        washing(washing_time, washing_time);
        drying(0, washing_time);
        machine_state = 2;
        play_music();
    } else if (machine_state == 2) {
        if (digitalRead(START_BUTTON_PIN)) {
            display.clearDisplay();
            display.setTextColor(WHITE);
            display.setCursor(0,0);
            display.println("Finished.");
            display.display();
            delay(1000);
            display.clearDisplay();
            display.setTextColor(BLACK, WHITE);
            display.setCursor(0,0);
            display.println("Finished.");
            display.display();
            delay(1000);
        } else {
            display.clearDisplay();
            display.setTextColor(WHITE);
            delay(1000);
            machine_state = 0;
            washing_time = DEFAULT_TIME;
            switch_count = 0;
        }
    } else {
        display.clearDisplay();
        display.setTextColor(WHITE);
        display.setCursor(0,0);
        display.println("ERROR");
        display.display();
    }
}

実装結果

動作結果は下記動画をご覧いただきたい．（動画の拙さはご容赦ください．）

まず電池ボックスの電源を入れるとArduinoが起動し洗濯時間調整画面へ遷移する．
タクトスイッチを押すたびに洗濯時間が1分ずつ増え，最大10分まで設定できる．
洗濯時間を設定したら，スライドスイッチを奥側に押すとモータが回転し始め"洗濯"が開始される．
なお，タイヤが取り付けられた軸が洗濯槽の回転を表しており，プロペラが取り付けられた軸は洗濯機能とは関係ないが，プロペラはギアボックスの軸がぶれないための重しの役割も担っていると思っている．（あとプロペラ良いじゃない．）
洗濯中は赤色LEDが点灯しており，脱水中は緑色LEDが点灯する．
脱水が終わるとブザーから音が流れ，OLEDディスプレイに終了通知が出る．
スライドスイッチを元に戻すと洗濯時間調整画面に戻る．

今回は簡単のため洗濯時間と乾燥（脱水）時間を同じにしたが，脱水の場合は洗濯のときよりも回転速度を向上させることで効率的に脱水できるのではないかと考えている．（実際に洗濯していないのでわからない．今後の課題とさせていただきたい．）

新規購入物品一覧

名前　 用途 購入先 価格
工作用コード モータドライバ結線用．結局未使用． Amazon 160円
デジタルテスター 電圧・抵抗測定用 Amazon 1,273円
L298Nモータドライバ モータ制御用 Amazon 799円（2個セット）
OLEDディスプレイ ステータス表示用 Amazon 740円
電池ボックス 外部電源用 Amazon 398円
ジャンプワイヤ（メス-オス） モータドライバ結線用 Amazon 350円
ユニバーサルギアボックス モータ回転軸・速度調整用 ヨドバシカメラ 555円
クリップワイヤ モータ結線用 ヨドバシカメラ 521円
グリス ギアボックスの速度向上・消音用 ヨドバシカメラ 322円
プロペラ 軸回転の可視化 ヨドバシカメラ 247円
タイヤセット 軸回転の可視化 ヨドバシカメラ 305円

未使用や今後も使えるものも合わせて，合計5,670円．...結構かかったな...
デジタルテスターは今後も他の電子工作に使用可能であり，工作用コード・プロペラ・タイヤセット・グリスは今回の工作での重要度は低いので除外，モータドライバは2個セットだったので1個だけの計上とすると，合計2,443円．安くなったな．よし．

まとめと今後の課題

マスク洗濯用の簡易洗濯機を作成するため，洗濯槽の回転を制御する部分をArduinoを用いて実装した．結果として，モーターの回転速度と方向を変化させ，さらに稼働時間を調整可能な制御部を実現できた．
今後の課題は山積みであるが，最大は洗濯槽本体の作成である．洗濯槽本体には，100円ショップで販売されているサラダスピナーがサイズと機能の両方を満たすと考えている．今後時間が取れれば作成していきたい．
あー楽しかった！

参考文献

様々なサイトを参考にしたが，ログが残っているものだけ挙げさせていただく．

  1. 妻が使っているマスクはこんな感じのレースマスクである．配られた某マスクではない． ↩

0
0
1

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
Sign upLogin
0
0