Excel VBAにおける変数と定数の基本

私はVBAの活用経験を通じて得た知識を整理し、共有する目的で記事を作成しているプログラミング歴1年半になるエンジニアです。
前回は、Excel VBAの基本的なオブジェクト操作について解説しました。今回は、プログラミングの基礎となる「変数」と「定数」について説明していきます。「変数」を使いこなせるかどうかで、VBAを使いこなせるかどうかが決まると言っても過言ではありません！変数を理解し、適切に使いこなせるようになれば、より複雑な処理を自動化できるようになり、VBAの世界がさらに広がります！

目次

はじめに
 Option Explicitの効果
 変数とは
 型定義・変数の宣言をしないことによる不具合
 変数のスコープ設定
 オブジェクト変数の代入について
 定数の活用
 まとめ

はじめに

「変数」は、データを一時的に保存するための「箱」のようなものです。適切な変数の使用は、以下のような利点があります。

プログラムの可読性向上
メモリの効率的な使用
バグの防止
コードの保守性向上

変数はVBAプログラミングにおいて基礎となるだけでなく、コードの品質を左右する重要な要素です。今回の記事を通して、変数を適切に扱うための知識を深め、より効率的で信頼性の高いVBAプログラムを作成できるようにしていきましょう。

Option Explicitの効果

Option Explicit はモジュールの先頭に記述して、すべての変数が明示的に宣言されているかを確認するための（宣言されていない変数の使用を許可しない）オプションです。この設定により、未宣言の変数があればエラーとして警告が表示され、タイポやコーディングミスを発見しやすくなります。

変数の暗黙的な宣言を禁止
（宣言されていない変数としてエラーが発生 → 早期ミス発見）
- タイプミスによるバグを防止
- 未定義変数の使用を防止
コードの品質向上
- 変数の使用意図が明確になる
- デバッグ（バグや誤りを見つけて修正すること）が容易になる
- 他の人がコードを読む際や、後から自分でコードを見直す際に理解しやすくなる

Option Explicit           ' モジュールの先頭に記述

Sub サンプルコード()
    Dim str名前 As String ' 明示的な変数宣言が必要
    str名前 = "山田太郎"
    MsgBox str名前
End Sub

Option Explicitは必ず記述しましょう

未定義の変数使用によるバグを防ぐため、モジュールの先頭に必ず記述することを強く推奨します。

Option Explicitの自動挿入設定

VBEを開く
[ツール] → [オプション] を選択
[エディタ] タブの [変数の宣言を強制する] にチェック

第1回: Excel VBAの基礎知識とセキュリティ設定にも設定方法を記載しております。

変数とは

変数とは、プログラムの中でデータを一時的に記憶しておくためのものです。

例えば、商品の値段や個数を扱う場合、それぞれの値を変数に格納することで、計算や表示を効率的に行うことができます。変数を使うことで、コードがシンプルで見やすくなるだけでなく、後から修正が必要になった場合にも、変更箇所を少なく済ませることができます。

変数名のルール

使用できる文字: アルファベット、日本語、数字、アンダースコア（ _ ）
先頭文字: アルファベット、日本語
予約語: VBAであらかじめ定義されている語句（Sub、End Sub、Dim など）は使用できません
長さ: 255文字以内

データ型

データ型とは、変数に格納するデータの種類のことです。

VBAで扱える主なデータ型には、以下のようなものがあります。（抜粋）

Long（長整数型）: 整数値を扱うときに使用
（Integer という似たような型もありますが、基本的に Long を使用で問題ありません）
String（文字列型）: 文字列データを扱うときに使用
Single （単精度浮動小数点数）: 精度が低くてもよい小数を扱うときに使用
Double（倍精度浮動小数点型）: 高精度の（精度が求められる）小数を扱うときに使用
Date （日付）: 日付を扱うときに使用
Boolean（論理型）: 真偽値（True/False）を扱うときに使用
Variant （任意のデータ型）: データ型が不明な場合や、複数のデータ型を扱う場合に一時的に使用（非推奨）

変数の宣言と型指定

変数は使用前に必ず宣言しましょう。変数宣言は、基本的に Dim ステートメント（VBAの処理や命令、宣言などを行うための構文: プログラムを書くときのルール）を使って行います。Dim ステートメントは変数を設定する時の呪文（変数を利用するためのキーワード）と考えてください。基本的な宣言方法は以下の通りです。

' 変数宣言の型
Dim 変数名 As データ型

' 例：
Dim strName As String    ' 文字列型の変数
Dim intAge As Long       ' 長整数型の変数
Dim dblPrice As Double   ' 倍精度浮動小数点型の変数

命名規則のベストプラクティス

プレフィックス（単語の先頭につける文字）でデータ型を示す（ハンガリアン記法）
- str , int , dbl などのデータ型の省略文字
日本語でも英語でも可（業務に合わせて選択）
わかりやすい名前を付ける

' 良い例
Dim strCustomerName As String  ' 顧客名
Dim int従業員数 As Long         ' 従業員数
Dim dbl売上金額 As Double       ' 売上金額

' 悪い例
Dim x As String                ' 変数の用途が不明確
Dim a1 As Long                 ' 意味のない命名
Dim data As Double             ' 具体性に欠ける

複数の変数を1行で宣言

' カンマで区切って複数の変数を宣言可能
Dim strName As String, intAge As Long, dblHeight As Double

複数の変数を1行で宣言する場合は、各変数にデータ型を明示してください。
下記のように、意図しないデータ型になります。

' 注意：以下のように省略しない（As String を省略）
Dim strName, intAge As Long, dblHeight As Double
' strNameは暗黙的にVariant型となってしまう

ハンガリアン記法について

VBAでは、変数名の先頭にデータ型を示すプレフィックス（接頭辞）を付ける「ハンガリアン記法」が伝統的に広く使われてきました。例えば、文字列型（String）の変数には「str」、整数型（Long）の変数には「int」といったプレフィックスを付けます。

' ハンガリアン記法の使用例
Dim strUserName As String ' strはString型を示す
strUserName = "田中 太郎" ' ユーザー名を格納

Dim intUserAge As Long    ' intはLong型を示す
intUserAge = 20           ' ユーザーの年齢を格納

Dim blnLoggedIn As Boolean ' blnはBoolean型を示す
blnLoggedIn = False        ' ログイン状態を格納

ハンガリアン記法のメリット

変数のデータ型が一目でわかるため、コードの可読性が向上する
特に大規模なプロジェクトや、複数の開発者が関わる場合に、変数の型を間違えるリスクを減らすことができる

ハンガリアン記法は非推奨

ハンガリアン記法は以下の理由により、現代のプログラミングでは推奨されなくなっております。

型推論や強力な IDE の普及により、型情報を変数名に含める必要性が低下
(IDE: プログラミングを効率的に行うために作られた総合的な開発環境。コードの補完や自動チェック機能などを備えたソフトウェア)
変数の型が変更された場合、変数名も変更する必要がある

現代的なプログラミングでは、変数の役割や目的を明確に表現する命名を重視する傾向にあります。

ハンガリアン記法がVBAで広く使用されている理由

歴史的な経緯
VB（Visual Basicの略で、Microsoftが開発したプログラミング言語）では、ハンガリアン記法が推奨されており、その影響がVBAにも残っています。
既存のコードベースとの一貫性
多くの既存のVBAコードがハンガリアン記法を使用しているため、互換性を保つために現在も使用されています。
VBAの開発環境の特性
VBAの開発環境（VBE）は、比較的新しい IDE に比べて、型推論やコード補完の機能が限定的です。そのため、ハンガリアン記法が、役立つ場合があります。

VBAでよく使用されるプレフィックス（接頭辞）の例

' 基本的なデータ型
Dim str名前 As String    ' str: 文字列型
Dim int年齢 As Long      ' int: 整数型
Dim dbl価格 As Double    ' dbl: 小数点数型
Dim bln確認 As Boolean   ' bln: 論理型

' Excelオブジェクト
Dim wb作業簿 As Workbook  ' wb: ブック
Dim ws売上表 As Worksheet ' ws: シート
Dim rng選択範囲 As Range  ' rng: 範囲

変数名の命名規則の重要性

ハンガリアン記法は、広く使用されていることもあり、ベストプラクティスに私は記載しております。
しかし、現代のログラミングでは、非推奨です。

ハンガリアン記法の是非はさておき、最も重要なのは、一貫した命名規則を使用し、可読性と保守性を維持することです。適切な変数名をつけることで、コードの意図が明確になり、後から見直す際やチームでの開発時に理解しやすくなります。

既存のVBAコードが、ハンガリアン記法が使われていないコードであれば、キャメルケース（単語の先頭を大文字にする記法：例 userName）を使用したり、日本語の変数名を使用しても良いでしょう。

変数名の命名ポイント

変数の用途が分かる具体的な名前をつける
一貫性のある命名規則を使用する
あまりに短すぎたり長すぎたりする名前は避ける
チーム内で統一された命名規則を使用する

命名規則（キャメルケースなど）について、以下の私の記事でまとめております。
😫命名規則で悩まない！初心者のための命名規則ガイド💡

ぜひ、ご覧ください。

型定義・変数の宣言をしないことによる不具合

型定義

予期せぬ演算結果

Sub 商品コード結合例()
    ' 型を定義しない場合
    Dim 商品区分, 連番          ' 暗黙的にVariant型
    商品区分 = 100 
    連番 = 101 
    
    ' 数値の加算として処理されてしまう
    MsgBox 商品区分 + 連番      ' 結果：201（100 + 101 として計算される）
    
    ' 文字列型として定義する場合
    Dim str商品区分 As String, str連番 As String
    str商品区分 = 100
    str連番 = 101
    
    ' 文字列の結合として正しく処理される
    MsgBox str商品区分 & str連番 ' 結果："100001"（意図した商品コード）
End Sub

このように、型を明示的に定義しないことで、予期せぬ演算結果になる可能性があります。そのため、変数を使用する際は適切な型を定義することが重要です。
また、変数のデータ型が明示されていないため、コードの可読性が低下します。これは、後からコードを見直す際に、変数の役割を理解することを困難にします。

メモリ使用の非効率化

' 型を定義しない場合（暗黙的にVariant型となる）
Dim 数値         ' メモリを16バイト使用
数値 = 10

' 型を定義する場合
Dim 数値 As Long ' メモリを4バイト使用
数値 = 10

Variant型は処理速度が遅く、メモリも多く使用します。特に大量のデータを扱う場合や、繰り返し処理を行う場合は、適切な型を定義することで、メモリ使用量を抑え、処理速度を向上させることができます。

詳細なデータ型とメモリ使用量については、Microsoftの公式ドキュメントをご参照ください。

変数の宣言

実は、VBAでは変数を宣言せずに使用することができます。しかし、これは一見便利に見えますが、予期せぬバグを引き起こす原因となるため、避けるべきです。

Sub 型定義なし()
    Filename = "data.xlsx" ' 変数の宣言なしで使用
    MsgBox Filename
End Sub

上記はエラーなく動作しますが、変数 fileName は宣言せずに使用しているため、暗黙的に Variant 型として扱われます。そのため、型定義をしないことによる不具合が、発生する可能性があります。
また、変数名にタイプミスがあった場合、新しい変数が暗黙的に生成されてしまいます。これは意図しない動作を引き起こす原因となります。

Sub 型定義なし()
    Filename = "data.xlsx" ' 変数の宣言なしで使用
    MsgBox Filenamae       ' 変数名をタイポ
End Sub

上記はエラーなく動作しますが、メッセージボックスには何も表示されません。これは、FilenameとFilenamaeが別の変数として扱われているためです。Filenamaeは未定義の新しい変数として自動的に作成され、初期値（空の値）が設定されています。このように、変数を宣言せずに使用すると、タイプミスに気づきにくく、バグの発見が遅れる原因となります。

これらの問題は、冒頭で説明したOption Explicitを使用することで防ぐことができます。Option Explicitを設定していれば、未宣言の変数を使用した時点でコンパイルエラーとなり、早期にバグを発見できます。

変数のスコープ設定

変数のスコープとは、その変数が使用可能な範囲のことです。適切なスコープ設定により、変数の管理が容易になり、バグの防止にもつながります。

スコープの種類

プロシージャレベル（Sub内のみ）
```
'【モジュール1】
Sub 例題A1()
    Dim localVar As String ' このSub内でのみ使用可能
    localVar = "ローカル変数"
    MsgBox localVar        ' メッセージボックスに表示される
End Sub

Sub 例題A2()
    MsgBox localVar        ' メッセージボックスに表示されない
End Sub

'【モジュール2】
Sub 例題A3()
    MsgBox localVar        ' エラーになる
End Sub
```
プロシージャレベルの変数は、宣言されたSub（またはFunction）内でのみ使用できる最も限定的なスコープです。Dim ステートメントで宣言し、そのプロシージャが終了すると変数は破棄されます。一時的な値の保持に最適で、他のプロシージャに影響を与えることがないため、最も安全な変数宣言方法です。例のように、例題A1() で宣言した変数は、他のプロシージャ（ 例題A2() や 例題A3() ）からはアクセスできません。
モジュールレベル（モジュール内で共有）

Private（プライベート）: 宣言したモジュール内だけで使用可能
```
'【モジュール1】
Option Explicit

Private moduleVar As String ' モジュール内のすべてのSubで使用可能

Sub 例題B1()
    moduleVar = "モジュール変数"
    MsgBox moduleVar        ' メッセージボックスに表示される
End Sub

Sub 例題B2()
    ' 例題B1で設定した値を使用可能
    MsgBox moduleVar        ' メッセージボックスに表示される
End Sub

'【モジュール2】
Sub 例題B3()  
    MsgBox moduleVar        ' メッセージボックスに表示されない
End Sub
```
モジュールレベルの変数は、そのモジュール内のすべてのプロシージャから参照できます。Private ステートメントを使用して宣言し、モジュールが開いている間は値が保持されます。同じモジュール内の複数のプロシージャで共有したい値がある場合に便利です。例のように、例題B1() で設定した値を 例題B2() で参照できますが、別モジュールの例題B3()からは参照できません。

また、プロシージャの外で Dim ステートメントを使って変数を宣言した場合、自動的に Private 属性が設定されます。つまり、下記のように記載しても、Private moduleVar As String と宣言した場合と同じように扱われます。(上記のコードと同じになります。)
```
'【モジュール1】
Option Explicit

' 自動的にPrivate属性が設定される
Dim moduleVar As String 

' 以下、同上
```
しかし、可読性を考慮すると、下記の理由で Private を明記することを推奨します。
- コードの意図が明確になる
- 他の開発者がコードを読む際に変数のスコープが一目で分かる
- 将来的なコードのメンテナンス性が向上する
グローバルレベル（すべてのモジュールで共有）

Public（パブリック）: 全てのモジュールで使用可能
```
'【モジュール1】
Option Explicit

Public globalVar As String ' すべてのモジュールで使用可能

Sub 例題C1()
    globalVar = "グローバル変数"
    MsgBox globalVar       ' メッセージボックスに表示される
End Sub

Sub 例C2()
    ' 例題C1で設定した値を使用可能
    MsgBox globalVar       ' メッセージボックスに表示される
End Sub

'【モジュール2】
Sub 例題C3()
    MsgBox globalVar       ' メッセージボックスに表示される
End Sub
```
グローバルレベルの変数は、VBAプロジェクト内のすべてのモジュールからアクセスできます。Public ステートメントを使用して宣言し、プロジェクト全体で値を共有する必要がある場合に使用します。例のように、例題C1() で設定した値を、同じモジュールの 例題C2() だけでなく、別モジュールの 例題C3() からも参照することができます。ただし、グローバル変数の使用は、コードの依存関係を複雑にする可能性があるため、必要最小限に抑えることをお勧めします。

グローバル変数の問題点コード例

'【モジュール1】
Option Explicit

' グローバル変数として合計金額を宣言
Public globalTotal As Long

Sub 商品Aの金額を加算()
    ' 商品Aの金額を計算
    Dim itemAPrice As Long
    itemAPrice = 1000

    ' グローバル変数の合計金額に加算
    globalTotal = globalTotal + itemAPrice
End Sub

'【モジュール2】
Sub 商品Bの金額を加算()
    ' 商品Bの金額を計算
    Dim itemBPrice As Long
    itemBPrice = 2000

    ' グローバル変数の合計金額に加算
    globalTotal = globalTotal + itemBPrice
End Sub

'【モジュール3】
Sub 合計金額を表示()
    MsgBox "合計金額は" & globalTotal & "円です。"
End Sub

'【モジュール4】
Sub 初期化処理()
    ' グローバル変数の合計金額を初期化
    globalTotal = 0
End Sub

一見すると、このプログラムは正しく動作するように見えます。しかし、以下のような重大な問題が潜んでいます。

実行順序の依存性
- 初期化処理を実行し忘れると、前回の実行時の値が残ったまま計算が始まる
- 各モジュールの処理順序が変わると、計算結果が変わる
デバッグの困難さ
- どのモジュールで値が変更されたのか追跡が難しい
- 複数の処理で同じ変数を使用するため、バグの原因特定が困難
予期せぬ値の変更
- 他のモジュールで意図せずに値が変更される可能性がある
- エラー処理が複雑になる

このような問題を防ぐため、できるだけローカル変数やモジュール変数を使用し、処理結果は戻り値として返すことをお勧めします。

グローバル変数の使用は最小限に

デバッグが困難になる
コードの保守性が低下する
予期せぬバグの原因となる
スコープを狭く設定することで、変数の不正アクセスを防ぎ、コードの意図せぬ変更を防げます。
可能な限り、必要最小限のスコープで変数を宣言することをお勧めします。

スコープの種類まとめ

スコープ	説明	宣言時のキーワード
ローカル変数	特定のプロシージャ（Sub、またはFunction）内でのみ有効な変数	Dim
モジュール変数	モジュール全体で有効な変数	Private
グローバル変数	すべてのモジュールから参照可能な変数	Public

オブジェクト変数の代入について

VBAでは、Worksheetなどのオブジェクトを変数に代入する場合、必ず Set ステートメントを使用する必要があります。

オブジェクト変数の基本

' Worksheetオブジェクトを格納する変数を宣言
Dim ws As Worksheet  

' 正しい代入方法（Setを使用）
Set ws = ThisWorkbook.Sheets("Sheet1") ' シートオブジェクトを変数に代入

' 誤った代入方法（Setを使用しない）
ws = ThisWorkbook.Sheets("Sheet1")     ' コンパイルエラーになる

オブジェクト変数の活用例

Sub シート操作例()
    ' シートオブジェクトを格納する変数を宣言
    Dim ws作業シート As Worksheet
    
    ' Setを使用してシートを変数に代入
    Set ws作業シート = ThisWorkbook.Sheets("売上データ")
    
    ' 代入したシートオブジェクトを使用して操作
    ws作業シート.Range("A1").Value = "商品名" ' A1セルに「商品名」を入力
    ws作業シート.Range("B1").Value = "個数"   ' B1セルに「個数」を入力
End Sub

オブジェクト変数の解放

オブジェクト変数が不要になった場合は、以下のように Set を使用して Nothing を代入することで、メモリを解放できます。

Set ws作業シート = Nothing  ' オブジェクト変数の解放

定数の活用

変数は、その名の通り値が変化する（変わる数）ものを扱うために使用します。
一方、定数は、プログラム内で変更されない値を定義するために使用します。定数は、Const ステートメントを使用して宣言します。

定数のメリット

コードの可読性向上
値の一括変更が容易
タイプミスの防止
メンテナンス性・再利用性の向上

定数の宣言方法

' 定数の基本的な宣言
Const 定数名 As データ型 = 値

' 例：
Const TAX_RATE As Double = 0.1          ' 消費税率
Const MAX_ROWS As Long = 1000           ' 最大行数
Const FILE_PATH As String = "C:\data\"  ' ファイルパス

消費税率のような変更の可能性がある値は、定数として一か所で定義すると、修正が1か所で済むので便利です！

変数と定数の使い分け

区分	変数	定数
定義	プログラム実行中に値を変更できる	プログラム実行中に値を変更できない
宣言	`Dim` ステートメント	`Const` ステートメント
使用例	計算途中の値、ユーザー入力値、カウンター等	税率、ファイルパス、最大値

基本的には、値が変更される可能性がある場合は変数を使用し、値が固定されている場合は定数を使用します。

まとめ

変数は一時的にデータを保存するための重要な要素であり、その使い方次第でVBAプログラムの効率や信頼性が大きく向上します。特に、Option Explicit を活用することで、未宣言の変数使用によるバグを防ぎ、プログラムの品質を高めることができます。また、変数のスコープをしっかりと理解することで、変数の適切な管理が容易になり、不要なバグを防ぐことができるでしょう。さらに、定数の利用は固定値の管理を楽にし、メンテナンス性を向上させるので、プログラム全体の一貫性を保つためには非常に有効です。

もし記事の内容で不明な点や、より詳しく知りたい部分がありましたら、コメントでお知らせください。また、実務での経験やベストプラクティスなども、ぜひ共有していただければ幸いです。

次回は、シートの操作と最終行取得に焦点を当てたVBAの技法を詳しく解説する予定です。VBAのシート操作に関する理解を深め、実務での活用に役立てていただければと思います。どうぞお楽しみに！