NDL Authoritiesでの上位語、下位語、関連語、同義語、同義語から標目、参考を検索するためのSPARQLクエリチートシート

はじめに

この記事のポイント

Web Authorities Endpointにおける典拠データの上位語・下位語・関連語・同義語・同義語から標目・参考を検索する際の、
SPARQLのクエリを掲載します。

Web Authorities、典拠データとは

国立国会図書館の運営する典拠データの検索サイトです。
https://id.ndl.go.jp/auth/ndla

「典拠データとは何か、その利便性」についてはこちらの記事を参照して下さい。
https://qiita.com/Avocado/items/1270612179fac82ac187

SPARQLとは

WEB APIでエンドポイントを呼び出し、データベースへのアクセスを行う際に
必要となる言語です。
クエリは、このページでテストすることが可能です。
また、詳細な仕様も掲載されています。
http://id.ndl.go.jp/information/sparql/

SPARQLクエリ

例として、「インターネット」、関連語として「Internet」を検索語に使っています。

上位語の検索

query

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?label WHERE{
   ?uri1 rdfs:label "インターネット"; skos:broader ?uri2.
   ?uri2 rdfs:label ?label.
}

result

label
コンピュータネットワーク

下位語の検索

query

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?label WHERE{
   ?uri1 rdfs:label "インターネット"; skos:narrower ?uri2.
   ?uri2 rdfs:label ?label.
}

result

label
セマンティックウェブ
イントラネット
バーチャルプライベートネットワーク

関連語の検索

query

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?label WHERE {
   ?uri1 rdfs:label "インターネット"; skos:related ?uri2.
    OPTIONAL{
?uri2 rdfs:label ?label
}}

result

label
IP電話
情報活動 (インターネット)
チャット
インターネット放送
ウェブアプリケーション
ドメイン名
インターネットプロバイダー
インターネット広告
ホームページ
ネットワークゲーム
クロール (インターネット)
インターネット選挙運動
ソーシャルメディア
インターネットショッピング
検索エンジン
ネット犯罪
インターネット依存症

同義語の検索

query

PREFIX xl: <http://www.w3.org/2008/05/skos-xl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?literal WHERE {
   ?uri1 rdfs:label "インターネット"; xl:altLabel ?uri2.
    OPTIONAL{
?uri2 xl:literalForm ?literal
}}

result

literal
Internet

同義語から標目の検索

query

PREFIX xl: <http://www.w3.org/2008/05/skos-xl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?label WHERE {
?uri1 rdfs:label ?label; xl:altLabel ?uri2.
?uri2 xl:literalForm "Internet" .
}

result

label
インターネット

参考の検索

query

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
SELECT DISTINCT ?label WHERE{
?uri1 rdfs:seeAlso ?uri2; rdfs:seeAlso ?uri5.
?uri3 owl:sameAs ?uri2; rdfs:label ?label.
?uri4 owl:sameAs ?uri5; rdfs:label "インターネット".
}

result

label
インターネット
判例
法令
辞書
歴史
会議録
統計
論文集
特許
世論