経緯

ある日友人から「USBフットペダルが欲しいが、どれも野暮ったいデザインばかり。いい製品を知らないか？」と相談を受けました。
オシャレな製品の一つくらいあるだろうと調べてみると、予想と異なり目を覆いたくなるようなデザインの商品しか存在しませんでした。

そこで思いついたのが電子ピアノのフットペダルをUSBフットペダルに利用する方法です。
これをUSB接続できれば最高のUSBフットペダルが出来上がるはず！

でもフットペダルそのものを改造してしまうと、後から増やしたい場合に不便です。
(増設時はフットペダル買ってきて刺すだけで完了させたい)

ということで今回はフットペダルのジャックを接続することでUSBフットペダル化する変換器を作りたいと思います。

作りたいもの

モノラルジャックの接続端子を持ち、信号をArduinoでUSB入力に変換するデバイスを作成します。

材料費 (5,109円)

品名	金額	販売ページ
Arduino Micro	￥3,200	Amazon
モノラルジャックオープンタイプ	￥700	Amazon
デュポンワイヤー(メス)	￥990	Amazon
プラスチックケース	￥219	モノタロウ

1. 調査と設計

1-1. 調査編

フットペダルの接続端子を見ると絶縁ラインは1本のみなので、GND/信号線の2極のはずです。

フットペダルを踏みながらテスターで確認するとしっかり通電してました。
これでフットペダルはただのスイッチと同じ扱いで良いことがわかりました。

次は端子を接続するジャック側のGNDと信号線を確認します。
フットペダルの端子をジャックに接続し、テスターで確認すると中央と右側の端子が通電していることが確認できました。
この端子に配線すればArduino Microでフットペダルの状態を取得できます。

1-2. 設計編

Fritzingでサクッと回路図を作ります。
調査編でフットペダルはただのスイッチに過ぎないと確認したので、回路図上はタクトスイッチとして扱います。
※実際は回路図のスイッチの箇所にジャックを接続します。

配置図	回路図

※あれ？抵抗は？？って思う方いるかもしれませんが、今回はソース側にてINPUT_PULLUPでマイコン内のプルアップ抵抗を使ってるので、回路に抵抗は組み込まないのです！

2. デバイスの作成

2-1. ジャックにワイヤーを接続する

設計図に従ってジャックと配線をはんだ付けします。

2-2. ケースに穴を空ける

ケースにジャックの穴を3ヶ所、USBケーブル用の穴を1ヶ所作成します。
※ドリルで下穴を通して、テーパーリーマーでゴリゴリして空けました。

2-3. ケースに部品を組み込む

ジャックをナットで固定して、Arduino MicroのGPIOピンに配線を接続します。

Arduino Microにmicro USBケーブルを接続して蓋をねじ止めすればデバイスは完成です。

3. ソースコードの焼き込み

3-1. Arduino IDEをインストールする

Arduino IDEをダウンロードしてインストールします。

3-2. 制御用ソースを準備する

※エミュレートするキー値・マウス操作の値　(ソース中のBTN_xに設定する値)

設定値
キーボード (ASCII)
キーボード (拡張)
マウス

以下が制御ソースとなります。

footpedal_fw.ino

# include <Mouse.h>
# include <Keyboard.h>

// キー割り当て
const int BTN_1 = 0x80;
const int BTN_2 = MOUSE_RIGHT;
const int BTN_3 = MOUSE_LEFT;

// 定数
const int BTN_PUSH    = 0;
const int BTN_RELEASE = 1;
const int PIN[] = {8, 9, 10};                  // 利用PIN定義
const int PIN_NUM  = sizeof(PIN) / sizeof(int);// 利用PINの数

// ペダルごとの動作定義
static void push_btn_1(void){ Keyboard.press( BTN_1 ); }
static void push_btn_2(void){ Mouse.press( BTN_2 ); }
static void push_btn_3(void){ Mouse.press( BTN_3 ); }
static void release_btn_1(void){ Keyboard.release( BTN_1 ); }
static void release_btn_2(void){ Mouse.release( BTN_2 ); }
static void release_btn_3(void){ Mouse.release( BTN_3 ); }

void (* const FUNC_BTNS[PIN_NUM][2])(void) = {
    {push_btn_1, release_btn_1},
    {push_btn_2, release_btn_2},
    {push_btn_3, release_btn_3}
};

// グローバル変数
int BEFORE_VALUE[PIN_NUM] = {HIGH, HIGH, HIGH};  // 押下情報記録用 (High -> Low検知式の為、初期値High)

/*
 * 通電時の初期化処理
 */
void setup(){
  // ピン設定
  for (int i=0 ; i < PIN_NUM ; i++) {
      pinMode( PIN[i], INPUT_PULLUP );
  }
}

/*
 * 通電中のループ処理
 */
void loop(){
  for (int i=0 ; i < PIN_NUM ; i++) {

    // ピン値読み取り
    int value = digitalRead( PIN[i] );

    if (value == LOW) {
      if (BEFORE_VALUE[i] == HIGH) {
        // High -> Lowの場合
        FUNC_BTNS[i][BTN_PUSH]();

        // ボタンの変化を記録
        BEFORE_VALUE[i] = value;
      } else {
        // Low -> Lowの場合
        // Do Nothing
      }
    } else {
      if (BEFORE_VALUE[i] == LOW) {
        // Low -> Highの場合
        FUNC_BTNS[i][BTN_RELEASE]();

        // ボタンの変化を記録
        BEFORE_VALUE[i] = value;
      } else {
        // High -> Highの場合
        // Do Nothing
      }
    }
  }

  // ポーリング間隔
  delay( 10 );
}

3-3. 制御ソースをArduinoに焼く

まずはArduino MicroをUSBで開発PCに接続します。

「ツール」→「ボード」から「Arduino Micro」を選択します。

「ツール」→「シリアルポート」から接続している「Arduino Micro」を選択します。

「→」ボタンで制御用ソースを「Arduino Micro」に焼き込みます。

4. 完成

制御ソースの書き込みが完了すればキーボードデバイスとして認識するので、ジャックにフットペダルを接続すれば利用できます。
オシャレなUSBフットペダルでブラウジングやコーディング、ゲーム体験を向上させましょう！
※ゲームとかはもしかするとマクロツール判定されるかもしれないので利用は自己責任で！