よく使う入力規則の例

数値関連

数値になっていません。

OR(
   ISBLANK(AccountNumber),
   NOT(ISNUMBER(AccountNumber))
)

7 桁で指定してください。

OR(
   ISBLANK(AccountNumber),
   LEN(AccountNumber) <> 7
)

100000000000以内で指定してください。

OR(
   AnnualRevenue < 0,
   AnnualRevenue > 100000000000
)

割合は 0 から 100% の間で指定してください。

OR(
   Mix_Pct__c > 1.0,
   Mix_Pct__c < 0.0
)

整数を指定してください。

FLOOR( My_Integer__c) <> My_Integer__c

数量は -50 から 50 までの値を指定してください。

ABS( Volume__c) > 50

日付関連

平日を入力してください

CASE(MOD( My_Date__c - DATE(1900, 1, 7), 7),
0, 0,
6, 0,
1) = 0

今月の日付を入力してください。

OR (
YEAR( My_Date__c ) <> YEAR ( TODAY() ),
MONTH( My_Date__c ) <> MONTH ( TODAY() )
)

月の最終日を指定してください。

DAY(My_Date__c) <>
IF(Month(My_Date__c)=12, 31, DAY(DATE(YEAR(My_Date__c),MONTH(My_Date__c)+1,1) - 1))

完了予定日には今月以降の月を指定してください。

AND(
  OR (
     ISNEW(),
     ISCHANGED( CloseDate )),
  CloseDate < DATE( YEAR(TODAY()), MONTH(TODAY()), 1) )

終了日には、開始日より後の日付を指定してください。

Begin_Date__c > End_Date__c

郵便番号

郵便番号は必須です。

ISBLANK( BillingPostalCode)

郵便番号は 99999 または 99999-9999 の形式で指定してください。

AND(
 OR(BillingCountry = "USA", BillingCountry = "US"),
 NOT(REGEX(BillingPostalCode, "\\d{5}(-\\d{4})?"))
)

項目関連チェック

[その他]指定の場合、理由が必要です。

AND(
  ISPICKVAL( Reason, "Other" ),
  ISBLANK(Other_Reason__c)
)

[Status] が「New」に戻されない

AND(
  ISCHANGED( Status ),
  NOT(ISPICKVAL(PRIORVALUE( Status ), "New")),
  ISPICKVAL( Status, "New")
)

完了した商談は、Number_of_Line_Items__cが下方修正はできません。
PRIORVALUE関数：更新前の値を取得。

AND(
　OR(ISPICKVAL(StageName, "Closed Won"), 
　　　ISPICKVAL(StageName, "Closed Lost")), 
Number_of_Line_Items__c <  PRIORVALUE(Number_of_Line_Items__c) )

このフェーズには [納品日] が必要です。

AND (
  OR (
     ISPICKVAL(StageName, "Closed Won"),
     ISPICKVAL(StageName, "Negotiation/Review")),
ISBLANK(Delivery_Date__c)
)

重要商談(50000以上)はすべて承認されたときにだけクローズできます。

AND(
   OR(
      ISPICKVAL(StageName,"Closed Won"),
      ISPICKVAL(StageName,"Closed Lost")),
(Amount > 50000),
NOT(ISPICKVAL(Approval_Status__c ,"Approved")))

所有者だけ、Personal_Goal__c を更新できる

AND(
   ISCHANGED( Personal_Goal__c ),
   Owner <> $User.Id 
)

一度登録した後に変更できません。

AND(
   NOT( ISNEW() ),
   ISCHANGED( Guaranteed_Rate__c )
)

参照リンク：
https://help.salesforce.com/s/articleView?id=sf.fields_useful_field_validation_formulas.htm&type=5

役立つリンク：
https://help.salesforce.com/s/articleView?id=sf.customize_functions_a_h.htm&type=5