Office 2019オフラインインストール用batファイル(32ビット版のみ)

ボリュームライセンスでOffice Standard 2019を購入し、オフラインでインストールを行う方法です。
インストールは、32ビット版を対象としています。
Office 2019オフラインインストール用batファイル(32ビット版/64ビット版の両方)
Office 2019オフラインインストール用batファイル(64ビット版のみ)

インストールファイルのダウンロード

VLSCからOffice Standard 2019のダウンロードでOffice 2019 Deployment Toolのexeをダウンロードする。

ダウンロードしたexeを実行し、展開先に適当なフォルダ(C:\Office2019)を指定する。
展開先のフォルダにはsetup.exeとサンプルのxmlがある。

展開先のフォルダに次のファイルを作成する。

configuration-x86.xml

<Configuration>
    <Add SourcePath="C:\Office2019\Download_x86" OfficeClientEdition="32" Channel="PerpetualVL2019">
        <Product ID="Standard2019Volume">
            <Language ID="ja-jp" />
        </Product>
    </Add>
</Configuration>

コマンドプロンプトを実行し、setup.exeがある展開先のフォルダに移動して次のコマンドを実行する。
32ビット版のダウンロードが始まる。
ダウンロード中の進捗メータは表示されないので、コマンドが終わるまで待つ。

コマンドプロンプト

setup /download configuration-x86.xml

これで次のフォルダにインストールに必要なファイルがダウンロードされている。

• C:\Office2019\Download_x86

インストーラーファイルの作成

次の2つのファイルを作成する。(シフトJISで作成)

configuration-template.xml

<Configuration>
    <Add SourcePath="$SourcePath$" OfficeClientEdition="$OfficeClientEdition$" Channel="PerpetualVL2019">
        <Product ID="Standard2019Volume">
            <Language ID="ja-jp" />
        </Product>
    </Add>
</Configuration>

Office_Setup.bat

rem Office 2019 のオフラインインストールを実行します。
rem DVDメディアにオフラインデータを書き込んでいることを想定しています。
@echo off
cls

echo.
echo 32ビット版 Office のインストールを行います。
echo.

rem 構成ファイルのテンプレートのパス
set TemplatePath=%~dp0configuration-template.xml
rem Tempフォルダに出力した構成ファイルののパス
set ConfigurationPath=%temp%\configuration.xml

rem 32ビット版を選択
set SourcePath=%~dp0Download_x86
set OfficeClientEdition=32

rem 既に構成ファイルがあれば削除
if exist %ConfigurationPath% del %ConfigurationPath%
rem テンプレートを読み込みパラメータを置き換えて
rem Tempフォルダに構成ファイルを出力する。
setlocal enabledelayedexpansion
for /f "delims=" %%a in (%TemplatePath%) do (
    set line0=%%a
    set line1=!line0:$SourcePath$=%SourcePath%!
    set line2=!line1:$OfficeClientEdition$=%OfficeClientEdition%!
    echo !line2!>>%ConfigurationPath%
)
endlocal

rem setup.exeを実行
start %~dp0setup.exe /configure %ConfigurationPath%

作成した2つのファイルとダウンロードしたインストール用データをDVDメディア等に書き込む。

• Download_x86
• Office_Setup.bat
• configuration-template.xml
• setup.exe

オフラインインストールの実行

DVDメディア等に書き込んだOffice_Setup.batを実行するだけ。