ftp接続してカレントへダウンロードするbatファイル

ftpコマンドに-iを付与してあげると、インタラクティブモードがオフとなり、複数のファイルを対話することなく送受信できるようです。

@echo off
echo  **********************************
echo  FTP接続後バイナリでカレントへダウンロードする
echo  **********************************
echo;

rem 本batの起動ディレクトリをカレントにします
cd /d %~dp0

rem ********************************************
rem  変数（ホスト毎に変更が必要です。）
rem ********************************************
set FTPSERVER=ホスト名 or IP
set ID=ユーザ名
set PASS=パスワード
set DIR=/tmp
set DLFILE=*.csv
rem ********************************************

set FTPTEXT=ftp.txt

echo open %FTPSERVER% >> %FTPTEXT%
echo %ID%>> %FTPTEXT%
echo %PASS%>> %FTPTEXT%
echo bin >> %FTPTEXT%
echo cd %DIR% >> %FTPTEXT%
echo ls -ltr >> %FTPTEXT%
echo mget %DLFILE% >> %FTPTEXT%
echo bye >> %FTPTEXT%

echo  FTP接続を開始します
rem  ※補足
rem    -i でインタラクティブモードがオフとなり、
rem    対話することなく、ファイルの送受信が可能
echo;
ftp -i -s:%FTPTEXT%

echo;
echo;
echo ↓↓ダウンロードされたファイルは以下となります↓↓
echo;
echo;

dir /a:-d %DLFILE%

@echo on
del %FTPTEXT%

@echo off
echo;
echo ********************************************
echo FTPの接続情報テキストを削除しました
echo ********************************************
echo;

pause