ﾀﾞｧ ｼｴﾘｲｪｽなライブラリをつかって、みんなでﾀﾞｧしたい。

TongChangさんからバトンを引き継ぎまして、IoTLT Advent Calendar 2017の6日目を担当いたします、ポキオです。こんにちは。

人生初のアドベントカレンダー参加、そして人生初のQiitaへの書き込みということで、右も左もわかりませんが、生暖かい目で見守って頂けると幸いです。

がじぇるね賞をいただきました！
ありがとうございました！#iotlt pic.twitter.com/8Xul5wcMpo

— ポキオ (@pokiiio) September 14, 2016

初めてIoTLTで登壇したのが、1年以上前のvol.19（＠三菱総研）でした。その時から京急ネタで色々やらせていただいてきました。今回のアドベントカレンダーも京急ネタでやらせていただいてきます（笑）

京急なライブラリとは

前置きがかなり長くなりましたが、今回のネタはESP8266（Arduino）で使える「京急なライブラリ」です。

ESP8266Keikyu
https://github.com/pokiiio/ESP8266Keikyu

このライブラリを使うと、京急の運行状況が簡単に確認できるという神がかったものに仕上がっています。「なかなかIoTはハードルが高い」「わたしも京急がすき」「ﾀﾞｧなガジェットが作りたい」というひとにぴったりなライブラリとなっています。（そんな人いるのか？）

なにができるのか

上記ライブラリをインストールしたあとに、ESP8266向けのArdunoスケッチ上で、

#include <ESP8266Keikyu.h>

こんな感じでincludeしてあげます。そして、Wi-Fiが使える状態（インターネット接続可能なアクセスポイントに接続済み）で、

int keikyuStatus = Keikyu.getStatus();

この関数を呼ぶと、京急の運行状況がわかるというものです。

このステータスの詳細は以下のようになってます。

#define KEIKYU_STATUS_UNKNOWN 0           // 京急の運行情報が取得できません
#define KEIKYU_STATUS_NORMAL 1            // 京急は平常通り運転してます
#define KEIKYU_STATUS_DELAYED 2           // 遅れています
#define KEIKYU_STATUS_TERRIBLE 3          // ダイヤが乱れています
#define KEIKYU_STATUS_STOPPED 4           // 運転を見合わせています
#define KEIKYU_STATUS_DELAYED_DUE_TO_JR 5 // JRからの振替輸送受託のため遅れています

こんな感じで、ちょっと細かめにステータスを分けています。特に、KEIKYU_STATUS_DELAYED_DUE_TO_JRのケースはなんとも切ない気分になるので、敢えて分けています（笑）

このステータスによって、LEDチカさせたりすれば、簡単に京急遅延監視ガジェットが作れます。ページの最後に、サンプルコードも用意しています、もしご興味があれば、作ってみて下さい。

ごめんなさい案件

もちろん、いろいろと制約はあります。

• ESP8266用です。 ESP32などには使えません。 ESP32用も作りました！
• 京急専用です。他社線には対応していません。
• どこで遅延が発生しているのかはわかりません。
• 京急の運行情報ページをパースしている関係上、ページ構成が変更になると正しく情報を取得できない可能性があります。
• 京急の運行情報ページをパースしている関係上、あまり短いインターバルで関数をコールしないで下さい。サーバーに負担がかかってしまいます。

あまり目くじらを立てずに使って頂けると助かります。ご意見などはいつでも歓迎です。

本当はJRも好きなんですよ

今回も鉄分高めな内容でしたが、生活と切って切り離せない鉄道をIoTでより身近に感じられると、もしかしたらハッピーになれることもあるかも？遅延監視ガジェットだけでなく、色んなネタにも今後チャレンジしていきますので、乞うご期待下さい。

あしたは、多方面で活躍されているtseigoさんです！
どんなネタなのか気になります！

Appendix

ESPr Developerにマイコン内蔵RGB LEDを接続して、運行状況に応じてLEDを光らせるサンプルコードです。

ESP8266 core for Arduinoがすでにインストールされている状態を想定しています。また、以下のライブラリも使用しています。

• Adafruit NeoPixel Library：LEDの制御に必要
• EmotionalBlink：LEDをじんわり点滅させたり、パリピ点滅をするために使用

#include <ESP8266WiFi.h>
#include <Adafruit_NeoPixel.h>
#include <EmotionalBlink.h>
#include <ESP8266Keikyu.h>

#define SSID "pokio" // アクセスポイントのSSID
#define PASSWORD "inkeikyuwetrust" // アクセスポイントのパスワード
#define INTERVAL_SEC 10 * 60 // 運行情報を確認する間隔：10分
#define PIN 4 // マイコン内蔵RGB LEDの信号線を繋いだピン番号：4番ピン
#define NUMLED 1 // マイコン内蔵RGB LEDの個数：今回は1個

// NeoPixel（LED）の宣言
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMLED, PIN, NEO_RGB + NEO_KHZ800);

// 京急の運行情報を保持しておく変数
int keikyuStatus = KEIKYU_STATUS_UNKNOWN;

void setup() {
  // Serialの初期化
  Serial.begin(115200);
  Serial.println("");

  // NeoPixelの初期化
  pixels.begin();
}

void loop() {
  // Wi-Fi接続
  connectWifi();

  // 情報取得
  keikyuStatus = Keikyu.getStatus();

  // Wi-Fi切断
  disconnectWifi();

  // 運行情報に基いてLEDを光らせる
  blinkLed();
}

void connectWifi() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(SSID, PASSWORD);

  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    // Wi-Fi接続試行中は白い点滅
    Blink.softly(&pixels, NUMLED, 255, 255, 255);
  }

  Serial.println("connected!");
}

void disconnectWifi() {
  WiFi.disconnect();
  Serial.println("disconnected!");
}

void blinkLed() {
  if (keikyuStatus == KEIKYU_STATUS_DELAYED_DUE_TO_JR) {
    // 振替輸送受託が理由で遅延している場合は、パリピ点滅
    Blink.likePartyPeople(&pixels, NUMLED, INTERVAL_SEC * 1000);
    return;
  }

  int r, g, b;

  switch (keikyuStatus) {
    case KEIKYU_STATUS_UNKNOWN:
    case KEIKYU_STATUS_NORMAL:
      // 情報取得エラー・平常運転時は光らせない
      r = 0;
      g = 0;
      b = 0;
      break;
    case KEIKYU_STATUS_DELAYED:
      // 多少の遅れは黄色く光らせる
      r = 255;
      g = 255;
      b = 0;
      break;
    case KEIKYU_STATUS_TERRIBLE:
      // 大幅なダイヤ乱れはオレンジ色に光らせる
      r = 255;
      g = 128;
      b = 0;
      break;
    case KEIKYU_STATUS_STOPPED:
      // 運転見合わせ時は赤い点滅
      r = 255;
      g = 0;
      b = 0;
      break;
  }

  for (int i = 0; i < INTERVAL_SEC; i++) {
    Blink.softly(&pixels, NUMLED, r, g, b);
  }
}

💩