tcsh設定ファイル

.cshrc

# $FreeBSD: src/share/skel/dot.cshrc,v 1.13 2001/01/10 17:35:28 archie Exp $
# Last Modified: 2006/11/07 (Tue) 17:24:30 JST by Shigeyuki Osada
# Information-tag: /usr/home/osada_ns/.cshrc
#
# .cshrc - csh resource script, read at beginning of execution by each shell
#
# see also csh(1), environ(7).
#

alias h     history 25
alias j     jobs -l
alias la    ls -a
alias lf    ls -A
alias ll    ls -lA
alias a     ./a.out
alias e         emacs

## normal ls (FreeBSD6.0R)
#alias ls   ls -G
## GNUls (requires gnuls: /usr/ports/misc/gnuls)
alias ls    gnuls --color=auto

alias c2ps      c2ps -X Ryumin-Light-EUC-H -b -d 0.5
alias less      jless
alias psd       pushd
alias ppd       popd

# A righteous umask
umask 22

# 'rm *' check
set rmstar

#TAB using
set autolist

# color complete
set color

# filtering .o ~ .aux .log
set fignore = (.o \~ .aux .log)

set path = (/sbin /bin /usr/sbin /usr/bin /usr/games /usr/local/sbin /usr/local/bin /usr/X11R6/bin $HOME/bin /usr/home/osada_ns/ns-allinone-2.28/bin)

setenv  EDITOR  vi
setenv  PAGER   jless
setenv  BLOCKSIZE   K
setenv  LANG    ja_JP.eucJP
setenv  JSERVER localhost 
#setenv  XMODIFIERS      @im=kinput2
setenv  XMODIFIERS      @im=SCIM
if( $TERM == 'kterm' ) then
     setenv TERM kterm-color
else if ( $TERM == 'xterm' ) then
     setenv TERM xterm-color
else if ( $TERM == 'Eterm' ) then
     setenv TERM kterm-color
endif



# Remove Beep
set nobeep

# Dont make .core
limit coredumpsize 0

if ($?prompt) then
    # An interactive shell -- set some stuff up
    set filec
    set history = 100
    set savehist = 100
    set mail = (/var/mail/$USER)
    if ( $?tcsh ) then
        bindkey "^W" backward-delete-word
        bindkey -k up history-search-backward
        bindkey -k down history-search-forward
    endif
endif
#set prompt='[ %{\e[33m%d %w %D %T %Y\e[00m%} ] %{\e[32m%~\e[00m%}\e[00m \
#%n@%m<%h>%'
set prompt='[ %{\e[33m%d %w %D %T %Y\e[00m%} ] %{\e[32m%~\e[00m%} \
%n@%m<%h>%'
# printf "\033[33;41;04mABC\033[00m\n"
# set prompt = '%n@%m\%'
# set prompt = '%n@%m:%~%# '

#
# [[[ Complete (for tcsh only) ]]]
#
if ( $?tcsh ) then
    set hostnames = ( node1.loacl \
                      node2.local)
    uncomplete *
    complete env     'p/1/e/='
    complete {un,}setenv     'p/1/e/'
    complete {un,}set     'p/1/s/'
    complete unalias     'p/1/a/'
    complete cd     'p/1/d/'
    complete psd     'p/1/d/'
    complete {sudo,strace,which,where}  'p/1/c/'
    complete man     'p/*/c/'
    complete kill     'c/-/`kill -l`/'
    complete killall     'c/-/`kill -l`/' 'p/*/c/'
    complete gunzip     'n/*/f:*.{gz,Z}/'
    complete umcompress     'n/*/f:*.Z/'
    complete *tex     'n/*/f:*.{tex,TEX}/'
    complete {dvi*,xdvi}     'n/*/f:*.{dvi,DVI}/'
    complete ps{nup,select}  'n/*/f:*.{ps,PS}/'
    complete {gv,ghostview}  'n/*/f:*.{ps,eps,PS,pdf,PDF}/'
    complete acroread     'n/*/f:*.{pdf,PDF}/'
    complete tar     'n/*f/f:*.{tar.z,tar.Z,tar.gz,tgz,tar}/'
    complete idraw     'n/*/f:*.{eps,EPS}/'
    complete {pix,bit}map    'n/*/f:*.{xpm,XPM,xbm,XBM,h,H}/'
    complete {x11,free}amp   'n/*/f:*.{mp3,MP3}/'
    complete xhost     'c/*{+,-}/$hostnames/'\
                             'p/*/$hostnames/'
    complete {finger,[M,m]ail} 'c/*@/$hostnames/' 'p/1/u/@'
    complete [r,s]{sh,login} 'c/*@/$hostnames/' \
                             'n/-l/u/' 'C/*/$hostnames/' 
    complete [r,s]{cp}       'c/*@/$hostnames/:' 'n/-l/u/'
    complete {nslookup,host,telnet,ping,traceroute}\
                             'p/*/$hostnames/'
    complete *ftp     'p/*/$hostnames/'
    complete vncviewer     'p/1/$hostnames/:'
    complete make     'p/1/(all clean distclean depend \
                install install.man Makefiles)/'
endif