黒電話のダイヤル検出

Last updated at 2024-09-07Posted at 2024-09-01

概要

黒電話のダイヤルがパルス計測で番号の判別ができることを知り、すぐに中古の黒電話を買いました。
黒電話のダイヤル検出の仕組みと開発したアプリについて説明します。

ダイヤル検出の仕組み

開発環境

黒電話
M5 Atom S3
アプリ
- Android Studio
- Flutter 3.19.6

※GPIOを搭載したデバイス(M5Stackシリーズ、ラズパイなど)何でも良い。

システム構成図

黒電話の信号線の加工

電話線(2線)の被覆を剥がして、GPIOの信号へ入力できるようにジャンパー線にハンダします。

受話器状態とダイヤル検出

M5 Atom S3は電話の2線からHigh/Lowを監視します。(ActiveLow)
受話器を上げると信号がLowになります。
ダイヤルを回します。
- 番号に応じて出力されるパルス(約20msec)を計測します。
- 1は1パルス、2は2パルス... 9はパルス
- 0は例外で10パルス
受話器を置くとHighになります。
- パルス計測と区別するため、50msec以上Highが継続した場合、受話器を置いたと判断します。

配線

M5 Atom S3では以下のように配線します。
赤い線 <-> GND
白い線 <-> G7

ソースコード

受話器の上げた・置いたとダイヤルの検出を抜粋しています。
M5 Atom S3で動作確認していますが、他のデバイスではヘッダーなどの変更が必要かもしれません。

#include <M5Unified.h>

// for measure
int inPin1 = 7;   // 未使用
int inPin2 = 8;   // INPUT

int countState = 0;    // パルスカウント状態
int totalValue = 0;    // パルス合計=数字

unsigned long timeStart = 0;
unsigned long timeEnd = 0;
unsigned long timeHigh = 0;
unsigned long timeLow = 0;
bool loopFlag = true;

void setup() {
  auto cfg = M5.config();
  M5.begin(cfg);
  Serial.begin(115200);
  pinMode(inPin1, INPUT_PULLUP);
  pinMode(inPin2, INPUT_PULLUP);
}

void loop() {
  // countState
  // 0: High待ち
  // 1: Low待ち
  if (digitalRead(inPin2) == LOW) {
    // 受話器を上げた
    countState = 0;
    totalValue = 0;
    timeHigh = 0;
    timeLow = millis();
    loopFlag = true;
    while(loopFlag) {
      int state = digitalRead(inPin2);
      switch (state) {
      case HIGH:
        switch (countState) {
        case 0:
          // パルス開始 or 受話器を置くとHighになるので検出開始
          countState = 1;
          timeHigh = millis();
          break;
        case 1:
          // 一定時間Highならば受話器を置いたと判断
          if ((millis() - timeHigh) > 100) {
            countState = 0;
            loopFlag = false;
          }
          break;
        }
        break;
      case LOW:
        switch (countState) {
        case 0:
          // Lowが続いたら数字確定
          if (timeHigh > 0 && (millis() - timeLow) > 100) {
            Serial.println(totalValue);
            timeLow = millis();

            // init
            totalValue = 0;
            timeHigh = 0;
          }
          break;
        case 1:
          timeLow = millis();
          // Highが一定時間継続していたら数字のパルスと判断
          if ((millis() - timeHigh) > 20) {
            totalValue++;
            if (totalValue == 10) {
              totalValue= 0;
            }
          }
          countState = 0;
          break;
        }
        break;
      }
    }
  }
}