ESP8266で電子工作練習、「Milkcocoa Hardware」を作ってみた

Posted at 2015-12-21

Milkcocoaのサイトとかを作っている者です。

電子工作の練習がてら、Milkcocoaの基本のAPI（push()、send()、on()）が使えるハードウェアを試作しました。

milkcocoa.datastore().send() https://t.co/c0iJN6VaQW
— kiyopikko (@kiyopikko) 2015, 12月 10

milkcocoa.datastore().on() https://t.co/o5Dsmjxz2Y
— kiyopikko (@kiyopikko) 2015, 12月 10

※参考：APIの説明は省きますが、ざっくり以下みたいな感じです。

機能

見た目の割に出来ることは相当しょぼいです。

pushかsendを選択できる
0〜3の範囲でカウントした数字をPublishする
Subscribeして、来た数字を表示する

GPIO割り当て

(MODE切り替え兼用のものを除いて)6本あるGPIOを以下のように割り当てました。（ピン配置参考：https://tech-blog.cerevo.com/archives/859/ ）

INPUT

IO4, IO5：2bitで0〜3の値読み取り
IO14：LOWになったらPublishする
IO12：LOWの間だけSubscribeのコールバックを呼ぶ
IO16：push(LOW), send(HIGH)の切り替え

OUTPUT

IO13：カウンタの入力につないで、来た値の回数だけカウンタをカウント(LOW&HIGHのセットを送る)する

プログラム

#include <ESP8266WiFi.h>
#include <Milkcocoa.h>

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "...SSID..."
#define WLAN_PASS       "...PASS..."


/************************* Your Milkcocoa Setup *********************************/

#define MILKCOCOA_APP_ID             "...Your_Milkcocoa_app_id..."
#define MILKCOCOA_DATASTORE_PUSH     "esp8266/push"
#define MILKCOCOA_DATASTORE_ONPUSH   "esp8266/onpush"
#define MILKCOCOA_DATASTORE_SEND     "esp8266/send"
#define MILKCOCOA_DATASTORE_ONSEND   "esp8266/onsend"


/************* Milkcocoa Setup (you don't need to change this!) ******************/

#define MILKCOCOA_SERVERPORT  1883

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;

const char MQTT_SERVER[] PROGMEM    = MILKCOCOA_APP_ID ".mlkcca.com";
const char MQTT_CLIENTID[] PROGMEM  = __TIME__ MILKCOCOA_APP_ID;

Milkcocoa milkcocoa = Milkcocoa(&client, MQTT_SERVER, MILKCOCOA_SERVERPORT, MILKCOCOA_APP_ID, MQTT_CLIENTID);


/************************* PIN Number *********************************/

#define PUBLISH_PIN        14
#define SUBSCRIBE_PIN      12

#define ON_VALUE_PIN       13

#define PUBLISH_VALUE_PIN1  4
#define PUBLISH_VALUE_PIN2  5

#define CHANGE_MODE_PIN    16


void setup() {
  Serial.begin(115200);
  delay(10);

  Serial.println(F("Milkcocoa SDK demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  pinMode(PUBLISH_PIN, INPUT);
  pinMode(SUBSCRIBE_PIN, INPUT);
  pinMode(PUBLISH_VALUE_PIN1, INPUT);
  pinMode(PUBLISH_VALUE_PIN2, INPUT);
  pinMode(CHANGE_MODE_PIN, INPUT);

  pinMode(ON_VALUE_PIN, OUTPUT);

  Serial.println( milkcocoa.on(MILKCOCOA_DATASTORE_ONPUSH, "push", onCallback) );
  Serial.println( milkcocoa.on(MILKCOCOA_DATASTORE_ONSEND, "send", onCallback) );
};

void loop() {
  milkcocoa.loop();

  /* set publish value */
  DataElement elem = DataElement();

  int val = digitalRead(PUBLISH_VALUE_PIN1) + digitalRead(PUBLISH_VALUE_PIN2)*2;
  elem.setValue("v", val);
  Serial.println(String(val));

  /* change mode */
  int apimode; 
  apimode = digitalRead(CHANGE_MODE_PIN);
  
  /* publish */
  if(digitalRead(PUBLISH_PIN) == LOW)
    triggerAPI(apimode, elem);
      
  delay(20);
};

void triggerAPI(int apimode, DataElement elem) {
  
  Serial.println("publish");
  
  if(apimode == LOW)
    milkcocoa.push(MILKCOCOA_DATASTORE_PUSH, elem);
  else
    milkcocoa.send(MILKCOCOA_DATASTORE_SEND, elem);

  delay(3000);
  
  Serial.println("publish finish");
};

void onCallback(DataElement elem) {
  Serial.println("onCallback");
  if(digitalRead(SUBSCRIBE_PIN) == LOW){
    int val = elem.getInt("v");

    // データが来たことを知らせるLEDを光らせるためのHIGH
    digitalWrite(ON_VALUE_PIN, HIGH);
    delay(200);

    // 0だったら1週させる
    if(val==0) val = 4;

    // 値の回数だけHIGHとLOWを送る
    for (int i = 0; i < val; i ++)
    {
      if(i!=0)
        digitalWrite(ON_VALUE_PIN, HIGH);
        
      delay(1);
      digitalWrite(ON_VALUE_PIN, LOW);
      delay(1);
    };
  }
};