ESP8266で電子工作練習、「Milkcocoa Hardware」を作ってみた

  • 18
    Like
  • 0
    Comment
More than 1 year has passed since last update.

Milkcocoaのサイトとかを作っている者です。

電子工作の練習がてら、Milkcocoaの基本のAPI(push()send()on())が使えるハードウェアを試作しました。

※参考:APIの説明は省きますが、ざっくり以下みたいな感じです。

機能

見た目の割に出来ることは相当しょぼいです。

  • pushsendを選択できる
  • 0〜3の範囲でカウントした数字をPublishする
  • Subscribeして、来た数字を表示する

esp8266-qiita.png

GPIO割り当て

(MODE切り替え兼用のものを除いて)6本あるGPIOを以下のように割り当てました。(ピン配置参考:https://tech-blog.cerevo.com/archives/859/

INPUT

  • IO4, IO5:2bitで0〜3の値読み取り
  • IO14LOWになったらPublishする
  • IO12LOWの間だけSubscribeのコールバックを呼ぶ
  • IO16push(LOW), send(HIGH)の切り替え

OUTPUT

  • IO13:カウンタの入力につないで、来た値の回数だけカウンタをカウント(LOW&HIGHのセットを送る)する

プログラム

#include <ESP8266WiFi.h>
#include <Milkcocoa.h>

/************************* WiFi Access Point *********************************/

#define WLAN_SSID       "...SSID..."
#define WLAN_PASS       "...PASS..."


/************************* Your Milkcocoa Setup *********************************/

#define MILKCOCOA_APP_ID             "...Your_Milkcocoa_app_id..."
#define MILKCOCOA_DATASTORE_PUSH     "esp8266/push"
#define MILKCOCOA_DATASTORE_ONPUSH   "esp8266/onpush"
#define MILKCOCOA_DATASTORE_SEND     "esp8266/send"
#define MILKCOCOA_DATASTORE_ONSEND   "esp8266/onsend"


/************* Milkcocoa Setup (you don't need to change this!) ******************/

#define MILKCOCOA_SERVERPORT  1883

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;

const char MQTT_SERVER[] PROGMEM    = MILKCOCOA_APP_ID ".mlkcca.com";
const char MQTT_CLIENTID[] PROGMEM  = __TIME__ MILKCOCOA_APP_ID;

Milkcocoa milkcocoa = Milkcocoa(&client, MQTT_SERVER, MILKCOCOA_SERVERPORT, MILKCOCOA_APP_ID, MQTT_CLIENTID);


/************************* PIN Number *********************************/

#define PUBLISH_PIN        14
#define SUBSCRIBE_PIN      12

#define ON_VALUE_PIN       13

#define PUBLISH_VALUE_PIN1  4
#define PUBLISH_VALUE_PIN2  5

#define CHANGE_MODE_PIN    16


void setup() {
  Serial.begin(115200);
  delay(10);

  Serial.println(F("Milkcocoa SDK demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  pinMode(PUBLISH_PIN, INPUT);
  pinMode(SUBSCRIBE_PIN, INPUT);
  pinMode(PUBLISH_VALUE_PIN1, INPUT);
  pinMode(PUBLISH_VALUE_PIN2, INPUT);
  pinMode(CHANGE_MODE_PIN, INPUT);

  pinMode(ON_VALUE_PIN, OUTPUT);

  Serial.println( milkcocoa.on(MILKCOCOA_DATASTORE_ONPUSH, "push", onCallback) );
  Serial.println( milkcocoa.on(MILKCOCOA_DATASTORE_ONSEND, "send", onCallback) );
};

void loop() {
  milkcocoa.loop();

  /* set publish value */
  DataElement elem = DataElement();

  int val = digitalRead(PUBLISH_VALUE_PIN1) + digitalRead(PUBLISH_VALUE_PIN2)*2;
  elem.setValue("v", val);
  Serial.println(String(val));

  /* change mode */
  int apimode; 
  apimode = digitalRead(CHANGE_MODE_PIN);

  /* publish */
  if(digitalRead(PUBLISH_PIN) == LOW)
    triggerAPI(apimode, elem);

  delay(20);
};

void triggerAPI(int apimode, DataElement elem) {

  Serial.println("publish");

  if(apimode == LOW)
    milkcocoa.push(MILKCOCOA_DATASTORE_PUSH, elem);
  else
    milkcocoa.send(MILKCOCOA_DATASTORE_SEND, elem);

  delay(3000);

  Serial.println("publish finish");
};

void onCallback(DataElement elem) {
  Serial.println("onCallback");
  if(digitalRead(SUBSCRIBE_PIN) == LOW){
    int val = elem.getInt("v");

    // データが来たことを知らせるLEDを光らせるためのHIGH
    digitalWrite(ON_VALUE_PIN, HIGH);
    delay(200);

    // 0だったら1週させる
    if(val==0) val = 4;

    // 値の回数だけHIGHとLOWを送る
    for (int i = 0; i < val; i ++)
    {
      if(i!=0)
        digitalWrite(ON_VALUE_PIN, HIGH);

      delay(1);
      digitalWrite(ON_VALUE_PIN, LOW);
      delay(1);
    };
  }
};

使った部品

通信モジュール

esp8266-qiita2.jpg

pushsendのモード切り替え部分

esp8266-qiita3.jpg

何故プルアップ抵抗が必要かについてはこちら。

Publish、Subscribe部分

  • タクトスイッチ:2個
  • 10kΩ抵抗(プルアップ用):2個
  • LED&100Ω抵抗(写真載せ忘れました):各1個

esp8266-qiita4-mod.jpg

数字カウント部分

7セグ周り

esp8266-qiita5-mod.jpg

カウンタ

esp8266-qiita6.jpg

カウンタの入力部分

  • OR回路(74HC32)(ESP側の出力とシュミットトリガの出力をショートさせない用):1個

esp8266-qiita7.jpg

何故ロジックICの出力をショートさせたらだめかについてはこちら

カウンタ入力のチャタリング対策部分

  • 0.1μF0.47μF積層セラミックコンデンサ(チャタリング平滑用、1つでも良いですが私の場合1つじゃ安定しなかったので2つ使ってます):各1個
  • 2.2kΩ、22kΩ抵抗(プルアップ用、コンデンサの電流制御用):各1個
  • タクトスイッチ(カウント用):1個
  • シュミットトリガ(74HC14)(中間値取らない用):1個

esp8266-qiita8.jpg

チャタリングについてはこちら

回路図

厳密な回路図じゃなくて、ざっくりイメージ伝える系の回路図です。

esp8266-qiita9-01-01.png

esp8266-qiita9-01-02.png

感想

思い描いたものが実際に動くと大変面白かったです。2日目の方もおっしゃっていましたが、ボタンをカチカチするのは楽しいです。無駄に押してしまいます。

あと、テスターが最高に頼もしかったです。電子工作は「何が起こってるのがわからない」っていう怖さがあるので、そこが明らかになるのはとても安心できます。

次はユニバーサル基板で出来るだけコンパクトにしたいと作れたらとか思っています。

用途としては4択のアンケート回答とかでしょうか。Milkcocoaに保存もできるので集計も楽です。
また4択ということで、実際にやっちゃうとアウトですが、見せ方を時計っぽく作ったらマークシート式の緩いテストならインターネット越しのカンニングマシンとして使えるかもとか妄想しました。

電子工作の勉強で参考になったものとか

Make: Electronics ―作ってわかる電気と電子回路の基礎 ((Make:PROJECTS))

これに尽きました(2日前にはてなの人もおすすめしてましたね)。これを1章から順番に必要なものを買って工作していくのが一番勉強になると思います。

少し前に話題になったクックパッドのCTOさんの記事を見ると必要な道具の多さに面食らう&一気に全部買ったとしても何のこっちゃわからないと思うので、段階的に買って学び進めていくとわかりやすいと思います(と言いつつ、送料で結構損した気がしますが)。

頭だけで理解するより手を動かした方が10倍理解しやすいです。

剣菱P零からの電子工作(ニコ動)

Make: Electronicsと並行して見ていくとすごく理解できます。この動画があったからこの試作品が作れたと言っても過言ではないです。

説明不要の必修科目です。

始める電子回路

古い感じのサイトですが、とても丁寧でわかりやすいサイトです。私の謎だった部分に答えてくれていました。

データシート

参考になるとかじゃなくて、読めないと始まらない類いのものなんですが。

LEDだってデータシートを読まないと何mAまで流して良いとか何V電圧が落ちるのかがわからないので、読める(どこを見れば良いかわかっている)ようになっておく必要があります。

This post is the No.22 article of ESP8266 Advent Calendar 2015