Photoshopの言語モードを切り替える

バッチファイル

Switch-Photoshop-language-mode.bat

@echo off
set PHOTOSHOP_DIR=%ProgramFiles%\Adobe\Adobe Photoshop CC 2015.5
if not exist "%PHOTOSHOP_DIR%\" (
  echo %PHOTOSHOP_DIR% is not found.
  pause
  exit /b -1
)

if exist "%PHOTOSHOP_DIR%\Locales\ja_JP\Support Files\tw10428.dat" (
  set CURRENT_LANG=Japanese
  set SWITCHED_LANG=English
) else if exist "%PHOTOSHOP_DIR%\Locales\ja_JP\Support Files\tw10428.dat.bak" (
  set CURRENT_LANG=English
  set SWITCHED_LANG=Japanese
) else (
  echo Cannot understand currently Photoshop language mode.
  pause
  exit /b -1
)

echo Currently Photoshop language mode is %CURRENT_LANG%.
echo.
echo Press any key to switch to %SWITCHED_LANG%.
pause

if exist "%PHOTOSHOP_DIR%\Locales\ja_JP\Support Files\tw10428.dat" (
  rename "%PHOTOSHOP_DIR%\Locales\ja_JP\Support Files\tw10428.dat" tw10428.dat.bak
) else if exist "%PHOTOSHOP_DIR%\Locales\ja_JP\Support Files\tw10428.dat.bak" (
  rename "%PHOTOSHOP_DIR%\Locales\ja_JP\Support Files\tw10428.dat.bak" tw10428.dat
) else (
  echo Failure to switch Photoshop language mode.
  pause
  exit /b -1
)

exit /b 0

実行するとこんな感じ

Currently Photoshop language mode is Japanese.

Press any key to switch to English.
続行するには何かキーを押してください . . .

実行するたび、日本語と英語感を相互に切り替えます。

動作確認

• Windows 10.0.10586
• Adobe Photoshop 2015.5リリース 日本語版
  • PHOTOSHOP_DIRのフォルダ名を置き換えれば、次が出ても使えるかも？

参考

大変重宝しております、有り難うございます！

• photoshopを英語版で起動する方法(macの場合)
  http://qiita.com/tsukishimaao/items/470f361babd3569371bd

以上