【Delphi】DBGrid のバグを回避する

Last updated at 2024-10-10Posted at 2024-10-08

はじめに

個人的には DBGrid をあまり使わないので気付かなかったのですが、DBGrid には長い間バグが存在したようです。この問題は 『Delphi 10.1 Berlin』 以前のバージョンで発生します。

DBGrid のバグ

バグの再現方法と回避方法です。

再現方法

まず、何でもいいので DBGrid にデータを表示させます。

テストとして ADO で接続するようにしてみました。データは %ProgramFiles%\Common Files\Borland Shared\Data の dbdemos.mdb を使いました。

Button1 と Button2 をクリックした時のイベントハンドラにこんな感じで記述します。

procedure TForm1.Button1Click(Sender: TObject);
begin
  ADOQuery1.Close;
  ADOQuery1.SQL.Text := 'select * from country';
  ADOQuery1.Open;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  ADOQuery1.Close;
  ADOQuery1.SQL.Text := 'select * from country where Population < 0';
  ADOQuery1.Open;
end;

Button1 を押すと全件表示され、

Button2 を押すと 0 件になります。

もう一度 Button1 を押すと再度全件表示されます。

では次に、横スクロールバーが出ないようにフィールドを絞ってみます。Button1 と Button2 をクリックした時のイベントハンドラはこんな感じになります。

procedure TForm1.Button1Click(Sender: TObject);
begin
  ADOQuery1.Close;
  ADOQuery1.SQL.Text := 'select Name, Population from country';
  ADOQuery1.Open;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  ADOQuery1.Close;
  ADOQuery1.SQL.Text := 'select Name, Population from country where Population < 0';
  ADOQuery1.Open;
end;

先程と同様に実行してみます。Button1 を押すと全件表示され、

Button2 を押すと 0 件になります。

もう一度 Button1 を押すと再度全件表示されますが、ここでバグが発生します。

縦スクロールバーが表示されていませんよね？

回避方法

この問題を回避するには、横スクロールバーを表示させるようにするか、強制的に縦スクロールバーを表示させます。

強制的に縦スクロールバーを表示させるのには ShowScrollBar() API を使います。

  ShowScrollBar(DBGrid1.Handle, SB_VERT, True);

See also:

ShowScrollBar 関数 (winuser.h) (learn.microsoft.com)

インターポーザークラスを使った回避方法

インターポーザークラスを使って回避するのが簡単でしょう。以下のユニットを問題の出るプロジェクトに追加してください。

uDBGridFix.pas

unit uDBGridFix;
{$IFDEF CONDITIONALEXPRESSIONS}
  {$IF CompilerVersion >= 32.0}
    {$MESSAGE ERROR 'uDBGridFix.pas: This unit is only required for Delphi 10.1 Berlin or earlier.'}
  {$IFEND}
  {$IF CompilerVersion >= 23.0}
    {$DEFINE XE2_OR_LATER}
  {$IFEND}
{$ENDIF}

interface

uses
{$IFDEF XE2_OR_LATER}
  System.SysUtils, Vcl.DBGrids, Winapi.Windows;
{$ELSE}
  SysUtils, DBGrids, Windows;
{$ENDIF}

type
  TDBGrid = class({$IFDEF XE2_OR_LATER}Vcl.{$ENDIF}DBGrids.TDBGrid)
  protected
    procedure UpdateScrollBar; override;
  end;

implementation

{ TDBGrid }

procedure TDBGrid.UpdateScrollBar;
begin
  inherited;
  ShowScrollBar(Self.Handle, SB_VERT, True);
end;

end.