[Unity] Box Projectionで屋内シーンの反射による映り込みの品質を向上する

Last updated at 2023-04-26Posted at 2019-12-23

これは【unityプロ技】 Advent Calendar 2019の24日目の記事です。

Unity標準の ReflectionProbe のオプションにある Box Projection を設定することで、屋内シーンの反射の破綻を軽減して、映り込みの品質を向上する方法を紹介します。

百聞は一見に如かずということで、 Box ProjectionをON/OFF した動画を用意しました。

Box Projectionで屋内シーンの反射による映り込みの品質を向上する
という記事を書きました！
▶️https://t.co/gz0CpeizHb

カメラの位置を考慮して、Cubemapの映り込みの位置を正しく補正する手法です。
設定が簡単なわりに、劇的に見た目のリッチ感UPできるのでオススメです！#Unity3D #shader #HLSL pic.twitter.com/o75TDgPBL2
— がむ (@gam0022) December 23, 2019

Box Projection: OFF では、カメラの位置が無視されて、家具などの映り込みの位置がずれてしまっています。
Box Projection: ON では、カメラの位置が正しく考慮されて、家具などの映り込みの位置が正しくなっています！

環境

2018.4.13f1 (LTS)
Build-in Rendering Pipeline および LWRP（Light Weight Render Pipeline）

Box Projectionとは、どんな技術なのか？

公式マニュアルにもBox Projectionの解説はあるのですが、ちょっと初心者には理解しずらかったので、簡単に解説をします。

より高度なリフレクションプローブの機能 - Unity マニュアル

端的に言うと、Cubemap（ReflectionProbe）のテクスチャをサンプリングするための反射ベクトルの向きを、カメラの位置と部屋の広さを定義するBoundingboxを考慮して補正する手法です。

普通のCubemapとの違いは、反射ベクトルの計算の違いだけなので、GPUの処理負荷もそれほど高くはありません。

反射はしていますが、レイトレをするわけではないので、RTXも不要です！

Parallax-Corrected Cubemapの解説

※Box Projectionの理論に興味がない人は、この節はスキップして本題から読んでください。
Unity標準のStandardShaderでBox Projectionは実装済みなので、理論は理解しなくても使うことはできます。

UnityではBox Projectionという名称ですが、Parallax-Corrected Cubemap とも呼ばれる手法です。

Parallax-Corrected Cubemapの具体的な理論と実装については、このスライドに非常に詳しく解説してあります。

Parallax Corrected CubeMaps from Siggraph 2012

この図は上記のスライドから引用しました。

この図を用いて簡単にParallax-Corrected Cubemapの解説を行います。基本的な考え方はそれほど難しくはありません。

まず各記号の説明をします。

$\vec{V}$: カメラのビューベクトル
$C$: ReflectionProbeの位置
$\vec{N}$: 法線
$\vec{R}$: 反射ベクトル（補正前）
$\vec{R'}$: 反射ベクトル（補正後）
$P$: $\vec{R}$と壁の交差点

$\vec{R}$ 方向をサンプリングすれば、 普通のCubemap ですが、
$\vec{R'}$ 方向をサンプリングすると視差が考慮された Parallax-Corrected Cubemap になります。

そして、図が示すように $\vec{R}$ を補正した $\vec{R'}$ は

\vec{R'} = P - C

によって計算できます。

$C$ は既知なので、 $\vec{R}$と壁の交差点である $P$ を計算すれば、$\vec{R'}$ が求まります。

ベクトルとAABBの交差判定のアルゴリズムを用いれば、$P$ は計算ができます。

HLSLによる Parallax-Corrected Cubemap の反射ベクトル $\vec{R'}$ を求める実装例です（MITライセンス）。

// Parallax-Corrected Cubemap
// https://seblagarde.files.wordpress.com/2012/08/parallax_corrected_cubemap-siggraph2012.pdf
float3 calcParallaxCorrectedCubemapReflect(float3 worldPos, float3 worldReflect, float3 cubemapPos, float3 boxMin, float3 boxMax)
{
    // AABB と 反射ベクトル の交差点 worldIntersectPos を計算します
    float3 firstPlaneIntersect  = (boxMax - worldPos) / worldReflect;
    float3 secondPlaneIntersect = (boxMin - worldPos) / worldReflect;
    float3 furthestPlane = max(firstPlaneIntersect, secondPlaneIntersect);
    float dist = min(min(furthestPlane.x, furthestPlane.y), furthestPlane.z);
    float3 worldIntersectPos = worldPos + worldReflect * dist;

    // Cubemapから交差点に向かうベクトルが ParallaxCorrected された反射ベクトルになります
    return worldIntersectPos - cubemapPos;
}