[備忘録]VBSでファイルを増殖＆置換

・VBSでファイルを増やす
Option Explicit

Dim fso ' FileSystemObject
Set fso = WScript.CreateObject("Scripting.FileSystemObject")

Dim targetFile, afterFile
Dim beforeFolder, afterFolder
Dim beforePath, afterPathB, afterPathA
Dim startNum, endNum
Dim replaceTarget
Dim i, nowNum , objFile, fileContents, cncFlg

'入力
'targetFile = inputbox("コピー対象")
'beforeFolder = inputbox("コピー対象のパス(末尾に\をつける)")
'startNum = inputbox("開始")
'endNum = inputbox("終了")

targetFile = "" 'コピー対象
beforeFolder = "" 'コピー元フォルダ
afterFolder = "" 'コピー先フォルダ
startNum = "1"
endNum = "70"

cncflg = msgbox ("以下の内容で処理を開始。" & vbCr & _
"コピー対象 : " & targetFile & vbCr & _
"コピー元フォルダ : " & beforeFolder & vbCr & _
"コピー先フォルダ : " & afterFolder & vbCr & _
"開始番号 : " & startNum & vbCr & _
"終了番号 : " & endNum & vbCr, 1)

if cncFlg = vbCancel then
msgbox "処理を中断"
Wscript.quit
end if

'置換対象文字列
replaceTarget = "" '置換対象

'コピー元パス
beforePath = beforeFolder & targetFile

'ファイル名変更前パス
afterPathB = afterFolder & targetFile

'増殖処理beforePath
for i = startNum to endNum

'①afterフォルダに対象をコピー
fso.CopyFile beforePath, afterFolder

'②一桁の場合、二桁にする
if i <= 9 then
    nowNum = "0" & cstr(i)
else 
    nowNum = cstr(i)
end if

'③中身置換
'ファイルの中身読み込み
set objFile = fso.OpenTextFile(afterPathB)
fileContents = objFile.ReadAll
objFile.Close

'対象を置換した文字列の作成
fileContents = replace(fileContents, replaceTarget, nowNum)

'置換後中身を書き込み
set objFile = fso.createtextfile(afterPathB)
objFile.writeline(fileContents) 
objFile.Close


'③ファイル名置換
'置換後ファイル名
afterFile = replace(targetFile, replaceTarget, nowNum)
'置換後パス
afterPathA = afterFolder & afterFile

'リネーム
fso.moveFile afterPathB, afterPathA

next

msgbox "処理終了"

'オブジェクト開放
Set fso = Nothing
fileContents = ""