Android
Windows
開発環境
batch

.apk をダブルクリックしてインストール&実行

Windows環境用にバッチファイル(CMD.EXE)の機能だけで実現しました。

Android端末を開発者モードに設定する等の準備はもちろん必要です。

拡張子 .apk のファイルに関連づけて使って下さい。
バッチファイルなのでコマンドプロンプトが開きます。
あまりオシャレではないですがそこはガマン。

adbコマンドにパスが通っている事を前提としています。
不都合な場合は適当に改造して下さい。

apk_launch.bat
@echo off
setlocal enableextensions
rem adbコマンドにパスが通っているものとする。
rem set ASDK=%ANDROID_HOME%
for /f "delims=" %%i in ('where adb') do set ASDK=%%~dpi..
for /f "delims=" %%i in ('dir /b %ASDK%\build-tools') do set AVER=%%i
set PCKG=
for /f "tokens=1,2,3 delims== " %%i in ('%ASDK%\build-tools\%AVER%\aapt.exe dump xmltree %1 AndroidManifest.xml') do if not defined PCKG if %%i%%j==A:package set PCKG=%%k
echo Package = %PCKG%
echo on
adb shell am force-stop %PCKG%
adb install -r %1
@if ERRORLEVEL 1 goto :ERR
adb shell monkey -p %PCKG% -c android.intent.category.LAUNCHER 1
@timeout /t 5
@exit /b

:ERR
@pause
@exit /b 1
apk_launch.reg
Windows Registry Editor Version 5.00

[HKEY_CLASSES_ROOT\.apk\shell\Open\command]
@="C:\\Programs\\bin\\apk_launch.bat \"%1\""

※パスは適宜修正して下さい

他の記事

PCからダブルクリック一発でapkインストール(Windows)
apkをダブルクリックでAndroid実機へ転送&実行