まえがき

まだ日本語を勉強しているので、言葉の表現がうまく伝わらないかもしれません。その点ご理解をお願いします > <);

概要

最近、Imaging Edge Mobileでは何かが物足りなさがあって、ソニーのミラーレスカメラのIRリモコンのレプリカ（約500円ほど）を買いました。
- でも、残念ながら自分が持っていたa6100(ILCE-6100)ではIR端子がついてなかったので使用不能でした。
なんとか方法はないのかいろいろ探してみた結果…
- ソニーは Camera Remote API（ほぼdeprecatedですが）で、JSON RPCを使用しカメラを遠隔操作することに対するドキュメントを提供していました。
- ちょうど半年前、友達からM5Stackをもらって、そこにはWiFiモジュールが入っていたので、これを使用してみることにします。

ソースコード

ソースコードはこちらです。

#include <M5Stack.h>
#include <WiFi.h>

const char* WIFI_SSID = "DIRECT-moE1:ILCE-6100";
const char* WIFI_PASSWORD = "bdjbopYD";

const char* SERVER_IP = "192.168.122.1";
const int SERVER_PORT = 10000;

int wifiStatus = WL_IDLE_STATUS;

WiFiClient client;
auto& LCD = M5.Lcd;

void printWiFiInfo() {
  IPAddress ip = WiFi.localIP();
  LCD.print("Connected as: ");
  LCD.println(ip.toString());
}

void dumpBattery() {
  LCD.setCursor(0, 230);
  auto &Power = M5.Power;
  int8_t level = Power.getBatteryLevel();
  bool isChargeFull = Power.isChargeFull();
  bool isCharging = Power.isCharging();

  if (isChargeFull) {
    LCD.print("[charge full] ");
  } else if (isCharging) {
    LCD.print("[charging] ");
  }
  LCD.printf("battery level: %d\n", level);
  LCD.setCursor(0, 0);
}

// the setup routine runs once when M5Stack starts up
void setup(){

  // Initialize the M5Stack object
  M5.begin();

  /*
    Power chip connected to gpio21, gpio22, I2C device
    Set battery charging voltage and current
    If used battery, please call this function in your project
  */
  M5.Power.begin();
  LCD.setBrightness(10);
  LCD.println("connecting");
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
  while (wifiStatus != WL_CONNECTED) {
    wifiStatus = WiFi.status();  
    dumpBattery();
    delay(5000);
  }

  LCD.clear();
}

void sendRequest(const String& data, const int sleepAmount) {
    if (client.connect(SERVER_IP, SERVER_PORT)) {
    client.println("POST /sony/camera HTTP/1.1");
    client.print("Host: ");
    client.print(SERVER_IP);
    client.print(":");
    client.print(SERVER_PORT);
    client.println();
    client.println("User-Agent: Arduino/0.1");
    client.printf("Content-Length: %d\n", data.length());
    client.println(); 
    client.println(data);
    delay(sleepAmount);
    client.stop();
  } else {
    LCD.println("cannot establish connection!");
  }
}


void halfShutter() {
  LCD.println("acting half shutter..");
  const String data = "{ \"method\": \"actHalfPressShutter\", \"params\": [], \"id\": 1, \"version\": \"1.0\" }";
  sendRequest(data, 500);
}

void takePicture() {
  LCD.println("taking picture..");
  const String data = "{ \"method\": \"actTakePicture\", \"params\": [], \"id\": 1, \"version\": \"1.0\" }";
  sendRequest(data, 300);
}


// the loop routine runs over and over again forever
void loop() {
  M5.update();
  LCD.setCursor(0,0);
  dumpBattery();
  printWiFiInfo();
  int isButtonAPressed = M5.BtnA.isPressed();
  int isButtonBPressed = M5.BtnB.isPressed();
  int isButtonCPressed = M5.BtnC.isPressed();
  if (isButtonAPressed) {
    halfShutter();
    LCD.clear();
  } else if (isButtonBPressed) {
    halfShutter();
    takePicture();
    LCD.clear();
  } else if (isButtonCPressed) {
    takePicture();
    LCD.clear();
  }
  delay(16);
}

これを使用するためにやるべきこと

カメラのSSID, パスワードを知る

ハードウェアの特性上、SSIDどパスワードがハードコードされています。
これを自分のカメラに合わせて修正します。

韓国語メニュー基準ですのですこし違うかもしれません。

メニューに入ります。
ネットワークタブでスマートフォンで制御を選択します。
接続を選択します。
QRコードが出たらゴミ箱ボタンを押してパスワード表示に切り替えます。
接続情報をメモします。

接続情報が漏れないように気をつけてください。ソニーのカメラの遠隔制御機能は思った以上に強力すぎてハッカーの手に入ると情報が漏れたり画像が勝手に表示されたりする可能性があります。

カメラのIPアドレスを知る

この方法でカメラを操作するには、カメラのIPアドレスを知る必要があります。
ソニーのドキュメント(Development Guide)によると、以下の通りSSDP M-SEARCHメソッドを使用してカメラを探索することができるらしいですが、めんどくさいので今回は他の方法で行きたいと思います。

M-SEARCH * HTTP/1.1
HOST: 239.255.255.250:1900
MAN: "ssdp:discover"
MX: seconds to delay response (ex. MX: 1)
ST: urn:schemas-sony-com:service:ScalarWebAPI:1
USER-AGENT: OS/version product/version

まず、さっきメモしておいた接続情報通りPCで接続します。
ゲートウェイのIPを取得します。(Linuxの場合、ip routeコマンドで確認できます)
3番はありません！それがカメラのIPです！

やりたかったこと

http responseを表示したいのにresponseのreadができない


// 何も表示されない
while (client.available()) {
    print(client.read())
}

ハードコードじゃなくて、キレイにJSONオブジェクトを作りたかった…

M5Stackでソニーのミラーレスカメラのリモコン作った