[AutoHotKey]Chrome-urlsを入力する

Chrome://quitとかのChrome-urlsを簡単に入力したかった。
ホットストリングでブックマーク呼び出し的なこと。

アクティブウィンドウがChrome（系ブラウザ）なら、Ctrl+Lでアドレスバーに移動してから文字列をペーストする。
Chromeかどうかはウィンドウクラスと実行ファイル名の両方で判断する。Visual Studio CodeとかもウィンドウクラスがChrome_WidgetWin_1なので。

Chrome-urls.ahk

::cu:: ; Chrome-urls
    IfChrome()
    PasteString("Chrome://")
    Return

::cuq:: ; quit
    IfChrome()
    PasteString("Chrome://quit")
    Return

::cur:: ; restart
    IfChrome()
    PasteString("Chrome://restart")
    Return

::cuc:: ; 閲覧履歴データを消去する
    IfChrome()
    PasteString("chrome://settings/clearBrowserData")
    Return

IfChrome() {
    if ("Chrome_WidgetWin_1" = WinGetClass() and (("Chrome.exe" = WinGet_ProcessName()) or ("Kinza.exe" = WinGet_ProcessName())))
    {
        Send, ^l
    }
}
WinGetClass(WinTitle="A") {
    WinGetClass, OutputVar, %WinTitle%
    Return, OutputVar
}
WinGet_ProcessName(WinTitle="A") {
    WinGet, OutputVar, ProcessName, %WinTitle%
    Return, OutputVar
}
PasteString(String)
{
    OnClipboardChange("ClipChanged",0)
    Backup := ClipboardAll
    Clipboard := String
    Sleep, 100 ; 削除が間に合わないので
    SendPlay, ^v
    Clipboard := Backup
    OnClipboardChange("ClipChanged",1)
}