LoginSignup
3
2

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?

@cardene(かるでね)inCryptoGames株式会社

[ERC5216] 所有しているERC1155トークンの一部を他アドレスへ承認できる仕組みを理解しよう！

Last updated at Posted at 2023-09-03

はじめに

初めまして。
CryptoGamesというブロックチェーンゲーム企業でエンジニアをしている cardene（かるでね） です！
スマートコントラクトを書いたり、フロントエンド・バックエンド・インフラと幅広く触れています。

代表的なゲームはクリプトスペルズというブロックチェーンゲームです。

今回は、ERC1155規格を拡張して、より細かくトークンのapproveを実行できる提案であるERC5216についてまとめていきます！

以下にまとめられているものを翻訳・要約・補足しながらまとめていきます。

ERC5216は現在（2023年9月3日）では「Last Call」段階です。

概要

EIP1155は、同じトークンIDを持つ複数のトークンを効率的に管理する標準インターフェースを提供する企画です。

ERC1155については以下を参考にしてください。

動機

この規格では、トークンの識別子（id）と数量に基づいてより細かい承認プロセスを実行する提案がされています。
ERC1155は、ERC721の仕組みで提案されている各idに数量というデータが紐づくトークン形式です。

ERC721については以下を参考にしてください。

ERC1155については以下を参考にしてください。

ブロックチェーンでは、プログラムのエラーや悪意のある操作によって資金が永久に失われる可能性があるため、安全にトランザクションが実行される必要があります。
ERC1155は、setApprovalForAll関数を使用しており、特定のアドレスが保有するidのトークンを一括してapproveします。

setApprovalForAll関数は、所有者が特定のアドレス（オペレーター）に対して、自分のトークンの操作権限を一括で与える関数です。

例えば、NFT（Non-Fungible Token）の所有者である「Alice」が、NFTマーケットプレイスの「Opensea」に自分のトークンを出品したいとします。
この場合、Aliceは setApprovalForAll関数を使用して、Openseaに対して自分のNFTを操作する権限を与えることができます。

// NFTの所有者
address public owner = msg.sender;

// NFTマーケットプレイスのアドレス
address public marketplace = 0x...; // ダミーアドレス

// NFTのトークンID
uint256 public tokenId = 123;

// Marketplaceに対してトークンの操作権限を一括で与える
function grantPermissionToMarketplace() public {
    // ownerがmarketplaceに対して操作権限を一括で与える
    approve(marketplace, true);
}

// 操作権限を取り消す
function revokePermissionFromMarketplace() public {
    // ownerがmarketplaceに対して操作権限を取り消す
    approve(marketplace, false);
}

// アドレスに対して操作権限を一括で与える関数
function approve(address operator, bool approval) private {
    // ERC-1155のsetApprovalForAll関数を呼び出す
    IERC1155(tokenContractAddress).setApprovalForAll(operator, approval);
}

上記の例では、Aliceは自分のNFTをOpenseaに出品するために、grantPermissionToMarketplace関数を呼び出し、Openseaに対して操作権限を一括で与えます。
その後、NFTが売却される時に、OpenseaはAliceの操作権限を使用してトークンを移動できます。
不要になった場合、Aliceは revokePermissionFromMarketplace関数を呼び出すことで、Openseaに対する操作権限を取り消すことができます。

しかし、この方法では最低限の信頼性を確保するには不足しています。
この提案では、ERC20とERC721のアイデアを組み合わせて、所有者がマーケットプレイスなどの第三者に対して、特定のidに対して指定された数のトークンをapproveする仕組みを提案しています。

ERC20については以下を参考にしてください。

仕様

このEIPを使用するコントラクトは、IERC1155ApprovalByAmountインタフェースを実装する必要があります。

インターフェース実装

/**
 * @title ERC-1155 Approval By Amount Extension
 * Note: the ERC-165 identifier for this interface is 0x1be07d74
 */
interface IERC1155ApprovalByAmount is IERC1155 {

    /**
     * @notice Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `id` and with an amount: `amount`.
     */
    event ApprovalByAmount(address indexed account, address indexed operator, uint256 id, uint256 amount);

    /**
     * @notice Grants permission to `operator` to transfer the caller's tokens, according to `id`, and an amount: `amount`.
     * Emits an {ApprovalByAmount} event.
     *
     * Requirements:
     * - `operator` cannot be the caller.
     */
    function approve(address operator, uint256 id, uint256 amount) external;

    /**
     * @notice Returns the amount allocated to `operator` approved to transfer `account`'s tokens, according to `id`.
     */
    function allowance(address account, address operator, uint256 id) external view returns (uint256);
}
  • approve(address operator, uint256 id, uint256 amount)関数は、publicまたはexternalである必要があります。
  • allowance(address account, address operator, uint256 id)関数は、publicまたはexternalかつviewである必要があります。
  • safeTrasferFrom関数（EIP1155で定義されたもの）は、以下の条件を満たす必要があります。
    • ユーザーがmsg.senderに十分なトークン量を承認している場合、リバート（revert）してはいけない。
    • msg.senderがsetApprovalForAllで承認されていない場合、送りたいトークン量のうち承認済みではない数量を引く必要がある。

msg.senderはトークンの持ち主ではなく、トークンの持ち主からトークンのやり取りをする権限を与えられているアドレスです。
setApprovalForAllで承認されている場合は、持ち主の全てのトークンをやり取りできますが、そうでない場合は持ち主の一部のトークンのみやり取りできます（もしくは1つも承認されていないか）。
そのため、送りたいトークン量のうち、承認されているトークン量だけ送ることができます。

  • safeBatchTransferFrom関数には、次の追加条件が必要です。
    • 送りたいトークンの全てのidに対して、送りたいトークン量が承認されているか確認する条件を追加する必要があります。

safeBatchTransferFrom関数は、複数のトークンを安全に一括で転送する関数です。
具体的を用いて説明します。

例えば、ユーザー「Bob」が所有する複数の異なるNFT（Non-Fungible Token）を、別のユーザー「Alice」に一括で転送する場面を考えてみます。

// ERC-1155のトークンコントラクトアドレス
address public tokenContractAddress = 0x...; // ダミーアドレス

// Bobのアドレス
address public bob = msg.sender;

// Aliceのアドレス
address public alice = 0x...; // ダミーアドレス

// 転送するトークンの情報
uint256[] public tokenIds = [1, 2, 3]; // 仮のトークンID
uint256[] public amounts = [1, 1, 1]; // 各トークンの数量

// BobがAliceにトークンを一括で転送する
function transferTokensToAlice() public {
    // ERC-1155のsafeBatchTransferFrom関数を呼び出す
    IERC1155(tokenContractAddress).safeBatchTransferFrom(bob, alice, tokenIds, amounts, "");
}

上記の例では、Bobは自分が所有する複数のNFTを一括でAliceに転送するために、transferTokensToAlice関数を呼び出しています。
safeBatchTransferFrom関数は、BobのアドレスからAliceのアドレスへ、指定したトークンIDと数量のトークンを一括で転送します。

safeBatchTransferFrom関数は、複数の異なるトークンを一括で転送する場合に便利な機能です。
関数の呼び出しによって、指定されたトークンIDと数量のトークンが安全に転送されます。

  • 一定数のトークンが承認された場合、ApprovalByAmountイベントが発行します。
  • supportsInterfaceメソッドは、0x1be07d74を引数として呼び出された際に、trueを返します。

補足

**"EIP-1155 Approval By Amount Extension"**という名前は、このEIPの簡潔な説明を提供するために選ばれました。
ユーザーは特定のトークンのidと数量を指定して、オペレーターに対してトークンの承認を行うことができる機能を拡張するためのEIPです。

EIP20に似た方法でトークンの承認と取り消しを行うことにより、ユーザーはより直接的にトークンの管理を行うことができるようになります。

  • approve関数を使用することで、ユーザーは特定のオペレーターに対して、各トークンのidごとに一定の数量のトークンの使用を許可することができます。
  • allowance関数を使用することで、ユーザーは特定のオペレーターが各トークンのidごとにどれだけの承認を持っているかを確認できます。

この名前の選択は、EIP1155で提案されているトークンの承認の仕組みが、既存のEIP20と似た考え方に基づいており、トークン管理のプロセスを理解しやすくするためです。
これにより、ユーザーは自分のトークンの操作をより管理しやすくなります。

後方互換性

この標準は、EIP1155と互換性があります。

参考実装

以下が参考実装になります。

// SPDX-License-Identifier: CC0-1.0
pragma solidity ^0.8.15;

import "IERC1155.sol";
import "ERC1155.sol";

/**
 * @title ERC-1155 Approval By Amount Extension
 * Note: the ERC-165 identifier for this interface is 0x1be07d74
 */
interface IERC1155ApprovalByAmount is IERC1155 {

    /**
     * @notice Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `id` and with an amount: `amount`.
     */
    event ApprovalByAmount(address indexed account, address indexed operator, uint256 id, uint256 amount);

    /**
     * @notice Grants permission to `operator` to transfer the caller's tokens, according to `id`, and an amount: `amount`.
     * Emits an {ApprovalByAmount} event.
     *
     * Requirements:
     * - `operator` cannot be the caller.
     */
    function approve(address operator, uint256 id, uint256 amount) external;

    /**
     * @notice Returns the amount allocated to `operator` approved to transfer `account`'s tokens, according to `id`.
     */
    function allowance(address account, address operator, uint256 id) external view returns (uint256);
    
}

/**
 * @dev Extension of {ERC1155} that allows you to approve your tokens by amount and id.
 */
abstract contract ERC1155ApprovalByAmount is ERC1155, IERC1155ApprovalByAmount {

    // Mapping from account to operator approvals by id and amount.
    mapping(address => mapping(address => mapping(uint256 => uint256))) internal _allowances;

    /**
     * @dev See {IERC1155ApprovalByAmount}
     */
    function approve(address operator, uint256 id, uint256 amount) public virtual {
        _approve(msg.sender, operator, id, amount);
    }

    /**
     * @dev See {IERC1155ApprovalByAmount}
     */
    function allowance(address account, address operator, uint256 id) public view virtual returns (uint256) {
        return _allowances[account][operator][id];
    }

    /**
     * @dev safeTransferFrom implementation for using ApprovalByAmount extension
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes memory data
    ) public override(IERC1155, ERC1155) {
        require(
            from == msg.sender || isApprovedForAll(from, msg.sender) || allowance(from, msg.sender, id) >= amount,
            "ERC1155: caller is not owner nor approved nor approved for amount"
        );
        unchecked {
            _allowances[from][msg.sender][id] -= amount;
        }
        _safeTransferFrom(from, to, id, amount, data);
    }

    /**
     * @dev safeBatchTransferFrom implementation for using ApprovalByAmount extension
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] memory ids,
        uint256[] memory amounts,
        bytes memory data
    ) public virtual override(IERC1155, ERC1155) {
        require(
            from == msg.sender || isApprovedForAll(from, msg.sender) || _checkApprovalForBatch(from, msg.sender, ids, amounts),
            "ERC1155: transfer caller is not owner nor approved nor approved for some amount"
        );
        _safeBatchTransferFrom(from, to, ids, amounts, data);
    }

    /**
     * @dev Checks if all ids and amounts are permissioned for `to`. 
     *
     * Requirements:
     * - `ids` and `amounts` length should be equal.
     */
    function _checkApprovalForBatch(
        address from, 
        address to, 
        uint256[] memory ids,
        uint256[] memory amounts
    ) internal virtual returns (bool) {
        uint256 idsLength = ids.length;
        uint256 amountsLength = amounts.length;

        require(idsLength == amountsLength, "ERC1155ApprovalByAmount: ids and amounts length mismatch");
        for (uint256 i = 0; i < idsLength;) {
            require(allowance(from, to, ids[i]) >= amounts[i], "ERC1155ApprovalByAmount: operator is not approved for that id or amount");
            unchecked { 
                _allowances[from][to][ids[i]] -= amounts[i];
                ++i; 
            }
        }
        return true;
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens by id and amount.
     * Emits a {ApprovalByAmount} event.
     */
    function _approve(
        address owner,
        address operator,
        uint256 id,
        uint256 amount
    ) internal virtual {
        require(owner != operator, "ERC1155ApprovalByAmount: setting approval status for self");
        _allowances[owner][operator][id] = amount;
        emit ApprovalByAmount(owner, operator, id, amount);
    }
}

contract ExampleToken is ERC1155ApprovalByAmount {
    constructor() ERC1155("") {}

    function mint(address account, uint256 id, uint256 amount, bytes memory data) public {
        _mint(account, id, amount, data);
    }

    function mintBatch(address to, uint256[] memory ids, uint256[] memory amounts, bytes memory data) public {
        _mintBatch(to, ids, amounts, data);
    }
}

approve

function approve(address operator, uint256 id, uint256 amount) public virtual {
    _approve(msg.sender, operator, id, amount);
}

概要
所有者が特定のオペレーターに対して、指定されたトークンIDと数量に基づいてトークンの使用を許可する関数。

詳細
所有者は、この関数を使用してオペレーターに対してトークンの使用権を付与することができます。
関数は、指定されたオペレーターに対して、特定のトークンIDごとに一定の数量のトークンの使用を許可します。
この関数は内部で_approve関数を呼び出して実際の承認処理を行います。

引数

  • operator
    • トークンの操作権限を与える対象のアドレス（オペレーター）。
  • id
    • 操作権限を与えるトークンID。
  • amount
    • 操作権限を与えるトークンの数量。

allowance

function allowance(address account, address operator, uint256 id) public view virtual returns (uint256) {
    return _allowances[account][operator][id];
}

概要
指定されたアカウントとオペレーターの組み合わせに対して、特定のトークンIDの許可されたトークン数量を取得する関数。

詳細
指定されたアカウントとオペレーターの組み合わせに対して、特定のトークンIDに対して許可されたトークン数量を返します。
これにより、ユーザーは特定のオペレーターが特定のトークンに対してどれだけの操作権限を持っているかを確認できます。

引数

  • account
    • 許可情報を取得するアカウントのアドレス。
  • operator
    • アカウントに対するオペレーターのアドレス。
  • id
    • 許可情報を取得するトークンID。

戻り値
特定のアカウントとオペレーターの組み合わせに対して、指定されたトークンIDの許可されたトークン数量を示す整数値。

safeTransferFrom

function safeTransferFrom(
    address from,
    address to,
    uint256 id,
    uint256 amount,
    bytes memory data
) public override(IERC1155, ERC1155) {
    require(
        from == msg.sender || isApprovedForAll(from, msg.sender) || allowance(from, msg.sender, id) >= amount,
        "ERC1155: caller is not owner nor approved nor approved for amount"
    );
    unchecked {
        _allowances[from][msg.sender][id] -= amount;
    }
    _safeTransferFrom(from, to, id, amount, data);
}

概要
ApprovalByAmount拡張を使用した安全なトークンの転送を行う関数。

詳細
指定された条件を満たす場合にトークンを転送します。
条件としては、以下が含まれます。

  • fromがmsg.senderであるか、msg.senderによってfromからisApprovedForAllで承認されている。
  • fromがmsg.senderに対してidに指定されたトークンのamountに基づいて十分な承認を持っている。

転送処理の前に、オペレーターに対する許可された数量が減算されます。
その後、_safeTransferFrom関数を呼び出して安全なトークン転送を行います。

引数

  • from
    • トークンの所有者のアドレス。
  • to
    • トークンを受け取るアドレス。
  • id
    • 転送するトークンID。
  • amount
    • 転送するトークンの数量。
  • data
    • 任意の追加データ。

safeBatchTransferFrom

function safeBatchTransferFrom(
    address from,
    address to,
    uint256[] memory ids,
    uint256[] memory amounts,
    bytes memory data
) public virtual override(IERC1155, ERC1155) {
    require(
        from == msg.sender || isApprovedForAll(from, msg.sender) || _checkApprovalForBatch(from, msg.sender, ids, amounts),
        "ERC1155: transfer caller is not owner nor approved nor approved for some amount"
    );
    _safeBatchTransferFrom(from, to, ids, amounts, data);
}

概要
ApprovalByAmount拡張を使用した安全にトークンを一括転送を行う関数。

詳細
指定された条件を満たす場合に複数のトークンを一括で転送します。
条件としては、以下が含まれます。

  • fromがmsg.senderであるか、msg.senderによってfromからisApprovedForAllで承認されている。
  • fromがmsg.senderに対してidに指定された複数トークンごとに、各トークンのamountに基づいて十分な承認を持っている。

転送処理の前に、オペレーターに対する許可された数量が一括で減算されます。
その後、_safeBatchTransferFrom関数を呼び出して安全な一括トークン転送を行います。

引数

  • from
    • トークンの所有者のアドレス。
  • to
    • トークンを受け取るアドレス。
  • ids
    • 転送するトークンのidの配列。
  • amounts
    • 転送するトークンの数量の配列。
  • data
    • 任意の追加データ。

_checkApprovalForBatch

function _checkApprovalForBatch(
    address from, 
    address to, 
    uint256[] memory ids,
    uint256[] memory amounts
) internal virtual returns (bool) {
    uint256 idsLength = ids.length;
    uint256 amountsLength = amounts.length;

    require(idsLength == amountsLength, "ERC1155ApprovalByAmount: ids and amounts length mismatch");
    for (uint256 i = 0; i < idsLength;) {
        require(allowance(from, to, ids[i]) >= amounts[i], "ERC1155ApprovalByAmount: operator is not approved for that id or amount");
        unchecked { 
            _allowances[from][to][ids[i]] -= amounts[i];
            ++i; 
        }
    }
    return true;
}

概要
トークン一括転送の時に指定されたトークンIDと数量が許可されているかを確認する関数。

詳細
指定されたアカウントfromからアカウントtoへの一括トークン転送の時に、各トークンIDと数量が適切に許可されているかを確認します。
指定されたids配列とamounts配列の要素数が一致していることを確認し、各トークンに対する許可情報を確認します。
許可情報が適切であることが確認されると、許可された数量を減算します。

引数

  • from
    • トークンの所有者のアドレス。
  • to
    • トークンを受け取るアドレス。
  • ids
    • 転送するトークンのidの配列。
  • amounts
    • 転送するトークンの数量の配列。

戻り値
トークンのidと数量が適切に許可されている場合にtrueを返します。

_approve

function _approve(
    address owner,
    address operator,
    uint256 id,
    uint256 amount
) internal virtual {
    require(owner != operator, "ERC1155ApprovalByAmount: setting approval status for self");
    _allowances[owner][operator][id] = amount;
    emit ApprovalByAmount(owner, operator, id, amount);
}

概要
所有者がオペレーターに対して特定のトークンIDと数量に基づいて承認を行う関数。

詳細
指定された所有者のアドレスownerがオペレーターのアドレスoperatorに対して、特定のトークンIDに対して指定された数量を承認します。
ただし、所有者とオペレーターが同じアドレスである場合は、自己に対する承認を行うことはできません。
承認情報は_allowances配列内に設定され、ApprovalByAmountイベントが発行されます。

引数

  • owner
    • トークンの所有者のアドレス。
  • operator
    • トークンを操作するオペレーターのアドレス。
  • id
    • 承認するトークンID。
  • amount
    • 承認するトークンの数量。

セキュリティ考慮事項

このEIPのユーザーは、オペレーターに対して許可するトークンの数量を十分に検討し、使用されない許可を取り消すことを考慮する必要があります。

ユーザーがトークンの許可を適切に管理し、不要な権限を取り消すことが重要であることを強調しています。

引用

Iván Mañús (@ivanmmurciaua), Juan Carlos Cantó (@EscuelaCryptoES), "ERC-5216: EIP-1155 Approval By Amount Extension [DRAFT]," Ethereum Improvement Proposals, no. 5216, July 2022. [Online serial]. Available: https://eips.ethereum.org/EIPS/eip-5216.

最後に

今回は「ERC1155規格を拡張して、より細かくトークンのapproveを実行できる提案であるERC5216」についてまとめてきました！
いかがだったでしょうか？

質問などがある方は以下のTwitterのDMなどからお気軽に質問してください！

Twitter @cardene777

3
2
0

Register as a new user and use Qiita more conveniently

  1. You get articles that match your needs
  2. You can efficiently read back useful information
  3. You can use dark theme
What you can do with signing up
Sign upLogin
3
2

Delete article

Deleted articles cannot be recovered.

Draft of this article would be also deleted.

Are you sure you want to delete this article?