Excelを使った簡易な勤務報告書を作成
※皆様のためというより…私の仕事量を減らすために記述します。
各会社や書式によってさまざまな方法がございます。
当勤務表は、省力化を目的としているものです。
■要件概要
日付を何個も入力したくない
曜日を何個も入力したくない
休憩時間は自動で入力してほしい
現状の勤務時間の累計、残業時間の累計をすぐ出したい
現状の状態だと、勤務時間累計がどのくらいになるのか、残業がどのくらいになるのかを知りたい
こんな感じにする
【１ 日付】
B2に 2019/10/01 と、月の先頭の日付を入力します。書式設定にて YYYY年MM月の形式で表示します。
B6は ≂B2 を入力し、書式設定にて、 MM/DD の形式で表示します。
★日付の加算
★次月の日付の非表示
B7 は =IF(MONTH(B6+1)=MONTH($B$2),B6+1,"")
B8～B36はB7をコピー、書式設定にて、 MM/DD の形式で表示します。
これで、B2に初期日付を入れれば、自動で、日付を全部うめてくれます。
【３ 曜日・祭日】
C列は曜日を設定します。
★B列の同行が空白だったら、空白
★B列の同業に何かあったら、曜日表記で記入
C6列 =IF(B6="","",TEXT(B6,"aaa"))
C7~C36はC6をコピー
祭日用のリストを別シートに用意します 祭日シートのB列に今年の祭日の日付を記入しています。
B17 2019/10/14
B18 2019/10/22
B19 2019/11/4
B20 2019/11/23
★B列の同行の値が、祭日に当てはまったら 祝 を表示
★C列の同行の値が、日、土だったら、休 を表示 ※重なってもOK
D6 = =IF(COUNTIF(祭日!B:B,B6)=1,"祝","")&IF(C6="日","休","")&IF(C6="土","休","")
D7～36はD6をコピー
【４ 休憩時間】
こちらについては、開始業務時間やフレックス等にて影響しますので手で記入したほうが速い可能性もあります。
L列16行目 に12：00
L列17行目 に20：00 と記載しています。
★始業時間が空白の場合、空白
★始業時間が12：00よりも前の場合、休憩時間が60分、終業が22：00以降の場合90分
★始業時間が12：00よりも後の場合で終業が22：00以降の場合30分
G6 = IF(E6="","",IF(F6>L$17,IF(E6<L$16,"90","30"),IF(E6<L$16,"60","0")))
G7～G36 はG6をコピー
【５ 勤務時間】
★始業時間が空白の場合、空白
★終業時間 － 始業時間 － 休憩時間 を表示する
H6 =IF(F6="","",F6-E6-G6/(60*24))
H7～H36 はH6をコピー
【６ 集計】
L列15行目に
1日の所定労働時間 に 所定労働時間を記入しておきます。
★一日の所定労働時間から、勤務実績、残業実績の集計
勤務実績 L5=SUM(H6:H36)*24
残業実績 L6=L5-COUNT(H6:H36)*L15
★休日、日付から営業日数の集計
営業日数 L8=COUNT(B6:B36)-COUNTIF(D6:D36,"祝")-COUNTIF(D6:D36,"休")
★働いた日数の集計
実績日数 L8=COUNT(H6:H36)
休暇日数 L9≂ 公休日以外でお休みする日数を入力
★営業日数、実績から平均をだし、予測を単純計算
★勤務予測から残業時間の予測を単純計算
勤務予測 L12=SUM(H6:H36)24/COUNT(H6:H36)(L8-L10)
残業予測 L13=L12-(L8-L10)*L15
以上でございます。